在平常工作中,总是有些小修改
每次查找这些更能的文件都很费事
利用XCopy /d就能很好的解决这些, 不过只能针对修改的文件,新增的文件是不行的(谁知道你的修改时间是不是当天的)
每次打命令都挺费事的,保存成一个批处理文件就方便多了
具体代码如下:

@echo off
rem 只要设置提取路径,就会在当前路径下生成一个以当前日期命名的文件夹,若要提取的内容不是当天修改的,
rem 手动修改rem set mdy=1-22-2011为具体的日期就可以了(把前面的rem去掉)

rem 设置提取路径
@set tqpath="E:\source\tqpath"
@set targetTh=.\
rem 设置提取扩展名
@set ext=dll,xls,css,js,aspx,ashx,ascx,gif,png,jpg,htm,html

rem 提取时间
for /f %%j in ('date /t') do for /f "usebackq delims=/ tokens=1" %%i in ('%%j') do set yyy=%%i
for /f %%j in ('date /t') do for /f "usebackq delims=/ tokens=2" %%i in ('%%j') do set mmm=%%i
for /f %%j in ('date /t') do for /f "usebackq delims=/ tokens=3" %%i in ('%%j') do set ddd=%%i
rem 设置提取日期
set mdy=%mmm%-%ddd%-%yyy%
rem set mdy=1-22-2011

rem 设置当前日期路径
set targetTh=%targetTh%%yyy%%mmm%%ddd%\
echo 源路径:%tqpath%

echo 目标路径:%targetTh%

@echo 1 提取所有
@echo 其他键,只复制存在文件
set /p sel=请选择(1，其他键)?
if "%sel%"=="1" goto sel1

:sel2
for %%i in (%ext%) do @xcopy %tqpath%\*.%%i %targetTh% /s /d:%mdy% /y /u
goto end
:sel1
for %%i in (%ext%) do @xcopy %tqpath%\*.%%i %targetTh% /s /d:%mdy% /y
:end
pause