as3 模拟“抛”的动作

以一个小球为示例，在鼠标点击的时修改它的加速度值(在短时间内移动的距离)，加速度以一个值加速，在遇到边界时进行反向。

代码参考自：《ActionScript 3.0 动画教程》，添加了拖动时的范围限定<在整个文档内进行拖动>。

Ball.as

package
{
    import flash.display.Sprite;

    /**
     * ...
     * @author ...
     */
    public class Ball extends Sprite
    {
        public var radius:Number;
        private var color:uint;
        public var vx:Number;
        public var vy:Number;

        public function Ball(radius:Number=40, color:uint=0xff0000)
        {
            this.radius = radius;
            this.color = color;

            init();
        }

        private function init():void {
            graphics.clear();
            graphics.beginFill(color);
            graphics.drawCircle(0, 0, radius);
            graphics.endFill();
        }

    }

}

 

Throwing.as

package
{
    import flash.accessibility.Accessibility;
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.geom.Rectangle;

    /**
     * ...
     * @author ...
     */
    public class Throwing extends Sprite
    {

        private var ball:Ball;
        private var vx:Number;
        private var vy:Number;
        private var bounce:Number = -0.7;
        private var gravity:Number = .5;
        private var oldX:Number;
        private var oldY:Number;

        public function Throwing()
        {
            init();
        }

        private function init():void {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;

            ball = new Ball();
            ball.x = stage.stageWidth / 2;
            ball.y = stage.stageHeight / 2;
            vx = Math.random() * 10 - 5;
            vy = -10;

            addChild(ball);
            ball.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }

        private function onMouseDown(evt:MouseEvent):void {
            oldX = ball.x;
            oldY = ball.y;

            stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);

            ball.startDrag(false, new Rectangle(ball.radius, ball.radius,stage.stageWidth - ball.radius*2, stage.stageHeight - ball.radius*2));

            removeEventListener(Event.ENTER_FRAME, onEnterFrame);
            addEventListener(Event.ENTER_FRAME, trackVelocity);
        }

        private function onMouseUp(evt:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
            ball.stopDrag();
            removeEventListener(Event.ENTER_FRAME, trackVelocity);
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }

        private function trackVelocity(evt:Event):void {
            vx = ball.x - oldX;
            vy = ball.y - oldY;

            oldX = ball.x;
            oldY = ball.y;
        }

        private function onEnterFrame(evt:Event):void {
            vx += gravity;
            ball.x += vx;
            ball.y += vy;
            var left:Number = 0;
            var right:Number = stage.stageWidth;
            var top:Number = 0;
            var bottom:Number = stage.stageHeight;

            if (ball.x + ball.radius > right) {
                ball.x = right - ball.radius;
                vx *= bounce;
            } else if (ball.x - ball.radius < left) {
                ball.x = left + ball.radius;
                vx *= bounce;
            }

            if (ball.y + ball.radius > bottom) {
                ball.y = bottom - ball.radius;
                vy *= bounce;
            } else if (ball.y - ball.radius < top) {
                ball.y = top + ball.radius;
                vy *= bounce;
            }

        }

    }

}