实验4 汇编应用编程和c语言程序反汇编分析

一 实验结论

1.实验任务1

教材「实验9 根据材料编程」(P187-189)

编程：在屏幕中间分别显示绿色、绿底红色、白底蓝色的字符串'welcome to masm!'。

assume cs:codesg, ds:datasg, ss:stacksg

datasg segment
    db 'welcome to masm!'                       
    db 02H, 0A4H, 71H, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0    
    dw 11*160+64, 12*160+64, 13*160+64, 0, 0, 0, 0, 0     
datasg ends

stacksg segment       
    dw 0,0,0,0,0,0,0,0
stacksg ends

codesg segment
start:
    mov ax, stacksg     ; 设置栈段
    mov ss, ax      
    mov sp, 16

    mov ax, datasg      ; 设置数据段
    mov ds, ax

    mov ax, 0B800H    
    mov es, ax

    mov cx, 3      
    mov bx, 16     
    mov di, 32   

s0: push cx        
    mov cx, 16      
    mov bp, [di]        
    mov si, 0

s1: 
    mov al, [si]        ; 低位字节写存储字符的ASCII码
    mov ah, [bx]        ; 高位字节写存储字符的属性
    mov es:[bp], ax

    inc bp
    inc bp         
    inc si        
    loop s1

    pop cx
    add bx, 1      
    add di, 2       
    loop s0

    mov ax,4c00H
    int 21H

codesg ends

end start

对程序进行汇编和链接

 运行程序，屏幕上出现了绿底红色、白底蓝色的字符串'welcome to masm!'

说明：

列偏移位置应该为160/2-16，因为字符串送入的行数为12、13、14行，每一行的开始的偏移地址为：11*160+64、12*160+64、13*160+64

2.实验任务

编写子程序printStr，实现以指定颜色在屏幕上输出字符串。调用它，完成字符串输出。

代码如下：

assume cs:code, ds:data
data segment

  str db 'try', 0

data ends
code segment
start:  
    mov ax, data
    mov ds, ax

    mov si, offset str
    mov al, 2
    call printStr

    mov ah, 4ch
    int 21h

printStr:
    push bx
    push cx
    push si
    push di

    mov bx, 0b800H
    mov es, bx
    mov di, 0
s:      mov cl, [si]
    mov ch, 0
    jcxz over
    mov ch, al
    mov es:[di], cx
    inc si
    add di, 2
    jmp s

over:   pop di
    pop si
    pop cx
    pop bx
    ret

code ends
end start

对程序进行汇编和链接

 运行程序，观察结果

对源程序做如下修改：

把line3改为:

str db 'another try', 0

把line12改为：

mov al, 4

改完之后，汇编，链接运行程序

基于运行结果，理解源代码，以及，组合使用转移指令call和ret实现子程序的原理与方法。具体地，在line18-40中：

line19-22, line36-39，这组对称使用的push、pop，这样用的目的是什么？

对称使用push和pop是将子程序使用的寄存器中的内容保存起来，执行子程序就可以使用者4个寄存器，在子程序结束时再恢复di、si、cx、bx的值。

line30的功能是什么？

改变字符的颜色属性

3.实验任务3

使用任意文本编辑器，录入汇编源程序task3.asm。

子程序num2str：

功能：把0~2559之间的任意整数转换成数字字符串，例如，把1984转换成'1984'

入口参数

要转换的整数 —> ax

数字字符串的起始地址 —> ds:di （其中：数字字符串所在段的段地址—> ds，字符串

起始地址的偏移地址—>di）

出口参数：无

代码如下：

assume cs:code, ds:data
data segment
    x    dw 1984
    str  db 16 dup(0)
data ends

code segment
    start:  
            mov  ax, data
            mov  ds, ax
            mov  ax, x
            mov  di, offset str
            call num2str

            mov  ah, 4ch
            int  21h

    num2str:
            push ax
            push bx
            push cx
            push dx
        
            mov  cx, 0
            mov  bl, 10
    s1:     
            div  bl
            inc  cx
            mov  dl, ah
            push dx
            mov  ah, 0
            cmp  al, 0
            jne  s1
    s2:     
            pop  dx
            or   dl, 30h
            mov  [di], dl
            inc  di
            loop s2
        
            pop  dx
            pop  cx
            pop  bx
            pop  ax

            ret
code ends
end start

子任务1

对task3.asm进行汇编、链接，得到可执行程序后，在debug中使用u命令反汇编，使用g命令执行到line15(程序退出之前)，使用d命令查看数据段内容，观察是否把转换后的

数字字符串'1984'存放在数据段中str标号后面的单元。

 

可以看到1984已经存放在数据段中str标号后面的单元里

子任务2

对task3.asm源代码进行修改、完善，把task2.asm中用于输出以0结尾的字符串的子程序加进来，实现对转换后的字符串进行输出。

代码为：

assume cs:code, ds:data
data segment
        x dw 1984
        str db 16 dup(0)
data ends

code segment
start:  
        mov ax, data
        mov ds, ax
        mov ax, x
        mov di, offset str
        call num2str
        mov si, offset str
        mov al,2
        call printStr
        mov ah, 4ch
        int 21h

num2str:
        push ax
        push bx
        push cx
        push dx
        
        mov cx, 0
        mov bl, 10
s1:      
        div bl
        inc cx
        mov dl, ah
        push dx
        mov ah, 0
        cmp al, 0
        jne s1
s2:        
        pop dx
        or dl, 30h
        mov [di], dl
        inc di
        loop s2
        
        pop dx
        pop cx
        pop bx
        pop ax

        ret

printStr:
    push bx
    push cx
    push si
    push di

    mov bx, 0b800H
    mov es, bx
    mov di, 0
s:      mov cl, [si]
    mov ch, 0
    jcxz over
    mov ch, al
    mov es:[di], cx
    inc si
    add di, 2
    jmp s

over:   pop di
    pop si
    pop cx
    pop bx
    ret
code ends
end start

对程序进行汇编，链接和运行

把task3.asm源代码中，line3中整数改成0~2559之间的任意数值，运行测试，观察结果。 

4.实验任务4

使用任意文本编辑器，录入汇编源程序task4.asm。

代码如下：

assume cs:code, ds:data
data segment
    str  db 80 dup(?)
data ends

code segment
    start:
          mov  ax, data
          mov  ds, ax
          mov  si, 0

    s1:   
          mov  ah, 1       
          int  21h
          mov  [si], al    
          cmp  al, '#'     
          je   next        
          inc  si          
          jmp  s1          
    next: 
          mov  cx, si      
          mov  si, 0
    s2:   mov  ah, 2       
          mov  dl, [si]    
          int  21h
          inc  si          
          loop s2     

          mov  ah, 4ch
          int  21h
code ends
end start

对程序进行汇编链接和运行

line12-19实现的功能是？

利用int 21h中的1号子功能，如果遇到#就结束输入，跳转到标号为next 的代码段，如果没有遇到#就继续输入。

line21-27实现的功能是？

利用int 21h中的2号子功能，将存储在ds:[si]的字符输出到屏幕上。

5.实验任务5

在visual studio集成环境中，编写一个简单的包含有函数调用的c程序。代码如下：

#include <stdio.h> 
int sum(int, int); 
int main() 
{ int a = 2, b = 7, c; 
c = sum(a, b); 
return 0; }
int sum(int x, int y) 
{ return (x + y); }

参数传递和返回值是通过栈实现的，参数入栈的顺序为从右向左入栈，先借助寄存器，将参数b 的地址压入堆栈寄存器eax,再将参数a 的值压入堆栈寄存器ecx。函数返回时通过寄存器返回。