webgame开发中的文件加密

一般的webgame中都会对资源、消息进行加密，这里只是简单记录一下对文件的加密过程。

 

上图为实际项目中所使用的加密工具(较为简单的一个air项目)

 

输入加密key +  需要加密的文件  --> 加密 –> 将加密后的文件保存至另一目录(后缀名视自己的项目的规则进行修改)

实现步骤：

1、读取文件(flash.filesystem.File)，获取文件流(flash.filesystem.FileStream)，获取文件的二进制流(flash.util.ByteArray)

2、对二进制数据进行加密（混淆一下）

3、保存加密后的二进制数据

 

var file:File = new File(path);
//file.isDirectory == false && file.exists

var fs:FileStream = new FileStream();
var bytes:ByteArray = new ByteArray();
fs.open(file, FileMode.READ);   //只读模式
fs.position = 0;
fs.readBytes(bytes, 0, fs.bytesAvailable);
fs.close();


var tempFileName:String = "xxx"; //要保存的文件完整路径
var tempFile:File = new File(tempFileName);
if (tempFile.exists)
{
    tempFile.deleteFile();

    tempFile =  new File(tempFileName);
}

var tempFS:FileStream = new FileStream();
tempFS.open(tempFile, FileMode.WRITE);
tempFS.writeBytes(encrypt(bytes));   //加密数据
tempFS.close();


//encrypt..
var pos:int = 0;
var outByteArray:ByteArray = new ByteArray();
var key:String = StringUtil.trim(keyTxt.text);

