触发器

1. 触发器相关概念及语法

1.1 oracle触发器概述

什么是触发器（trigger）？
	触发器是在事件发生时隐式地自动运行的PL/SQL程序块，不能接收参数，不能被调用
	特殊的存储过程

1.2 触发器的概念和第一个触发器

一个与表相关联的、存储的PL/SQL程序
作用：当一个特定的数据操作语句（insert 、update 、 delete）在指定的表上发出时，Oracle自动地执行触发器中定义的语句序列。

第一个触发器：每当成功插入一个新员工后，自动打印“成功插入新员工”；
create trigger saynewemp 
after insert 
on emp
declare
begin
    dbms_output.put_line('成功插入新员工');
end;
/

1.3 触发器的应用场景

1.复杂的安全性检查
2.数据的确认
3.实现审计功能（数据库审计，基于值的审计）
4.完成数据的备份和同步

1.4 触发器的语法和类型

语法：
	CREATE [or REPLACE] TRIGGER 触发器名
	{BEFORE | AFTER}
	{DELETE | INSERT |UPDATE [OF 列名]}
	ON 表名
	[FOR EACH ROW [WHEN (条件)]]
	PLSQL块
	
类型：
	语句型触发器：在指定的操作语句之前或之后执行一次，不管这条语句影响了多少行。 针对是表。
	行级触发器：触发语句作用的每一条记录都被触发。在行级触发器中使用 :old和 :new伪记录变量，识别值的状态。针对是行 。

2 触发器应用

2.1 应用一 ： 复杂的安全性检查

-- 禁止在非工作时间插入新员工
-- 周末：to_char(sysdba,'day') in('星期六','星期日')
-- 上班前和下班后：to_number(to_char(sysdba,'hh24')) not between 9 and 18
-- 语句型触发器
create or replace trigger securityemp
before insert
on emp
begin 
    if to_char(sysdate,'day') in('星期六','星期日') or 
    to_number(to_char(sysdate,'hh24')) not between 9 and 18 then
        --禁止插入新员工
        raise_application_error(-20001,'禁止在非工作时间插入新员工');
    end if;
end;
/

2.2 应用二 ：数据的确认

-- 涨后的薪水不能少于涨前的薪水
-- :old和:new 代表同一条记录
-- :old 表示操作该行之前，这一行的值
-- :new 表示操作该行之后，这一行的值
-- 行级型触发器
create or replace trigger checksalary
before update
on emp
for each row
begin 
    if :new.sal<:old.sal then
        raise_application_error(-20002,'涨后的薪水不能少于涨前的薪水,涨后的薪水:'||:new.sal||',涨前的薪水:'||:old.sal);
    end if;
end;
/

2.3 应用三 ：实现审计功能-->基于值的审计

-- 给员工涨工资，当涨后的薪水超过6000元时，审计员工的信息
-- 行级型触发器
--创建表，用于保存审计信息
create table audit_info
(
    information varchar2(200)
);

create or replace trigger do_audit_emp_salary
after update
on emp
for each row
begin 
    if :new.sal>6000 then
        insert into audit_info values(:new.empno||' '||:new.ename||' '||:new.sal);
    end if;
end;
/

2.4 应用四 ：完成数据的备份和同步

-- 利用触发器实现数据的同步部分
-- 当给员工涨完工资后，自动备份新的工资到备份表中
-- 行级型触发器

create or replace trigger sync_salary
after update
on emp
for each row
begin 
    update emp_back set sal =:new.sal where empno=:new.empno;
end;
/