Delphi XML解析速度大比拼

最近闲来无事,想比较下在win系统中,MSXML、NativeXML和OXML三种组件解析XML的速度。

先说结果:
解析10万个,最深7层,每层最多5个结点的xml文件,在我电脑(U7 265K 16G内存)下,

| 解析器 | 用时(毫秒) | 相对速度 |
| --------- | ------ | -------- |
| OXml | 182 | 1.0x(基准) |
| MSXML | 411 | 约 2.26 倍 |
| NativeXml | 1203 | 约 6.61 倍 |

代码如下:
unit Main;

interface

uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl.Dialogs,
Vcl.StdCtrls, Xml.XMLDoc, Xml.XMLIntf, NativeXml, Vcl.ExtCtrls, Vcl.ComCtrls,
IOUtils,OXmlUtils,OXmlPDOM;

type
TForm10 = class(TForm)
BtnCreateXML: TButton;
BtnUseMSXML: TButton;
BtnUseNativeXml: TButton;
XMLmemo: TMemo;
Panel1: TPanel;
MsgMemo: TMemo;
progressBar: TProgressBar;
lblStatus: TLabel;
BtnUseOXML: TButton;
procedure BtnCreateXMLClick(Sender: TObject);
procedure BtnUseMSXMLClick(Sender: TObject);
procedure BtnUseNativeXmlClick(Sender: TObject);
procedure BtnUseOXMLClick(Sender: TObject);
private
function CreateXML(NodeCount: integer): boolean;
{ Private declarations }
public
{ Public declarations }
end;

var
Form10: TForm10;
FilePath: string;

implementation
uses system.Diagnostics;

procedure TForm10.BtnCreateXMLClick(Sender: TObject);
begin
CreateXML(100000);
XMLmemo.Lines.LoadFromFile(FilePath,TEncoding.UTF8);
end;

procedure TForm10.BtnUseMSXMLClick(Sender: TObject);
var
XMLDoc:xml.XMLDoc.TXMLDocument;
RootNode: IXMLNode;
i: Integer;
procedure GetChildNods(Node: IXMLNode);
var
Child: IXMLNode;
tt:string;
NodeValue: string;
begin
if Node.HasChildNodes then
begin
for var J := 0 to Node.ChildNodes.Count - 1 do
begin
Child := Node.ChildNodes[J];
tt:= VarToStr(Child.Attributes['ID']);
if Child.NodeType=xml.XMLIntf.ntText then
NodeValue :=Child.Text// VarToStr(Child.NodeValue);
else if Child.NodeType=xml.XMLIntf.ntElement then
begin
inc(i);
GetChildNods(Child);
end;
end;
end;
end;

begin
XMLDoc := xml.XMLDoc.TXMLDocument.Create(self);
var Stopwatch := TStopwatch.StartNew;
try
XMLDoc.LoadFromFile(FilePath);
XMLDoc.Active := True;
XMLDoc.Encoding:='GBK';
RootNode := XMLDoc.DocumentElement;
i := 0;
GetChildNods(RootNode);
Stopwatch.Stop;
finally
XMLDoc.Active := False;
XMLDoc.Free;
MsgMemo.Lines.Add('共读取了' + i.ToString + '个节点。');
MsgMemo.Lines.Add('用时' + Stopwatch.ElapsedMilliseconds.ToString);
end;
end;

procedure TForm10.BtnUseNativeXmlClick(Sender: TObject);
var
XML: TNativeXml;
RootNode: TsdElement;
i: Integer;

procedure GetChildNodes(Node: NativeXml.TXMLNode);
var
NodeValue: string;
Child: NativeXml.TXmlNode;
begin
for var J := 0 to Node.NodeCount - 1 do
begin
Child := Node.Nodes[J];
if Child.ElementType = xeCharData then
NodeValue := Child.Value
else
if Child.ElementType=xeElement then
begin
Inc(i);
GetChildNodes(Child);
end;
end;
end;

begin
XML := TNativeXml.Create(nil);
var Stopwatch := TStopwatch.StartNew;
try
i := 0;
XML.ExternalEncoding:=seAnsi;
XML.LoadFromFile(FilePath);
RootNode := XML.Root;
GetChildNodes(RootNode);
finally
XML.Free;
MsgMemo.Lines.Add('共读取了' + i.ToString + '个节点。');
MsgMemo.Lines.Add('用时' + Stopwatch.ElapsedMilliseconds.ToString);
end;
end;

procedure TForm10.BtnUseOXMLClick(Sender: TObject);
var
XML: IXMLDocument;
RootNode: PXmlNode;
i: Integer;

procedure GetChildNodes(Node: PXmlNode);
var
NodeValue: string;
Child: PXmlNode;
begin
Child := Node.FirstChild;
while Child <> nil do
begin
case Child.NodeType of
ntText, ntCData:
NodeValue := Child.Text; // 读取文本值
ntElement:
begin
Inc(i);
GetChildNodes(Child);
end;
// 其他节点类型忽略
end;
Child := Child.NextSibling;
end;
end;

