ADALM-PLUTO 固件升级 V0.38

 

最新固件地址：

Release v0.39 · analogdevicesinc/plutosdr-fw

 

因为 matlab R2025B 对应固件 V0.38， 因此 下载 V0.38 

Release v0.38 · analogdevicesinc/plutosdr-fw

 

固件更新 参考此方法：

Pluto固件更新误拔出的修复方法_plutosdr 固件-CSDN博客

 

上电之前 按着 USB 旁边的孔， 设备管理器 识别出 USB download gadget时，  使用  update.bat （内容在最后）指令 升级

在 固件 对应的文件夹下， 使用 命令行，启动固件升级

.\update.bat C:\Users\zydz\Desktop\AD9361\ADALM-PLUTO\plutosdr-fw-v0.38\pluto.dfu

 

 

 升级完成

 

 

update.bat 文件内容如下：

 

@echo OFF

IF %1.==. GOTO help

set FILE=%1
set pInstallDir=NULL

set KEY_NAME=HKEY_LOCAL_MACHINE\SOFTWARE\Analog Devices\PlutoSDR-M2k-USB-Win-Drivers\Settings
FOR /F "tokens=2*" %%A IN ('REG.exe query "%KEY_NAME%" /v "InstallPath"') DO (set pInstallDir=%%B)

IF "%pInstallDir%"=="NULL" (
	echo PlutoSDR-M2k-USB-Win-Drivers not installed && exit /b 1
)

REM "%pInstallDir%\dfu-util.exe" -l || exit /b 1

for /F %%i in ("%FILE%") do @set NAME=%%~nxi

if %NAME%==pluto.dfu goto firmware
if %NAME%==m2k.dfu goto firmware_m2k
if %NAME%==uboot-env.dfu goto ubootenv
goto help

:firmware
"%pInstallDir%\dfu-util.exe" -d 0456:b673,0456:b674 -D %FILE% -a firmware.dfu
exit /b 0

:firmware_m2k
"%pInstallDir%\dfu-util.exe" -d 0456:b672,0456:b675 -D %FILE% -a firmware.dfu
exit /b 0

:ubootenv
"%pInstallDir%\dfu-util.exe" -d 0456:b673,0456:b674 -D %FILE% -a uboot-env.dfu || "%pInstallDir%\dfu-util.exe" -d 0456:b672,0456:b675 -D %FILE% -a uboot-env.dfu
exit /b 0

:help
echo PlutoSDR/M2k DFU update utility
echo Usage: %0 PATH-TO\[pluto^|m2k].dfu
exit /b 0