for (var i:int = 0, len:int = byte.length; i < len; i++)
{
   //todo...

    outByteArray.writeByte(byte[i] + //.....);
}

return outByteArray;

 

主要的示例代码（加密方法已被隐去>_<）：

<?xml version="1.0" encoding="utf-8"?>
<mx:Canvas xmlns:mx="http://www.adobe.com/2006/mxml" width="100%" height="100%"
         horizontalScrollPolicy="off" verticalScrollPolicy="off">

    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.utils.StringUtil;

            private var filePath:String;
            private var directoryPath:String;

            private function encryptHandler():void
            {
                if (!filePath && !directoryPath)
                {
                    Alert.show("请先选择要加密的文件或目录", "错误");
                    return ;
                }

                var key:String = StringUtil.trim(keyTxt.text);

                if (key == "")
                {
                    Alert.show("加密KEY不能为空", "错误");
                    return ;
                }

                encryptBtn.enabled = false;

                if (!(!filePath))
                {
                    encryptFileHandler(filePath);

                    Alert.show("文件“"+filePath+"”加密完成", "温馨提示");
                }
                else if (!(!directoryPath))
                {
                    encryptDirectoryHandler(directoryPath);

                    Alert.show("目录“"+directoryPath+"”文件加密完成", "温馨提示");
                }

                outputTxt.validateNow();

                encryptBtn.enabled = true;
            }

            private function getTypeFilter():FileFilter
            {
                var str:String = "*.swf;*.jpg;*.png;*.xml;*.zip";

                var filter:FileFilter = new FileFilter("资源("+str+")", str);

                return filter;
            }

            private function selectFileHandler():void
            {
                var file:File = new File();
                file.addEventListener(Event.SELECT, selectFileCallback);
                file.browseForOpen("请选择一个文件", [getTypeFilter()]);
            }

            private function selectFileCallback(evt:Event):void
            {
                clear();

                var file:File = File(evt.target);
                file.removeEventListener(Event.SELECT, selectFileCallback);

                filePath = file.nativePath;

                inputTxt.htmlText = "选择的文件路径：" + filePath;
            }

            private function selectDirectoryHandler():void
            {
                var file:File = new File();
                file.addEventListener(Event.SELECT, selectDirectoryCallback);
                file.browseForDirectory("请选择一个目录");
            }

            private function selectDirectoryCallback(evt:Event):void
            {
                clear();

                directoryPath = File(evt.target).nativePath;

                inputTxt.htmlText = "选择的目录路径：" + directoryPath;

                File(evt.target).removeEventListener(Event.SELECT, selectDirectoryCallback);
            }

            private function getEncryptSuffix(fileType:String):String
            {
                var typeConfig:Object = {
                    'swf' : 's',
                    'jpg' : 'j',
                    'png' : 'p',
                    'xml' : 'x',
                    'zip' : 'z'
                };

                if (!typeConfig[fileType])
                {
                    return fileType;
                }

                return typeConfig[fileType];
            }

            private function clear():void
            {
                inputTxt.htmlText = "";
                outputTxt.htmlText = "";

                filePath = null;
                directoryPath = null;
            }

            private function encryptFileHandler(path:String):void
            {
                var file:File = new File(path);

                if (file.isDirectory == false && file.exists)
                {
                    maskPanel.visible = true;

                    var fs:FileStream = new FileStream();
                    var bytes:ByteArray = new ByteArray();

                    fs.open(file, FileMode.READ);
                    fs.position = 0;
                    fs.readBytes(bytes, 0, fs.bytesAvailable);
                    fs.close();

                    loadFileCompleteHandler(file, bytes);

                    maskPanel.visible = false;
                }
                else
                {
                    outputTxt.htmlText += "<br>【error】" + path + "不是一个正确的文件路径！";
                }
            }

            private function encryptDirectoryHandler(path:String):void
            {
                var file:File = new File(path);

                if (file.exists && file.isDirectory)
                {
                    var fileList:Array = file.getDirectoryListing();
                    var typeArr:Array = ["swf", "zip", "xml", "jpg", "png"];

                    for (var i:int = 0, len:int = fileList.length; i < len; i++)
                    {
                        var tempFile:File = File(fileList[i]);
                        var tempFilePath:String = tempFile.nativePath;

                        if (tempFile.isDirectory == false)
                        {
                            if (typeArr.indexOf(tempFile.extension) > -1)
                            {
                                encryptFileHandler(tempFilePath);
                            }
                            else
                            {
                                outputTxt.htmlText += "<br><font color='#ff0000'>【skip】跳过文件："+tempFilePath+"</font>";
                            }
                        }
                        else if (tempFile.name != ".svn")
                        {
                            encryptDirectoryHandler(tempFilePath);
                        }
                    }
                }
                else
                {
                    outputTxt.htmlText += "<br>【error】" + path + "不是一个正确的目录路径！";
                }
            }

            private function loadFileCompleteHandler(file:File, bytes:ByteArray):void
            {
                outputTxt.htmlText += "<br>开始加密文件" + file.nativePath;

                var tempFileName:String = file.parent.nativePath + "\\" + file.name.replace(new RegExp(file.extension + "$"), "") + getEncryptSuffix(file.extension);

                tempFileName = tempFileName.replace(/\\abc\\/, '\\encrypt_abc\\abc\\');

                var tempFile:File = new File(tempFileName);

                if (tempFile.exists)
                {
                    tempFile.deleteFile();

                    tempFile =  new File(tempFileName);
                }

                var tempFS:FileStream = new FileStream();
                tempFS.open(tempFile, FileMode.WRITE);
                tempFS.writeBytes(encrypt(bytes));
                tempFS.close();
            }

            private function encrypt(byte:ByteArray):ByteArray
            {
                var pos:int = 0;
                var outByteArray:ByteArray = new ByteArray();
                var key:String = StringUtil.trim(keyTxt.text);
                //todo...

                return outByteArray;
            }

        ]]>
    </mx:Script>

    <mx:VBox width="100%" height="100%"
             horizontalScrollPolicy="off" verticalScrollPolicy="off"
             paddingLeft="10" paddingRight="10" paddingTop="10" paddingBottom="10">

        <mx:HBox width="100%" height="50" horizontalScrollPolicy="off" verticalScrollPolicy="off"
                 verticalAlign="middle">

            <mx:Label text="加密KEY" />
            <mx:TextInput  id="keyTxt" width="300" text="abc123" />
            <mx:Button label="加密" id="encryptBtn" click="encryptHandler()" />
            <mx:Spacer width="100%" />

            <mx:Button id="selectFileBtn" click="selectFileHandler()" label="选择文件" />
            <mx:Button id="selectDirectoryBtn" click="selectDirectoryHandler()" label="选择文件夹" />

        </mx:HBox>

        <mx:HBox width="100%" height="100%" horizontalScrollPolicy="off" verticalScrollPolicy="off">

            <mx:TextArea id="inputTxt" width="100%" height="480" leading="5" letterSpacing="1"
                         borderColor="#eeeeee" borderStyle="solid"
                         paddingTop="5" paddingRight="5" paddingLeft="5" paddingBottom="5" />

            <mx:TextArea id="outputTxt" width="100%" height="480" leading="5" letterSpacing="1"
                         borderColor="#eeeeee" borderStyle="solid"
                         verticalScrollPolicy="auto"
                         paddingTop="5" paddingRight="5" paddingLeft="5" paddingBottom="5" />

        </mx:HBox>

    </mx:VBox>

    <mx:Canvas width="100%" height="100%" backgroundColor="#000000" backgroundAlpha=".3" visible="false" id="maskPanel">
        <mx:HBox width="130" height="50" horizontalCenter="0" verticalCenter="0"
                 backgroundColor="#ffffff" verticalAlign="middle" horizontalAlign="center">
            <mx:Text horizontalCenter="0" verticalCenter="0" text="正在处理..." fontSize="16" fontWeight="bold" color="#3399cc"  />
        </mx:HBox>
    </mx:Canvas>

</mx:Canvas>