begin
// 创建 XML 文档对象(使用接口自动释放)
XML := CreateXMLDoc;
var Stopwatch := TStopwatch.StartNew;
try
i := 0;
// OXml 加载文件,默认编码自动检测,如果需要 ANSI,可以设置,但 OXml 的 LoadFromFile 支持指定编码参数
// 这里我们简单使用 LoadFromFile,如果需要 ANSI 强制,可以传入 TEncoding.Default
XML.ReaderSettings.ErrorHandling := ehSilent;
if not XML.LoadFromFile(FilePath,TEncoding.UTF8) then
begin
MsgMemo.Lines.Add('加载 XML 文件失败。');
Exit;
end;

RootNode := XML.DocumentElement;
if RootNode = nil then
begin
MsgMemo.Lines.Add('没有根元素。');
Exit;
end;

// 调用递归遍历(根节点本身不计入 i)
GetChildNodes(RootNode);
finally
// XML 是接口,自动释放,无需手动 Free
MsgMemo.Lines.Add('共读取了' + i.ToString + '个节点。');
MsgMemo.Lines.Add('用时' + Stopwatch.ElapsedMilliseconds.ToString);
end;
end;

function TForm10.CreateXML(NodeCount: integer): boolean;
var
XMLDoc: xml.XMLDoc.TXMLDocument;
RootNode, DataNode, ItemNode: IXMLNode;
i: Integer;

function CreateChildNodes(Node: IXMLNode; Level: Integer): Boolean;
var
Child: IXMLNode;
CountOnLevel:Byte;
begin
if Level=1 then
CountOnLevel:=10
else CountOnLevel:=5;

for var j := 1 to CountOnLevel do
begin
inc(i);
if i > NodeCount then
Exit;
Child := Node.AddChild('第' + Level.ToString + '层' + j.ToString + '项');
Child.Attributes['ID'] := i;
Child.Attributes['Name'] := 'Item_' + IntToStr(i);
Child.Text := '测试文本' + IntToStr(i);

// 每1000个节点更新一次进度,提升性能
if i mod 1000 = 0 then
begin
progressBar.Position := Round(i / NodeCount * 100);
lblStatus.Caption := '正在生成XML文件...(' + IntToStr(i) + '/' + IntToStr(NodeCount) + ')';
Application.ProcessMessages;
end;
if Level < 7 then
CreateChildNodes(Child, Level + 1);
end;
end;

begin
result := False;
progressBar.Position := 0;
if FileExists(FilePath) then
begin
try
DeleteFile(PChar(FilePath));
except
MsgMemo.Lines.Add('⚠ 提示:删除旧测试文件失败,将尝试覆盖');
end;
end;

try
XMLDoc := xml.XMLDoc.TXMLDocument.Create(Self);
try
XMLDoc.Active := True; // Delphi 12必须显式激活
XMLDoc.Options := [doNodeAutoIndent];
XMLDoc.Encoding := 'UTF-8';
XMLDoc.Version := '1.0';

if not Assigned(XMLDoc.DocumentElement) then
begin
RootNode := XMLDoc.CreateNode('DataRoot');
XMLDoc.DocumentElement := RootNode;
end
else
begin
RootNode := XMLDoc.DocumentElement;
if RootNode.NodeName <> 'DataRoot' then
begin
RootNode := XMLDoc.CreateNode('DataRoot');
XMLDoc.DocumentElement := RootNode;
end;
end;

lblStatus.Caption := '正在生成XML文件...(0/' + IntToStr(NodeCount) + ')';
Application.ProcessMessages;

// 递归添加测试节点(优化性能)
CreateChildNodes(RootNode, 1);

// 强制更新最后进度
progressBar.Position := 100;
lblStatus.Caption := '正在保存XML文件...';
Application.ProcessMessages;

// 保存文件(使用UTF-8编码)
XMLDoc.SaveToFile(FilePath);
// 验证文件是否生成成功
if FileExists(FilePath) then
begin
Result := True;
lblStatus.Caption := 'XML文件生成完成: ' + FilePath;
MsgMemo.Lines.Add('✓ 生成测试XML文件成功,包含 ' + IntToStr(NodeCount) + ' 个节点');
MsgMemo.Lines.Add(' 文件路径: ' + FilePath);
MsgMemo.Lines.Add(' 文件大小: ' + FormatFloat('#,##0 KB', tfile.getsize(FilePath) / 1024));
end
else
begin
MsgMemo.Lines.Add('✗ 生成XML文件失败:文件未创建');
end;
finally
XMLDoc.Active := False;
XMLDoc.Free;
end;
Result := True;
except
on E: Exception do
begin
MsgMemo.Lines.Add('✗ 生成XML失败: ' + E.Message);
MsgMemo.Lines.Add(' 错误类型: ' + E.ClassName);
MsgMemo.Lines.Add(' 建议:检查临时目录权限 - ' + TPath.GetTempPath);
end;
end;
end;

initialization
FilePath := TPath.Combine(TPath.GetAppPath, '测试XML.xml');

finalization

end.

posted @ 2026-02-15 21:00  凸凹2  阅读(38)  评论(1)    收藏  举报