bzoj1005

有了bzoj1430的经验解决这题就不是什么难事了
首先考虑度数确定的点，令tot=sigma(d[i]-1)
首先给这tot个数分配prufer编码的位置有C(tot,n-2)种方案
每个方案中是可以进行可重复排列的，对应tot!/[(d[1]-1)!*(d[2]-1)!*…*(d[k]-1)!] 这里都是已确定的度数的点
下面考虑无所谓的点，这些可以在prufer序列中随意分配
因此答案是m^(n-2-tot) (m表示未确定度数的点的个数）
根据乘法原理答案就是C(tot,n-2)*m^(n-2-tot)*tot!/[(d[1]-1)!*(d[2]-1)!*…*(d[k]-1)!]
=（n-2)!*m^(n-2-tot)/[(d[1]-1)!*(d[2]-1)!*…*(d[k]-1)!*(n-2-tot)!]
肯定要高精度，但是我们要尽量避免除法
考虑到这里计算出的方案一定是整数，于是我们可以先质因数分解，然后消去，这要就是单精度的高精度乘法了

var d:array[0..1010,0..1010] of longint;
    a,p,c:array[0..1010] of longint;
    ans:array[0..100010] of longint;
    l,i,m,x,n,w,j,t:longint;
    f:boolean;

procedure mul(x,y:longint);
  var i,j,u,v:longint;
  begin
    for i:=1 to y do
    begin
      v:=0;
      for j:=1 to l do
      begin
        u:=ans[j]*x+v;
        v:=u div 10;
        ans[j]:=u mod 10;
      end;
      while v>0 do
      begin
        inc(l);
        ans[l]:=v mod 10;
        v:=v div 10;
      end;
    end;
  end;

begin
  readln(n);
  for i:=2 to n do
  begin
    f:=true;
    for j:=2 to trunc(sqrt(i)) do
      if i mod j=0 then
      begin
        f:=false;
        break;
      end;
    if f then
    begin
      inc(t);
      p[t]:=i;
    end;
  end;
  for i:=1 to n do
  begin
    readln(a[i]);
    if a[i]<>-1 then m:=m+a[i]-1
    else inc(w);
  end;
  for i:=2 to n-2 do
  begin
    for j:=1 to t do
      d[i,j]:=d[i-1,j];
    x:=i;
    j:=1;
    while x<>1 do //预处理阶乘的质因数分解
    begin
      while (x<>1) and (x mod p[j]=0) do
      begin
        x:=x div p[j];
        inc(d[i,j]);
      end;
      inc(j);
    end;
  end;
  ans[1]:=1;
  l:=1;
  x:=w;
  j:=1;
  while x<>1 do  //m^(n-2-tot)的质因数分解
  begin
    while (x<>1) and (x mod p[j]=0) do
    begin
      x:=x div p[j];
      c[j]:=c[j]+(n-2-m);
    end;
    inc(j);
  end;

  for i:=1 to t do
    c[i]:=c[i]+d[n-2,i]-d[n-2-m,i];

  for i:=1 to n do
    if a[i]<>-1 then
    begin
      for j:=1 to t do
        c[j]:=c[j]-d[a[i]-1,j];
    end;
  for i:=1 to t do
    mul(p[i],c[i]);
  for i:=l downto 1 do
    write(ans[i]);
  writeln;
end.