as3 vector 排序，数组排序，sort排序

package com.vini123
{

    import flash.display.Sprite;
    import com.vini123.model.ImageModel;
    
    public class Main extends Sprite
    {
        private var myXML:XML=
        <root>
             <images>
         <image index='1' url='1.jpg' filename='你的菜No1'/>
         <image index='3' url='3.jpg' filename='你的菜No3'/>
         <image index='2' url='2.jpg' filename='你的菜No2'/>
         <image index='4' url='4.jpg' filename='你的菜No4'/>
             </images>
        </root>;
        private var images:Vector.<ImageModel>=new Vector.<ImageModel>();

        public function Main():void
        {
            Init();
        }

        private function Init()
        {
            var xml:XMLList = myXML.images.image;
            for each (var imageNode:XML in xml)
            {
                addImages(new ImageModel(imageNode));
            }
            echo();
            sortImages();
            echo();
        }

        private function sortImages():void
        {
            images.sort(sortFunction);
        }

        private function sortFunction(x:ImageModel,y:ImageModel):int
        {
            return x.index-y.index;
        }

        private function addImages(model:ImageModel)
        {
            images.push(model);
        }
        private function echo()
        {
            for each (var imageModel:ImageModel in images)
            {
                trace(imageModel.filename);
            }
            trace("\n");
        }
    }

}

 

package com.vini123.model
{
    public class ImageModel
    {
        private var _index:int;
        private var _url:String;
        private var _filename:String;

        public function ImageModel(xml:XML):void
        {
            decode(xml);
        }

        /**
        *  序号
        */
        public function set index(param:int)
        {
            _index = param;
        }
        public function get index():int
        {
            return _index;
        }

        /**
        *  文件地址
        */
        public function set url(param:String)
        {
            _url = param;
        }
        public function get url():String
        {
            return _url;
        }

        /**
        *  文件名字
        */
        public function set filename(param:String)
        {
            _filename = param;
        }

        public function get filename():String
        {
            return _filename;
        }

        private function decode(imageNode:XML)
        {
            this.index = imageNode. @ index;
            this.filename = imageNode. @ filename;
            this.url = imageNode. @ url;
        }
    }
}