(1)renpy中，可使用Character()函数进行角色变量定义，Character()函数除了可以指定角色姓名外，还支持许多参数，并且参数前缀用what_和who_分为两部分，以区别是对角色名称进行操作还是对话文本进行操作。常见参数有：
- 角色姓名：默认为第一个参数且用双引号""包裹。示例：a = Character("一个名为A的路人")。
- font：字体。示例，给该角色名字体调整为霞鹜文楷字体，字体文件放在了游戏核心文件夹game下新创建的fonts文件夹下：a = Character("一个名为A的路人", who_font = "fonts/霞鹜文楷-Regular.ttf")。
- bold：文本粗体，用布尔值bool调整。示例，给该角色说话内容加粗：a = Character("一个名为A的路人", what_bold = True)。
- size：文本大小，分为角色名大小和文本大小。示例，该角色名大小调整为35，角色说话内容调整为45：a = Character("一个名为A的路人", what_size = 35, who_size = 45)。
- color：颜色，使用RGB格式，用双引号包裹。示例，该角色名颜色调整为绀紫：a = Character("一个名为A的路人", who_color = "#003371")。
- outlines：文字外边框，指定宽度、颜色、x方向的偏移量，y方向的偏移量。示例，给该角色名添加宽度为2的白色外边框：a = Character("一个名为A的路人", who_outlines = [(2, "#fff", 0, 0)])。
- prefix：文本自带前缀。示例，给该角色名带上“【”前缀：a = Character("一个名为A的路人", who_prefix = "【")。
- suffix：文本自带后缀。示例，给该角色名带上“】”后缀：a = Character("一个名为A的路人", who_suffix = "】")。

# 角色姓名：一个名为A的路人；角色名字体调整为霞鹜文楷字体；角色说话内容加粗；角色名大小调整为35，角色说话内容调整为45；角色名颜色调整为绀紫；给角色名添加宽度为2的白色外边框；角色名带有【】前后缀；
define a = Character("一个名为A的路人", who_font = "fonts/霞鹜文楷-Regular.ttf", what_bold = True, what_size = 35, who_size = 45, who_color = "#003371", who_outlines = [(2, "#fff", 0, 0)], who_prefix = "【", who_suffix = "】")

label start:
    a "内心似乎有些触动……"
    return

2.角色头像

(1)对话时展现的角色头像，默认显示在对话框左侧。使用image标签加上side标识创建图像组，在角色函数中指定该图像组。推荐图片大小为250×250。

# 参数image指定头像的图像组为c1
define a = Character("一个名为A的路人", who_font = "fonts/霞鹜文楷-Regular.ttf", what_bold = True, what_size = 35, who_size = 45, who_color = "#003371", who_outlines = [(2, "#fff", 0, 0)], who_prefix = "【", who_suffix = "】", image = "c1")

# 定义图像组c1
# 头像图像组c1 中 默认展示图像
image side c1 = "images/c1defaultside.jpg"
# 头像图像组c1 中 a标签对应图像
image side c1 a = "images/c1aside.jpg"
# 头像图像组c1 中 b标签对应图像
image side c1 b = "images/c1bside.jpg"

label start:
    a "内心似乎有些触动……（头像为默认表情）"
    a a "内心似乎有些触动……（头像为图像组a表情）"
    a b "内心似乎有些触动……（头像为图像组b表情）"
    return

(2)当同时创建了角色（立绘）图像组和角色头像图像组，且两者的图像标签对应一致时，可以实现同时变换。

# 角色姓名：一个名为A的路人；角色名字体调整为霞鹜文楷字体；角色说话内容加粗；角色名大小调整为35，角色说话内容调整为45；角色名颜色调整为绀紫；给角色名添加宽度为2的白色外边框；角色名带有【】前后缀；
define a = Character("一个名为A的路人", who_font = "fonts/霞鹜文楷-Regular.ttf", what_bold = True, what_size = 35, who_size = 45, who_color = "#003371", who_outlines = [(2, "#fff", 0, 0)], who_prefix = "【", who_suffix = "】", image = "c1")

# 头像图像组c1 中 默认展示图像
image side c1 = "images/c1defaultside.jpg"
# 头像图像组c1 中 a标签对应图像
image side c1 a = "images/c1aside.jpg"
# 头像图像组c1 中 b标签对应图像
image side c1 b = "images/c1bside.jpg"

# 图片图像组c1 中 默认展示图像
image c1 = "images/c1default.jpg"
# 图片图像组c1 中 a标签对应图像
image c1 a = "images/c1a.jpg"
# 图片图像组c1 中 b标签对应图像
image c1 b = "images/c1b.jpg"

label start:
    play music "audio/music01.mp3"
    # 在屏幕中展示图片
    show c1
    a "内心似乎有些触动……（头像为默认表情）"
    a a "内心似乎有些触动……（头像为图像组a表情）"
    a b "内心似乎有些触动……（头像为图像组b表情）"
    return

posted on 2026-10-08 00:40 retreatafter 阅读(18) 评论(0) 收藏举报

刷新页面返回顶部

导航

1.基础设置

2.角色头像