bzoj3531

不难想到树链剖分
这题的难点是记录的是路径上宗教相同的点
裸的想法是对每一种宗教都开一棵线段树，记录每个点的评级
但显然这样会爆空间，仔细分析一下，这些线段树内很多点压根就没用到
因此我们考虑对线段树动态开点，不难发现每次修改最多要开线段树上O(2*logn)个点，是可以接受的
然后就是打码的问题了

type node=record
       po,next:longint;
     end;
     link=record
       l,r,s,m:longint;
     end;

var tree:array[0..200010*20] of link;
    fa,size,d,top,p,c,h,b,w:array[0..100010] of longint;
    e:array[0..200010] of node;
    len,t,i,n,q,x,y:longint;
    ch:char;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure update(x:longint);
  begin
    tree[x].s:=tree[tree[x].l].s+tree[tree[x].r].s;
    tree[x].m:=max(tree[tree[x].l].m,tree[tree[x].r].m);
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    size[x]:=1;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if fa[x]<>y then
      begin
        d[y]:=d[x]+1;
        fa[y]:=x;
        dfs1(y);
        size[x]:=size[x]+size[y];
      end;
      i:=e[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var i,y,q:longint;
  begin
    q:=0;
    inc(t);
    c[x]:=t;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if (c[y]=0) and (size[y]>size[q]) then q:=y;
      i:=e[i].next;
    end;
    if q<>0 then
    begin
      top[q]:=top[x];
      dfs2(q);
    end;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if c[y]=0 then
      begin
        top[y]:=y;
        dfs2(y);
      end;
      i:=e[i].next;
    end;
  end;

function change(last,l,r,x,y:longint):longint;
  var m,q:longint;
  begin
    inc(t);
    if l=r then
    begin
      tree[t].m:=y;
      tree[t].s:=y;
      exit(t);
    end
    else begin
      m:=(l+r) shr 1;
      q:=t;
      if x<=m then
      begin
        tree[q].r:=tree[last].r;
        last:=tree[last].l;
        tree[q].l:=change(last,l,m,x,y);
      end
      else begin
        tree[q].l:=tree[last].l;
        last:=tree[last].r;
        tree[q].r:=change(last,m+1,r,x,y);
      end;
      update(q);
      exit(q);
    end;
  end;

function getmax(now,l,r,x,y:longint):longint;
  var m,q:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[now].m)
    else begin
      m:=(l+r) shr 1;
      q:=0;
      if (x<=m) and (tree[now].l<>0) then q:=getmax(tree[now].l,l,m,x,y);
      if (y>m) and (tree[now].r<>0) then q:=max(q,getmax(tree[now].r,m+1,r,x,y));
      exit(q);
    end;
  end;

function getsum(now,l,r,x,y:longint):longint;
  var m,q:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[now].s)
    else begin
      m:=(l+r) shr 1;
      q:=0;
      if (x<=m) and (tree[now].l<>0) then q:=q+getsum(tree[now].l,l,m,x,y);
      if (y>m) and (tree[now].r<>0) then q:=q+getsum(tree[now].r,m+1,r,x,y);
      exit(q);
    end;
  end;

function maxx(x,y:longint):longint;
  var f1,f2,re:longint;
  begin
    maxx:=0;
    re:=b[x];
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        maxx:=max(maxx,getmax(h[re],1,n,c[f1],c[x]));
        x:=fa[f1];
      end
      else begin
        maxx:=max(maxx,getmax(h[re],1,n,c[f2],c[y]));
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;
    if c[x]>c[y] then swap(x,y);
    maxx:=max(maxx,getmax(h[re],1,n,c[x],c[y]));
  end;

function ask(x,y:longint):longint;
  var f1,f2,re:longint;
  begin
    ask:=0;
    re:=b[x];
    f1:=top[x];
    f2:=top[y];
    while f1<>f2 do
    begin
      if d[f1]>=d[f2] then
      begin
        ask:=ask+getsum(h[re],1,n,c[f1],c[x]);
        x:=fa[f1];
      end
      else begin
        ask:=ask+getsum(h[re],1,n,c[f2],c[y]);
        y:=fa[f2];
      end;
      f1:=top[x];
      f2:=top[y];
    end;
    if c[x]>c[y] then swap(x,y);
    ask:=ask+getsum(h[re],1,n,c[x],c[y]);
  end;

begin
  readln(n,q);
  for i:=1 to n do
    readln(w[i],b[i]);
  for i:=1 to n-1 do
  begin
    readln(x,y);
    add(x,y);
    add(y,x);
  end;
  d[1]:=1;
  dfs1(1);
  top[1]:=1;
  dfs2(1);
  t:=0;
  for i:=1 to n do
    h[b[i]]:=change(h[b[i]],1,n,c[i],w[i]);
  for i:=1 to q do
  begin
    read(ch);
    if ch='C' then
    begin
      readln(ch,x,y);
      if ch='C' then
      begin
        h[b[x]]:=change(h[b[x]],1,n,c[x],0);
        b[x]:=y;
        h[y]:=change(h[y],1,n,c[x],w[x]);
      end
      else begin
        w[x]:=y;
        h[b[x]]:=change(h[b[x]],1,n,c[x],y);
      end;
    end
    else begin
      readln(ch,x,y);
      if ch='M' then
        writeln(maxx(x,y))
      else writeln(ask(x,y));
    end;
  end;
end.