加载动画

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.geom.Matrix;
    import flash.geom.Point;

    public class LoadMotion extends Sprite {
        public static const STYLE_RECT:int = 0;
        public static const STYLE_CIRCLE:int = 1;
        public static const STYLE_SQUARE:int = 2;
        private var _defaultStyle:int = 1;
        private var _color:uint = 0;
        private var _itemNum:int = 9;
        private var _refreshFrame:int = 1;
        private var _box:Sprite;

        public function get refreshFrame():int {
            return _refreshFrame;
        }
        private var degree:Number;

        /**
         * 刷新间隔的帧数
         * @param value
         *
         */
        public function set refreshFrame(value:int):void {
            if (value < 1) {
                _refreshFrame = 1;
            } else {
                _refreshFrame = value;
            }
        }
        /**
         * 转动速度
         */
        public var rotateSpeed:int = 1;
        private var _dir:int = 1;

        /**
         *
         * @param color
         * @param radius 每个子块到中心的距离
         * @param maxNum 子块数目
         * @param style 子块样式
         * @param dir 转动方向
         *
         */
        public function LoadMotion(color:int = 0xffffff, radius:int = 50, itemNum:int = 9, style:int = STYLE_CIRCLE, dir:int = 1) {
            _color = color;
            _itemNum = itemNum;
            _defaultStyle = style;
            _dir = dir;
            _box = new Sprite();
            degree = 360 / _itemNum;
            _refreshFrame = Math.ceil(degree / 5);
            var factor:Number = 1 / itemNum;

            for (var i:int = 0; i < _itemNum; i++) {
                var item:Sprite = buildItem();
                item.rotation = i * degree * _dir;
                var pt:Point = new Point(radius);
                pt = rotatePoint(item.rotation * Math.PI / 180, pt);
                item.x = pt.x;
                item.y = pt.y;
                var v:Number = factor * i;
                item.alpha = v;
                item.scaleX = item.scaleY = v;
                _box.addChild(item);
            }

            _box.cacheAsBitmap = true;
            addChild(_box);
        }

        private function rotatePoint(radian: Number, pt: Point, center: Point = null):Point {
            if (center == null) {
                center = new Point();
            }
            var matrix:Matrix = new Matrix(1, 0, 0, 1, pt.x - center.x, pt.y - center.y);
            matrix.rotate(radian);
            return new Point(matrix.tx + center.x, matrix.ty + center.y);
        }

        public function start():void {
            addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
        }

        public function stop():void {
            removeEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
        }

        private var _counter:int = 0;

        private function onEnterFrameHandler(e: Event):void {
            if (_counter % refreshFrame == 0) {
                _box.rotation += _dir * degree * rotateSpeed;
                _counter = 0;
            }
            _counter += 1;
        }

        private function buildItem():Sprite {
            var item:Sprite = new Sprite();
            item.graphics.beginFill(_color);
            if (_defaultStyle == STYLE_CIRCLE) {
                item.graphics.drawCircle(-5, -5, 10);
            } else if (_defaultStyle == STYLE_RECT) {
                item.graphics.drawRect(-10, -5, 20, 10)
            } else if (_defaultStyle == STYLE_SQUARE) {
                item.graphics.drawRect(-10, -10, 20, 20)
            }
            item.graphics.endFill();
            return item;
        }
    }
}