retreatafter

导航

 

本节目录

  1. 1.screen
  2. 2.UI框架语句
  3. 3.布局方式
  4. 4.布局属性
  5. 5.元素类型
  6. 6.活动行为

1.screen

  • (1)renpy默认存在screens.rpy脚本,可以看到该脚本用于管理游戏UI并预设了一些内容,如游戏内屏幕(对话屏幕、输入屏幕、选择屏幕、快捷菜单屏幕、读取和保存屏幕、历史屏幕)、标题和游戏菜单屏幕(导航屏幕、标题菜单屏幕、游戏菜单屏幕)、移动设备界面等等。我们想要自定义自己游戏的UI,可以创建新的UI管理脚本,以下以创建脚本myscreens.rpy为例。
  • (2)UI的制作使用到screen语句,表示是展示到游戏界面上的UI。我们在脚本myscreens.rpy中编写UI样式内容相关代码,在script.rpy脚本中调用显示此UI。

2.UI框架语句

  • (1)fixed:框架语句,声明包裹的内容都属于该UI,固定布局,自适应内容作为UI界面大小。
  • (2)frame:框架语句,声明包裹的内容都属于该UI,并默认存在白色背景。在不设置UI界面的宽高时默认填充整个页面。
    • 2026__引擎.Renpy__创建UI界面.UI框架语句
# 脚本myscreens.rpy
screen mysc:
    frame:
        text "这里似乎有一些文字"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return

3.布局方式

  • (1)hbox:横排框,将内容块元素横向排布。
  • (2)vbox:坚排框,将内容块元素纵向排布。
    • 2026__引擎.Renpy__创建UI界面.布局方式
# 脚本myscreens.rpy
screen mysc:
    frame:
        vbox:
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return
  • (3)grid [列数] [行数]:以网格排列。内容块元素必须完全符合所给网格数量,不常用此方式实现网格排列,通常用于图集展示。
    • 2026__引擎.Renpy__创建UI界面.布局方式
# 脚本myscreens.rpy
screen mysc:
    frame:
        grid 2 3:
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return
  • (4)viewport:滚动条。常用于背包系统等存在多数据的情况。
    • 2026__引擎.Renpy__创建UI界面.布局方式
# 脚本myscreens.rpy
screen mysc:
    frame:
        viewport:
            # x轴滚轮默认位置
            xinitial 0.0
            # y轴滚轮默认位置
            yinitial 1.0
            # 垂直滚动
            scrollbars "vertical"
            # 支持鼠标滚轮
            mousewheel True
            # 支持鼠标拖动,同样支持移动端触屏
            draggable True
            # 支持翻页键
            pagekeys True
            # 将y轴铺满
            side_yfill True
            vbox:
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
                text "这里似乎有一些文字"
# 脚本script.rpy
label start:
    # 调用UI界面mysc
    show screen mysc
    return

4.布局属性

  • (1)UI大小及位置设置,使用位置语句和size语句。
    • 2026__引擎.Renpy__创建UI界面.布局属性
# 脚本myscreens.rpy
screen mysc:
    frame:
        # 将该UI放到中央
        xcenter 0.5
        ycenter 0.5
        # 对该UI大小进行设置
        xsize 640
        ysize 360
        vbox:
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return
  • (2)spacing:设置内容块元素之间的行间距。
    • 2026__引擎.Renpy__创建UI界面.布局属性
# 脚本myscreens.rpy
screen mysc:
    frame:
        vbox:
            # 块与块间距设置为20
            spacing 20
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
            text "这里似乎有一些文字"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return

