图像处理-绘制位图笔触

package
{
    import flash.display.BitmapData;
    import flash.display.Shape;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    
    public class test005 extends Sprite
    {
        
        public function test005()
        {
            stage.addEventListener(MouseEvent.MOUSE_DOWN,mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP,mouseUpHandler);
        }
        
        private function mouseDownHandler(event:MouseEvent):void
        {
            createBrushStroke();
            this.graphics.moveTo(mouseX,mouseY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE,moveHandler);
            
        }    
        
        private function mouseUpHandler(event:MouseEvent):void
        {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE,moveHandler);
        }
        
        private function moveHandler(event:MouseEvent):void
        {
            this.graphics.lineTo(mouseX,mouseY);
            event.updateAfterEvent();
        }
        
        private function createBrushStroke():void
        {
            var radius:uint = Math.random()*10+2;
            var diameter:uint = radius*2;
            var shape:Shape = new Shape();
            shape.graphics.beginFill(Math.random()*0xFFFFFF);
            shape.graphics.drawCircle(radius,radius,radius);
            shape.graphics.endFill();
            var brushStroke:BitmapData = new BitmapData(diameter,diameter,true,0x00000000);
            brushStroke.draw(shape);
            this.graphics.lineStyle(diameter);
            this.graphics.lineBitmapStyle(brushStroke);
            
        }
        
    }
}