详细介绍：【AI大模型】WPS 接入DeepSeek 实战项目详解

随着当下国产大模型DeepSeek的走红，与之相关的应用领域也正在逐步接入DeepSeek，从而提升自己的竞争力，除了各大互联网巨头之外，比如像阿里云的百炼平台，硅基流动，字节的火山引擎等，都已经基于自身的平台与DeepSeek完成了整合，与此同时，一些开源的工具软件为了提升自己的AI能力，完善用户的使用体验，也开始支持对DeepSeek的模型配置能力，本文将详细介绍如何在wps中对接DeepSeek。

二、WPS接入AI工具的两种方式

要对接DeepSeek关键有两种方式。就是目前WPS中，以word或excel来说，要

2.1 手动配备的方式

手动安装，即通过一些底层的参数配置方式来搭建，具体来说，像world或excel，都是支持VB插件的，而VB具备代码编程的能力，于是能够借助VB插件作为桥接，从而将AI大模型产品集成进去使用。

2.2 Office AI助手

Office AI是一款AI插件，许可理解为专为Office 办公软件而生的一款AI插件，基于这个插件的代理能力，用户可以在Office AI中配置指定的第三方大模型，从而达到利用外部AI大模型的能力。

三、WPS手动配置的方式接入AI大模型

以WPS中word为例进行执行演示。

3.1 安装VBA

为WPS默认不支持VB编辑器（Visual Basic forApplication），所以得先手动安装插件

3.1.1 下载VBA插件并安装

将下载的VBA插件放到本地的目录，然后安装即可

3.2 配置WPS

手动创建一个word文档，接着使用wps打开

打开：文件->选型，弹出下面的框

找到左侧的"自定义功能区"，继而勾选下面的"工具"选项

上一步保存完成后，再次进入，切换为 "信任中心"，找到右侧的 "宏安全性"，在弹框中勾选最下面的那一栏 "低"

同时在信任中心中，勾选下图中的两个选项，勾选完毕后点击确定

3.3 配置VB

基于上面配置完成之后，再在导航栏顶部，通过点击"设备"，可以看到在这一栏中就看到了一个 VB编辑器的工具

点击VB编辑器进入下面的窗口

在当前的工程下插入一个模块

这样会打开一个代码编辑的窗口，然后将下面的代码粘贴到输入框中

Function CallDeepSeekAPI(api_key As String, inputText As String) As String
    Dim API As String
    Dim SendTxt As String
    Dim Http As Object
    Dim status_code As Integer
    Dim response As String
    API = "https://dashscope.aliyuncs.com/compatible-mode/v1/chat/completions"
    SendTxt = "{""model"": ""qwen-max-0125"", ""messages"": [{""role"":""system"", ""content"":""请根据用户的问题给出详细的解答。""}, {""role"":""user"", ""content"":""" & inputText & """}]}"
    Set Http = CreateObject("MSXML2.XMLHTTP")
    With Http
        .Open "POST", API, False
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "Authorization", "Bearer " & api_key
        .send SendTxt
        status_code = .Status
        response = .responseText
    End With
    ' 弹出窗口显示 API 响应（调试用）
    ' MsgBox "API Response: " & response, vbInformation, "Debug Info"
    If status_code = 200 Then
        CallDeepSeekAPI = response
    Else
        CallDeepSeekAPI = "Error: " & status_code & " - " & response
    End If
    Set Http = Nothing
End Function
Sub qwen2_5()
    Dim api_key As String
    Dim inputText As String
    Dim response As String
    Dim regex As Object
    Dim matches As Object
    Dim originalSelection As Object
    api_key = "填写你的API-KEY"
    If api_key = "" Then
        MsgBox "Please enter the API key."
        Exit Sub
    ElseIf Selection.Type <> wdSelectionNormal Then
        MsgBox "Please select text."
        Exit Sub
    End If
    ' 保存原始选中的文本
    Set originalSelection = Selection.Range.Duplicate
    inputText = Replace(Replace(Replace(Replace(Replace(Selection.text, "\", "\\"), vbCrLf, ""), vbCr, ""), vbLf, ""), Chr(34), "\""")
    response = CallDeepSeekAPI(api_key, inputText)
    If Left(response, 5) <> "Error" Then
        Set regex = CreateObject("VBScript.RegExp")
        With regex
            .Global = True
            .MultiLine = True
            .IgnoreCase = False
            .Pattern = """content"":""(.*?)"""
        End With
        Set matches = regex.Execute(response)
        If matches.Count > 0 Then
            response = matches(0).SubMatches(0)
            ' 处理换行符和特殊字符
            response = Replace(response, "\n\n", vbNewLine)  ' 双换行替换为真实的单换行
            response = Replace(response, "\n", vbNewLine)  ' 单换行替换为真实的换行
            response = Replace(Replace(response, """", Chr(34)), """", Chr(34))
            ' 取消选中原始文本
            Selection.Collapse Direction:=wdCollapseEnd
            ' 将内容插入到选中文字的下一行
            Selection.TypeParagraph ' 插入新行
            Selection.TypeText text:=response
            ' 将光标移回原来选中文本的末尾
            originalSelection.Select
        Else
            MsgBox "Failed to parse API response.", vbExclamation
        End If
    Else
        MsgBox response, vbCritical
    End If
End Sub