按键检测类 KeyPoll class

         as3中已经没有了Key.isDown，KeyPoll类模拟实现了此方法，非常实用.

    这个对于键盘控制人物角色八个方向的行走还是比较方便的。

贴出KeyPoll类：

package com{
    import flash.events.KeyboardEvent;
    import flash.events.Event;
    import flash.display.DisplayObject;
    import flash.utils.ByteArray;

    public class KeyPoll {
        private var states:ByteArray;
        private var dispObj:DisplayObject;

        public function KeyPoll( displayObj:DisplayObject ) {
            states = new ByteArray();
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            states.writeUnsignedInt( 0 );
            dispObj=displayObj;
            dispObj.addEventListener( KeyboardEvent.KEY_DOWN, keyDownListener, false, 0, true );
            dispObj.addEventListener( KeyboardEvent.KEY_UP, keyUpListener, false, 0, true );
            dispObj.addEventListener( Event.ACTIVATE, activateListener, false, 0, true );
            dispObj.addEventListener( Event.DEACTIVATE, deactivateListener, false, 0, true );
        }

        private function keyDownListener( ev:KeyboardEvent ):void {
            states[ ev.keyCode >>> 3 ] |= 1 << (ev.keyCode & 7);
        }

        private function keyUpListener( ev:KeyboardEvent ):void {
            states[ ev.keyCode >>> 3 ] &= ~(1 << (ev.keyCode & 7));
        }

        private function activateListener( ev:Event ):void {
            for (var i:int = 0; i < 32; ++i) {
                states[i]=0;
            }
        }

        private function deactivateListener( ev:Event ):void {
            for (var i:int = 0; i < 32; ++i) {
                states[i]=0;
            }
        }

        public function isDown( keyCode:uint ):Boolean {
            return ( states[ keyCode >>> 3 ] & (1 << (keyCode & 7)) ) != 0;
        }
        
        public function isUp( keyCode:uint ):Boolean {
            return ( states[ keyCode >>> 3 ] & (1 << (keyCode & 7)) ) == 0;
        }
    }
}

 

应用：

package 
{
    import com.KeyPoll;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.ui.Keyboard;
    import flash.text.TextField;
    import flash.text.TextFormat;

    [SWF(width = "720",height = "450",frameRate = "12",backgroundColor = "0x3399ee")]
    
    /**
    *@ web: http://blog.vini123.com 
    *@ explanation 文章来自网上，整理vini。 这个对于键盘控制人物角色八个方向的行走还是比较方便的。
    */
    public class Main extends Sprite
    {
        private var key:KeyPoll;
        private var curPosition:int;
        private var txt:TextField;

        public function Main():void
        {
            addEventListener(Event.ADDED_TO_STAGE,addtoStageHandler);
        }
        private function addtoStageHandler(e:Event)
        {
            removeEventListener(Event.ADDED_TO_STAGE,addtoStageHandler);

            var txtFormat:TextFormat=new TextFormat();
            txtFormat.size = 14;
            txtFormat.color = 0xff0000;
            txt=new TextField();
            txt.setTextFormat(txtFormat);
            txt.selectable = false;
            txt.mouseEnabled = false;
            txt.x = 10;
            txt.y = 20;
            addChild(txt);
            key = new KeyPoll(stage);
            addEventListener(Event.ENTER_FRAME,enterFrameHandler);
        }
        private function enterFrameHandler(e:Event)
        {
            controlKey();
        }

        private function controlKey():void
        {
            if (key.isDown(Keyboard.UP))
            {

                if (key.isDown(Keyboard.LEFT))
                {
                    curPosition = 7;
                }
                else if (key.isDown(Keyboard.RIGHT))
                {
                    curPosition = 8;
                }
                else
                {
                    curPosition = 3;
                }
            }
            else if (key.isDown(Keyboard.DOWN))
            {
                if (key.isDown(Keyboard.LEFT))
                {
                    curPosition = 5;

                }
                else if (key.isDown(Keyboard.RIGHT))
                {
                    curPosition = 6;
                }
                else
                {
                    curPosition = 1;
                }
            }
            else if (key.isDown(Keyboard.LEFT))
            {
                curPosition = 2;

            }
            else if (key.isDown(Keyboard.RIGHT))
            {
                curPosition = 4;
            }
            txt.text = "请注意看着：" + String(curPosition);
        }
    }
}