5.元素类型

  • (1)add:添加一个可视组件,通常是另外定义好的组件类。最为灵活。
  • (2)text:添加一段文本。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        # 在添加后还可以对样式进行简单调整,可以写在一行,也可以使用冒号后在缩进范围内描述样式。此处设置文字颜色为粉色,文字大小40,设置宽度为2的黑色外边框
        text "这里似乎有一些文字" size 40 outlines[(absolute(2), "#000", absolute(0), absolute(0))] color "#ffcce0"
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc
    show screen mysc
    return
  • (3)button:添加按钮。需要添加行为action,描述此按钮具体作用。此标签不支持鼠标聚焦在按钮上时的按钮颜色变化。关于按钮类型,下述的textbutton和imagebutton更常用。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        # 设置一个按钮,并且点击后推进接下来的内容
        button:
            text "这里似乎有一些文字"
            action Return('mysc')
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (4)textbutton:添加一个文本按钮。支持鼠标悬停时的颜色变化。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        # 设置一个按钮,并且点击后推进接下来的内容
        textbutton "这里似乎有一些文字":
            # 对该按钮的内容进行简单的样式修改
            text_size 40
            text_outlines [(absolute(2), "#000", absolute(0), absolute(0))]
            # 文字颜色
            text_color "#ffcce0"
            # 鼠标悬停时的颜色
            text_hover_color "#000"
            action Return('mysc')
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (5)imagebutton:添加一个图像按钮。可以通过设置不同状态下展示的图片来实现鼠标悬停效果。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        vbox:
            # 设置一个图像按钮,点击将flag的值设置为1
            imagebutton:
                # 默认效果
                idle "images/imagebutton1.png"
                # 悬停时效果
                hover "images/imagebutton2.png"
                action SetVariable("flag", 1)

            # 展示flag值变化
            text "[flag]":
                size 40
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
define flag = 0
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (6)imagemap:图像按钮集,配合hotspot允许切割一张图片为数个按钮。常用于解谜游戏。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    imagemap:
        # 默认图片
        idle "s1"
        # 悬停时图片
        hover "s1click"
        # 一个(x, y, width, height)形式的元组,给定了imagemap内组成按钮的区域
        hotspot (100, 200, 300, 400) action Return("mysc")
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
define flag = 0
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (7)bar value [函数]:用一个条来可视化展示数值变化。
    • 属性:可以设置bar_invert True使条从右往左填充、设置 bar_vertical True使条变为竖的条。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        vbox:
            # AnimatedValue()函数的参数value为展示什么变量的值,range为整个条的满值,delay为时间
            # 这里同时调整了条的长度 xsize 200像素
            bar value AnimatedValue(value=flag, range=3, delay=1.0) xsize 200
            # 设置一个图像按钮,点击将flag的值设置为1
            imagebutton:
                # 默认效果
                idle "images/imagebutton1.png"
                # 悬停时效果
                hover "images/imagebutton2.png"
                action SetVariable("flag", 1)

            # 展示flag值变化
            text "[flag]":
                size 40
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
define flag = 0
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (8)input value:定义一个输入框。
    • 属性:可以设置length [数值]来限制输入框中最多输入的字符数、设置allow [有效字符]来控制输入框中允许输入的内容。
    • 2026__引擎.Renpy__创建UI界面.元素类型
# 脚本myscreens.rpy
screen mysc:
    frame:
        input value VariableInputValue("input_value")
# 脚本script.rpy
# 对比示例图,省略了图片背景的插入及文本内容
define input_value = ""
label start:
    # 调用UI界面mysc,并且停在此界面,不推进接下来的内容,直到解除该行为
    call screen mysc
    return
  • (9)timer action:经过一段时间才会触发活动行动。
  • (10)use:引用其它界面。

6.活动行为

  • (1)创建button按钮时,提到了添加按钮必须同时添加活动行为。renpy中将活动行为分为控制行为(隐藏、跳转、显示、调用、Null等)、数据行为(对数据的控制)、菜单行为(唤起菜单)、文件行为(文件的保存、读取和删除)、音频行为等。常见的活动行为可参考:https://doc.renpy.cn/zh-CN/screen_actions.html
    • 控制行为:常见语句call、jump、hide、return、show、nullaction
    • 菜单行为:常见语句continue、mainmenu、quit、showmenu、start
posted on 2026-10-08 00:49  retreatafter  阅读(31)  评论(0)    收藏  举报