Bzoj 1016

题目大意：求可能的最小生成树有多少棵、

解：这个要用一些证明，这里只写自己的一些看完各神牛的blog后的想法总结，证明并不严谨。

首先我们用kruskal求最小生成树的原理是，用权值为c的边把一些强连通分量连起来，然后c从小到大递增，用并查集判可行性。如果反证伪，则在最后一步时，存在比c小的边把强连通分量连起来了，但kruskal的特性不会让这种事情发生。所以可以证明，在第n步，对于 相同的图 来说，如果存在不同的最小生成树，对应的不同只是在第n步选择的边的可能，而设原最小生成树的第n步用的边的大小为c，那么一定有其他最小生成树的第n步，用的边也一定是c，而且使用的边的数量相同，而且连接的强连通分量的点集一定相同（因为不同则从第一步开始，每个强连通分量都是点自己，如果比第一次做的点要多，说明有n-1条树边中，有的边变小了[如原来用a条c边，现在用b条c边，而多出来的b-a在原来的生成树中是大于c的]，所以违反了最小生成树的原理，同理可证少了），所以像构建最小生成树一样，从最小的边开始，在权值为c的边中，以2^p枚举可能，用乘法原理相乘即可。

//bzoj 1016 [JSOI2008] zuixiaoshengchengshujishu
const
        maxm=1111;
        maxn=111;
        inf='1.txt';
        def=31011;
type
        type_edge=record
          a, b: longint;
          cost: qword;
        end;
var
        edge: array[0..maxm]of type_edge;
        f, f_2:array[0..maxn]of longint;
        n, m: longint;
        cnt, ans, key: qword;
procedure qsort(b, e: longint);
var
        i, j, x: longint;
        k: type_edge;
begin
  i := b; j := e; x := edge[(i+j)>>1].cost;
  repeat
    while edge[i].cost<x do inc(i);
    while edge[j].cost>x do dec(j);
    if i<=j then begin
      k := edge[i]; edge[i] := edge[j]; edge[j] := k;
      inc(i); dec(j);
    end;
  until i>j;
  if j>b then qsort(b, j);
  if i<e then qsort(i, e);
end;

function getf(x: longint): longint;
begin
  if f[x] = x then exit(x);
  f[x] := getf(f[x]);
  exit(f[x]);
end;

function getfex(x: longint): longint;
begin
  if x=f_2[x] then exit(x);
  getfex := getfex(f_2[x]);
end;

procedure init;
var
        i: longint;
begin
  readln(n, m);
  for i := 1 to m do with edge[i] do readln(a, b, cost);
  for i := 1 to n do begin
    f[i] := i; f_2[i] := i;
  end;
  qsort(1, m);
  ans := 1; key := 0;
end;

procedure dfs(st, ed, num: longint);
var
        a, b: longint;
begin
  if num=0 then begin
    inc(cnt); exit;
  end;
  if st>ed then exit;
  a := getfex(edge[st].a); b := getfex(edge[st].b);
  if a<>b then begin
    f_2[a] := b;
    dfs(st+1, ed, num-1);
    f_2[a] := a;
  end;
  dfs(st+1, ed, num);
end;

function find(st, ed, num: longint): qword;
begin
  cnt := 0;
  dfs(st, ed, num);
  if cnt=0 then find := 1
    else find := cnt;
end;

procedure main;
var
        i, j, now, num, a, b: longint;
begin
  now := 1; num := 0;
  for i := 1 to m do begin
    if (i<>1)and(edge[i].cost<>edge[i-1].cost) then begin
      ans := ans * find(now, i-1, num) mod def;
      f_2 := f;
      num := 0;
      now := i;
    end;
    a := getf(edge[i].a); b := getf(edge[i].b);
    if a<>b then begin
      inc(key); inc(num);
      f[a] := b;
    end;
    if key=n-1 then break;
  end;
  while (i<m)and(edge[i].cost=edge[i+1].cost) do inc(i);
  ans := ans * find(now, i, num) mod def;
end;

procedure print;
begin
  if key=n-1 then writeln(ans)
    else writeln(0);
end;

begin
  assign(input,inf); reset(input);
  init;
  main;
  print;
end.