按键消抖（边沿检测）

1、按键消抖（边沿检测）

//仅支持单次模式的按键检测电路设计
module key_single(
    input  wire         clk_in,
    input  wire         rst_n,
    input  wire         key_i,
    output reg          pulse_ctrl_o
);

    //两级触发器避免亚稳态，得到key_cur_r     
    reg key_syn_r;//两级触发器避免亚稳态--第1级
    reg key_cur_r;//两级触发器避免亚稳态--第2级
    
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)begin
            key_syn_r  <= 1'b1;//按键正常(或松开)是高电平
            key_cur_r  <= 1'b1;
        end
        else begin
            key_syn_r  <= key_i;//按键正常(或松开)是高电平
            key_cur_r  <= key_syn_r;
        end
    end
    
    //边沿检测电路
    reg key_last_r;//将key_cur_r延缓一拍，相当于记录key_cur_r上次值
    
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)
            key_last_r <= 1'b1;
        else 
            key_last_r <= key_cur_r;//按键正常是高电平
    end
        
    //下降沿检测
    reg edge_neg_r; 
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)
            edge_neg_r    <= 1'b0;
        else begin
                //上一时刻为1，且当前时刻为0，代表下降沿
            if(key_last_r == 1'b1 && key_cur_r==1'b0)
                edge_neg_r <= 1'b1;//大概率仅维持1个时钟宽度
            else
                edge_neg_r <= 1'b0;
        end
    end
    
    //上升沿检测
    reg edge_pos_r; 
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)
            edge_pos_r    <= 1'b0;
        else begin
                //上一时刻为0，且当前时刻为1，代表下降沿
            if(key_last_r == 1'b0 && key_cur_r==1'b1)
                edge_pos_r <= 1'b1;//仅维持1个时钟宽度
            else
                edge_pos_r <= 1'b0;
        end
    end    
    
    //延时计数器  
    //cnt_20ms_r常置为0，edgepos_r或edgeneg_r只要有一个为1，cnt_20ms_r置为1  
    //cnt_20ms_r只要不为0，就自动累加，加到0就保持在0，当前自加的过程中，  
    //edge_pos_r或edge_neg_r只要有一个为1立即重新置为1，相当于重启  
    reg [19:0]cnt_20ms_r;//1_058_575*20ns≈20ms 
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)
            cnt_20ms_r    <= 20'd0;
        else begin
            if((edge_neg_r || edge_pos_r)==1'b1)//重启
                cnt_20ms_r <=20'd1;
            else if(cnt_20ms_r == 20'd0 )     //停止
                cnt_20ms_r <= cnt_20ms_r;
            else
                cnt_20ms_r <= cnt_20ms_r+20'd1;//启动后则一直加满，则回到0停止
        end
    end
    
    // 根据cnt_20ms_r值和当前按键值判定：按键是否按下或者松开
    always@(posedge clk_in or negedge rst_n)begin
        if(!rst_n)
            pulse_ctrl_o    <= 1'b0;
        else begin//20'd999999也可换做附近值如20'hfffff 
            if(cnt_20ms_r==20'd999999 && key_last_r==1'b0 && key_cur_r==1'b0)
                pulse_ctrl_o <= 1'b1;//一个脉冲宽度
            else
                pulse_ctrl_o <= 1'b0;
        end
    end
    
endmodule

2、仿真测试

`timescale 1ns/1ns        // 时间单位1ns/精度1ns

module key_single_tb();

    // 测试信号定义
    reg     clk;        // 50MHz时钟
    reg     rst_n;      // 低电平复位
    reg     key_in;     // 按键输入(0:按下, 1:松开)
    wire     key_out;   // 消抖后输出

    // 实例化被测模块
    key_single key_single_inst(
        .clk_in            (clk),
        .rst_n            (rst_n),
        .key_i            (key_in),
        .pulse_ctrl_o    (key_out)
    );

    // 时钟生成 (50MHz, 周期20ns)
    initial begin
         clk = 0;
         forever #10 clk = ~clk;
    end

    // 测试激励
    initial begin
         rst_n = 0;                 // 初始化
         key_in = 1;                 // 初始状态为松开
         #200; rst_n = 1;            // 复位操作

         // 模拟按键按下(20us后按下)
         #2_000_000; key_in = 0;
         repeat(5)    key_bounce; // 模拟10次按键抖动(按下过程)

         // 模拟稳定按下(100ns后按下，保持40us)
         #100; key_in = 0;
         #30_000_000;

         // 模拟按键释放(200ns后释放)
         #200; key_in = 1;
         repeat(3)    key_bounce; // 模拟8次按键抖动(释放过程)

         #100; key_in = 1;        // 最终保持释放状态(100ns后松开，保持50us)
         #2_000_000;
         $stop;                        // 停止仿真
    end

    task key_bounce;                    // 按键抖动任务定义
        begin
            @(posedge clk); #2;        // 同步到时钟上升沿后2ns
            key_in = 0;                  // 模拟按下
            #({$random}%1024);        // 随机延时(0-1023ns)
            @(posedge clk); #2;        // 再次同步时钟
            key_in = 1;                 // 模拟释放
            #({$random}%1024);        // 随机延时(0-1023ns)
        end
    endtask

endmodule