Visual Studio 配置使用

修复appverifUI.dll、vfcompat.dll在C盘根目录的残留

vs在安装后在C盘的根目录下会存在appverifUI.dll、vfcompat.dll两个文件可以通过bat脚本将他们移动到正确的位置。

来源：stackoverflow

@echo off
setlocal

set "COMP=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Installer\UserData\S-1-5-18\Components"
set "OUT_DIR=C:\Windows\SysWOW64"
goto :Process

:Fix
set "KEY=%COMP%\%~1"
set "OLD_FILE=%~2"
set "NEW_FILE=%~3"

for /f "tokens=1,2,*" %%A in ('reg query "%KEY%" 2^>nul') do (
    if "%%B"=="REG_SZ" if /i "%%C"=="%OLD_FILE%" (
        set "VAL=%%A"
        goto :Found
    )
)

echo.Value %OLD_FILE% not found in %KEY%
goto :CheckFile

:Found
reg add "%KEY%" /v "%VAL%" /t REG_SZ /d "%NEW_FILE%" /f && echo.Registry component %KEY%\%VAL% fixed || echo.Failed to update registry

:CheckFile
if exist "%OLD_FILE%" (
    move /Y "%OLD_FILE%" "%NEW_FILE%" && echo.%OLD_FILE% successfully moved to %NEW_FILE% || echo.Failed to move %OLD_FILE%
) else (
    echo.%OLD_FILE% does not exist, nothing to move
)
goto :EOF

:Process
call :Fix "0AF818DE4685190F5347FAF54BD80C82" "C:\appverifUI.dll" "%OUT_DIR%\appverifUI.dll"
call :Fix "E0C37F311948CF28AE087B694A681271" "C:\vfcompat.dll" "%OUT_DIR%\vfcompat.dll"

endlocal

使用管理员运行上述bat脚本。

字体调节

默认的是新宋体，这个字体会导致中英文的逗号非常相似，不容易区分。

工具 > 选项 > 环境 > 字体和颜色

我这里把字体改成了Consolas