[UnityShader学习日志]3.第七章实验代码记录

第七章-基础纹理

目录

提要

  • 本节介绍了有关纹理的一些操作，了解了有关纹理映射的技术

纹理采样

  • 纹理：先简单理解成一张图片，在渲染过程中，纹理用来表现表面的漫反射颜色
  • 纹素：一张4x4的纹理，有16个纹素，256x256的纹理，包含256x256个纹素，每个纹素具有单一的颜色。简单来说就是对纹理进行像素的切分
  • uv坐标：uv用来确定一个纹素在某张纹理上的位置。由于纹理的大小各异，我们希望能用同一个范围内的坐标来表示所有大小的纹理的uv坐标，因此uv都是归一化后的坐标，区间为[0,1],需要渲染一个物体时，首先需要有这个物体的模型（顶点数据），以及某一个顶点对应图片的哪一个坐标，所以 uv 坐标是存放在顶点数据中的。在模型中，每一个顶点有一个属性，表示uv坐标。在3d游戏中，3d建模人员在建模软件中完成顶点绑定纹理坐标的操作。
  • 纹理采样：给定一个 uv 坐标和一张纹理，获得这张纹理在 uv 坐标处的纹素的颜色值。这个过程就是纹理采样。GPU 中有专门的纹理采样硬件单元。
  • 在ShaderLab中，我们会在顶点着色器中获取uv坐标，在片元着色器中完成纹理采样及相关计算

实验1-1 单张纹理

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/SingelTexture"
{
    Properties
    {
        _Color ("Color Tint",Color) = (1,1,1,1)
        _MainTex("Main Tex",2D) = "white"{}
        _Specular("SPECULAR",COLOR) = (1,1,1,1)
        _Gloss("Gloss",Range(8.0,256)) = 20

    }
    SubShader
    {


        Pass
        {
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

                o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;//即用纹理的属性对顶点的纹理坐标进行变换，得到uv坐标

                return o;

            }

            fixed4 frag(v2f i) : SV_TARGET0
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));//处理更复杂的光源类型

                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                //高光反射
                fixed3 viewDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);

                return fixed4(ambient + diffuse + specular,1.0);



            }
            ENDCG
        }
    }
}

  • 关于_MainTex_ST:为了使用纹理，我们在属性中加入了2D类型的 _MainTex，当我们在Pass里声明属性时，还要额外加入一个_MainTex_ST,可以看出我们使用它是为了对模型的纹理坐标进行变换，也就是说它包含了纹理的一些信息，xy是缩放量，zw是偏移量，我们也可以在编辑器中找到:

  • 在上一节中，提到了材质的漫反射系数，而这一次，材质的漫反射系数将引入纹理来计算，albedo即是这个新的系数,ambient环境光也会随之改变

实验2-1 法线纹理（切线空间下）

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/NormalMapTangentSpace"
{
    Properties
    {
        _Color ("Color Tint",COLOR) = (1,1,1,1)
        _MainTex ("Main Tex",2D) = "white" { }
        _BumpMap ("Normal Map",2D) = "bump" { }
        _BumpScale ("Bump Scale",Float) = 1.0
        _Specular ("SPECULAR",COLOR) = (1,1,1,1)
        _Gloss ("Gloss",Range(8.0,256)) = 20

    }
    SubShader
    {

        Pass
        {
            Tags{"LightMode" = "ForwardBase"}

            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            float _BumpScale;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
              float4 pos :  SV_POSITION;
              float4 uv : TEXCOORD0;
              float3 lightDir : TEXCOORD1;
              float3 viewDir : TEXCOORD2;
              
            };


            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
                
                //叉乘法线与切线，得到副切线
                //切线的w分量记录副切线的方向
                float3 binormal = cross(normalize(v.normal),normalize(v.tangent.xyz)) * v.tangent.w;

                //构造矩阵变换(行排列)
                float3x3 rotation = float3x3(v.tangent.xyz,binormal,v.normal);

                //变换到切线空间
                o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;                                     
                o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

                return o;

            }

            fixed4 frag(v2f i) : SV_TARGET0
            {
                fixed3 tangentLightDir = normalize(i.lightDir);
                fixed3 tangentViewDir = normalize(i.viewDir);

                fixed4 packedNormal = tex2D(_BumpMap,i.uv.zw);//法线纹理采样
                fixed3 tangentNormal;

                tangentNormal = UnpackNormal(packedNormal);//得到切线方向下的法线方向
                tangentNormal.xy *=_BumpScale;
                tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(tangentNormal,tangentLightDir));
                
                fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss);


                return fixed4(ambient + diffuse + specular,1.0);

            }



        
            ENDCG
        }
    }
}

