bzoj2165

类似于bzoj1706，考虑到楼层是等价的
我们令f[p,i,j]为用了2^p次电梯，从房间i到j最多上升了多少层
然后从2^p很容易推到2^(p+1)，类似于floyd的转移即可
下面我们要用最小的电梯次数
可以考虑每一个数都有其唯一的而二进制拆分
从p到0贪心得到一个最接近上了m层的次数ans,ans+1即为答案

const inf=-1000000000000000000;
var f:array[0..64,0..100,0..100] of int64;
    w,v:array[0..100] of int64;
    e,t,i,j,k,n,p,h:longint;
    fl:boolean;
    ans,m:int64;

function max(a,b:int64):int64;
  begin
    if a>b then exit(a) else exit(b);
  end;

function check(p:longint):boolean;
  var i:longint;
  begin
    for i:=1 to n do
      if f[p,1,i]>=m then exit(true);
    exit(false);
  end;

begin
  readln(t);
  for e:=1 to t do
  begin
    readln(n,m);
    for i:=1 to n do
    begin
      for j:=1 to n do
      begin
        read(f[0,i,j]);
        if f[0,i,j]=0 then f[0,i,j]:=inf;
      end;
      readln;
    end;
    p:=0;
    while true do
    begin
      for i:=1 to n do
        for j:=1 to n do
        begin
          f[p+1,i,j]:=inf;
          for k:=1 to n do
          begin
            f[p+1,i,j]:=max(f[p+1,i,j],f[p,i,k]+f[p,k,j]);
            if f[p+1,i,j]>m then  
            begin
              f[p+1,i,j]:=m;
              break;
            end;
          end;
        end;
      if not check(p+1) then inc(p)  //出现了从房间1到某房间最大上升层数大于m就不用往下穷举了
      else break;
    end;
    w[1]:=0;
    for i:=2 to n do
      w[i]:=inf;  //w表示在当前所用次数下到i号房间最大上升层数层数
    ans:=0;
    for h:=p downto 0 do
    begin
      fl:=true;
      for i:=1 to n do
      begin
        for j:=1 to n do
          if w[i]+f[h,i,j]>=m then
          begin
            fl:=false;
            break;
          end;
        if not fl then break;
      end;
      if fl then
      begin
        ans:=ans+int64(1) shl h;
        for i:=1 to n do
          v[i]:=inf;
        for i:=1 to n do
          for j:=1 to n do
            v[j]:=max(v[j],w[i]+f[h,i,j]);
        w:=v;
      end;
    end;
    writeln(ans+1);
  end;
end.