记录一个最简单的Bloom效果的shader

Shader "UI/TexBloom"
{
    Properties
    {
        _MainTex ("Base Texture", 2D) = "white" {}
        _OverlayTex ("Overlay Texture", 2D) = "white" {}
        _OverlayRect ("Overlay Rect", Vector) = (0,0,1,1)
        _Saturation ("Overlay Saturation", Range(0,4)) = 2
        _BloomIntensity ("Bloom Intensity", Range(0,10)) = 4
        _BloomSize ("Bloom Size", Range(0,10)) = 4
    }

    SubShader
    {
        Tags{ "Queue"="Transparent" }

        Blend SrcAlpha OneMinusSrcAlpha
        Cull Off
        ZWrite Off

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            sampler2D _MainTex;
            sampler2D _OverlayTex;

            float4 _MainTex_TexelSize;
            float4 _OverlayRect;

            float _Saturation;
            float _BloomIntensity;
            float _BloomSize;

            struct appdata
            {
                float4 vertex:POSITION;
                float2 uv:TEXCOORD0;
                float4 color:COLOR;
            };

            struct v2f
            {
                float4 vertex:SV_POSITION;
                float2 uv:TEXCOORD0;
                float4 color:COLOR;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex=UnityObjectToClipPos(v.vertex);
                o.uv=v.uv;
                o.color=v.color;
                return o;
            }

            float3 AdjustSaturation(float3 c,float s)
            {
                float l=dot(c,float3(0.299,0.587,0.114));
                return lerp(l.xxx,c,s);
            }

            float4 SampleOverlayRect(float2 uv)
            {
                float2 rectUV=(uv-_OverlayRect.xy)/_OverlayRect.zw;
                if(rectUV.x<0||rectUV.y<0||rectUV.x>1||rectUV.y>1)
                    return 0;
                return tex2D(_OverlayTex,rectUV);
            }

            float3 ComputeBloom(float2 uv)
            {
                float2 texel=_MainTex_TexelSize.xy*_BloomSize;
                float3 bloom=0;
                bloom+=SampleOverlayRect(uv+texel*float2(-2,-2)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(-1,-1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(0,-1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(1,-1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(2,-2)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(-1,0)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(1,0)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(-2,2)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(-1,1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(0,1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(1,1)).rgb;
                bloom+=SampleOverlayRect(uv+texel*float2(2,2)).rgb;
                return bloom*_BloomIntensity*0.08;
            }

            fixed4 frag(v2f i):SV_Target
            {
                float2 uv=i.uv;
                float4 baseCol=tex2D(_MainTex,uv);
                float4 overlayCol=SampleOverlayRect(uv);
                overlayCol.rgb=AdjustSaturation(overlayCol.rgb,_Saturation);
                float3 bloom=ComputeBloom(uv);
                float3 result=baseCol.rgb+overlayCol.rgb+bloom;
                float alpha=baseCol.a+overlayCol.a;
                return float4(result,alpha)*i.color;
            }

            ENDCG
        }
    }
}