实验2-2 法线纹理（世界空间下）

  • 一开始给出的法线纹理是切线空间下的（呈浅蓝色），也因此若要在世界空间下计算，我们需要在片元着色器中把法线纹理中的法线方向从切线空间变换到世界空间下
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/NormalMapWorldSpaceMat"
{
    Properties
    {
        _Color ("Color Tint",Color) = (1,1,1,1)
        _MainTex ("MainTex",2D) = "white" { }
        _BumpMap ("BumpMap",2D) = "bump" { }
        _BumpScale ("BumpScale",Float) = 1.0
        _Specular ("SPECULAR",COLOR) = (1,1,1,1)
        _Gloss ("Gloss",Range(8.0,256)) = 20
    }
    SubShader
    {
           Tags{"LightMode" = "ForwardBase"}

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            float4 _BumpMap_ST;
            float _BumpScale;
            fixed4 _Specular;
            float _Gloss;

            struct a2v
            {   
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float4 uv : TEXCOORD0;
                float4 TtoW0 : TEXCOORD1;
                float4 TtoW1 : TEXCOORD2;
                float4 TtoW2 : TEXCOORD3;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                
                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
                o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

                fixed3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;//存储世界空间下的顶点坐标
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
                fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
                fixed3 worldBinormal = cross(worldNormal,worldTangent) * v.tangent.w;

                //列摆放变换矩阵
                o.TtoW0 = float4(worldTangent.x,worldBinormal.x,worldNormal.x,worldPos.x);
                o.TtoW1 = float4(worldTangent.y,worldBinormal.y,worldNormal.y,worldPos.y);
                o.TtoW2 = float4(worldTangent.z,worldBinormal.z,worldNormal.z,worldPos.z);

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET0
            {
                float3 worldPos = float3(i.TtoW0.w,i.TtoW1.w,i.TtoW1.w);
                fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));

                fixed3 bump = UnpackNormal(tex2D(_BumpMap,i.uv.zw));
                bump.xy *= _BumpScale;
                bump.z = sqrt(1.0 - saturate(dot(bump.xy,bump.xy)));
                bump = normalize(half3(dot(i.TtoW0.xyz,bump),dot(i.TtoW1,bump),dot(i.TtoW2,bump)));//变换到世界空间

                 fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(bump,lightDir));
                
                fixed3 halfDir = normalize(lightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(bump,halfDir)),_Gloss);
                return fixed4(ambient + diffuse + specular,1.0);
            }


            ENDCG
        }
    }
}

  • 两种法线纹理与普通纹理，其实大致一样

实验3-1 渐变纹理

  • 通过渐变纹理+半Lambert，可以得到一种特殊效果的漫反射
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/RampTexture"
{
    Properties
    {
        _Color ("Color Tint",COLOR) = (1,1,1,1)
        _RampTex ("Ramp Text",2D) = "white" { }
        _specular ("SPECULAR",COLOR) = (1,1,1,1)
        _Gloss ("Gloss",Range(8.0,256)) = 20
    }
    SubShader
    {
        Tags{"LightMode" = "ForwardBase"}


        Pass
        {
            CGPROGRAM
// Upgrade NOTE: excluded shader from
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"
            
            fixed4 _Color;
            sampler2D _RampTex;
            float4 _RampTex_ST;
            fixed4 _specular;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;

                o.uv = v.texcoord.xy * _RampTex_ST.xy + _RampTex_ST.zw;

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET0
            {  
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                //半兰伯特光照模型
                fixed halfLambert = 0.5 * dot(worldNormal,worldLightDir) + 0.5;
                fixed3 diffuseColor = tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;

                fixed3 diffuse = _LightColor0.rgb * diffuseColor;

                //计算高光反射
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);

                return fixed4(ambient+diffuse+specular,1.0);
            }
            ENDCG
        }
    }
}

实验4-1 遮罩纹理

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/MaskTexture"
{
    Properties
    {
        _Color ("Color Tint",COLOR) = (1,1,1,1)
        _MainTex ("MainTex", 2D) = "white" { }
        _Specular ("SPECULAR",COLOR) = (1,1,1,1)
        _SpecularMask ("Specular Mask",2D) = "white" { }
        _SpecularScale ("Specular Scale",Float) = 1.0
        _Gloss ("Gloss",Range(8.0,256)) = 20
        _BumpMap ("Normal Map",2D) = "bump" { }
        _BumpScale ("BumpScale",Float) = 1.0
    }
    SubShader
    {
        Tags{"LightMode" = "ForwardBase"}

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            sampler2D _BumpMap;
            fixed4 _Specular;
            sampler2D _SpecularMask;
            float _BumpScale;
            float _SpecularScale;
            float _Gloss;

            struct a2v
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 tangent : TANGENT;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float2 uv : TEXCOORD0;
                float3 lightDir : TEXCOORD1;
                float3 viewDir : TEXCOORD2;
            };

            v2f vert(a2v v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;

                TANGENT_SPACE_ROTATION;

                o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
                o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET0
            {
                fixed3 tangentLightDir = normalize(i.lightDir);
                fixed3 tangentViewDir = normalize(i.viewDir);

                fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap,i.uv));
                tangentNormal.xy *= _BumpScale;
                tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy,tangentNormal.xy)));

                fixed3 albedo = tex2D(_MainTex,i.uv).rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(tangentNormal,tangentLightDir));

                fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);

                fixed specularMask = tex2D(_SpecularMask,i.uv).r * _SpecularScale;
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss) * specularMask;

                return fixed4(ambient + diffuse + specular,1.0);

            }

            ENDCG
        }
    }
}
posted @ 2023-05-05 11:06  月牙同学  阅读(30)  评论(0)    收藏  举报