1．能量项链

(energy.pas/c/cpp)

【问题描述】

在Mars星球上，每个Mars人都随身佩带着一串能量项链。在项链上有N颗能量珠。能量珠是一颗有头标记与尾标记的珠子，这些标记对应着某个正整数。并且，对于相邻的两颗珠子，前一颗珠子的尾标记一定等于后一颗珠子的头标记。因为只有这样，通过吸盘（吸盘是Mars人吸收能量的一种器官）的作用，这两颗珠子才能聚合成一颗珠子，同时释放出可以被吸盘吸收的能量。如果前一颗能量珠的头标记为m，尾标记为r，后一颗能量珠的头标记为r，尾标记为n，则聚合后释放的能量为（Mars单位），新产生的珠子的头标记为m，尾标记为n。

需要时，Mars人就用吸盘夹住相邻的两颗珠子，通过聚合得到能量，直到项链上只剩下一颗珠子为止。显然，不同的聚合顺序得到的总能量是不同的，请你设计一个聚合顺序，使一串项链释放出的总能量最大。

例如：设N=4，4颗珠子的头标记与尾标记依次为(2，3) (3，5) (5，10) (10，2)。我们用记号⊕表示两颗珠子的聚合操作，(j⊕k)表示第j，k两颗珠子聚合后所释放的能量。则第4、1两颗珠子聚合后释放的能量为：

(4⊕1)=10*2*3=60。

这一串项链可以得到最优值的一个聚合顺序所释放的总能量为

((4⊕1)⊕2)⊕3）=10*2*3+10*3*5+10*5*10=710。

【输入文件】

输入文件energy.in的第一行是一个正整数N（4≤N≤100），表示项链上珠子的个数。第二行是N个用空格隔开的正整数，所有的数均不超过1000。第i个数为第i颗珠子的头标记（1≤i≤N），当i<N< span>时，第i颗珠子的尾标记应该等于第i+1颗珠子的头标记。第N颗珠子的尾标记应该等于第1颗珠子的头标记。

至于珠子的顺序，你可以这样确定：将项链放到桌面上，不要出现交叉，随意指定第一颗珠子，然后按顺时针方向确定其他珠子的顺序。

【输出文件】

输出文件energy.out只有一行，是一个正整数E（E≤2.1*109），为一个最优聚合顺序所释放的总能量。

【输入样例】

4

2 3 5 10

【输出样例】

710

{

By Spray_of_learn

Date 2011-11-4

}

program __energy;

var

  f:array[0..200,0..200] of longint;

  a:array[1..200] of longint;

  n,i,j,k,ans:longint;

function max(a,b:longint):longint;

  begin

    if (a>b) then exit(a) else exit(b);

  end;

begin

  assign(input,'input.txt');reset(input);

  assign(output,'output.txt');rewrite(output);

  readln(n);

  for i:=1 to n do

    begin

      read(a[i]);

      a[i+n]:=a[i];

    end;

  readln;

  for i:=2 to n do

    for j:=1 to 2*n-i do

      for k:=j to j+i-2 do

        f[j][j+i-1]:=max(f[j][j+i-1],f[j][k]+f[k+1][j+i-1]+a[j]*a[k+1]*a[j+i]);

  for i:=1 to n do

    ans:=max(ans,f[i][i+n-1]);

  writeln(ans);

  close(input);

  close(output);

end.



2．金明的预算方案 

(budget.pas/c/cpp) 

【问题描述】 

金明今天很开心，家里购置的新房就要领钥匙了，新房里有一间金明自己专用的很宽敞的房间。更让他高兴的是，妈妈昨天对他说：“你的房间需要购买哪些物品，怎么布置，你说了算，只要不超过N元钱就行”。今天一早，金明就开始做预算了，他把想买的物品分为两类：主件与附件，附件是从属于某个主件的，下表就是一些主件与附件的例子： 







主件



附件





电脑



打印机，扫描仪





书柜



图书





书桌



台灯，文具





工作椅



无


如果要买归类为附件的物品，必须先买该附件所属的主件。每个主件可以有0个、1个或2个附件。附件不再有从属于自己的附件。金明想买的东西很多，肯定会超过妈妈限定的N元。于是，他把每件物品规定了一个重要度，分为5等：用整数1~5表示，第5等最重要。他还从因特网上查到了每件物品的价格（都是10元的整数倍）。他希望在不超过N元（可以等于N元）的前提下，使每件物品的价格与重要度的乘积的总和最大。 

设第j件物品的价格为v[j]，重要度为w[j]，共选中了k件物品，编号依次为j1，j2，……，jk，则所求的总和为： 

v[j1]*w[j1]+v[j2]*w[j2]+ …+v[jk]*w[jk]。（其中*为乘号） 

请你帮助金明设计一个满足要求的购物单。 

【输入文件】 

输入文件budget.in 的第1行，为两个正整数，用一个空格隔开： 

N m 

（其中N（<32000）表示总钱数，m（<60）为希望购买物品的个数。） 

从第2行到第m+1行，第j行给出了编号为j-1的物品的基本数据，每行有3个非负整数 

v p q 

（其中v表示该物品的价格（v<10000），p表示该物品的重要度（1~5），q表示该物品是主件还是附件。如果q=0，表示该物品为主件，如果q>0，表示该物品为附件，q是所属主件的编号） 

【输出文件】 

输出文件budget.out只有一个正整数，为不超过总钱数的物品的价格与重要度乘积的总和的最大值（<200000）。 

【输入样例】 

1000 5 

800 2 0 

400 5 1 

300 5 1 

400 3 0 

500 2 0 

【输出样例】 

2200 

 


3．作业调度方案
{

By Spray_of_learn

Date 2011-11-4

}

program __budget;

var

  q:array[1..60] of longint;

  a,w,v,s:array[1..60,0..3] of longint;

  f:array[0..31000] of longint;

  c,m,i,n,j,k:longint;

begin

  assign(input,'input.txt');

  reset(input);

  assign(output,'output.txt');

  rewrite(output);

  readln(c,m);

  for i:=1 to m do

    begin

      readln(a[i][0],w[i][0],q[i]);

      w[i][0]:=w[i][0]*a[i][0];

    end;

  for i:=1 to m do

    begin

      if (q[i]>0) then

        begin

          if (a[q[i]][1]=0) then

            begin

              a[q[i]][1]:=a[q[i]][0]+a[i][0];

              w[q[i]][1]:=w[q[i]][0]+w[i][0];

            end

          else

            begin

              a[q[i]][2]:=a[q[i]][0]+a[i][0];

              w[q[i]][2]:=w[q[i]][0]+w[i][0];

              a[q[i]][3]:=a[q[i]][1]+a[i][0];

              w[q[i]][3]:=w[q[i]][1]+w[i][0];

            end;

        end;

    end;

  for i:=1 to m do

    begin

      if (q[i]=0) then

        begin

          inc(n);

          v[n]:=a[i];

          s[n]:=w[i];

        end;

    end;

  for i:=1 to n do

    for j:=c downto 0 do

      for k:=0 to 3 do

        if (j-v[i][k]>=0) then

          if (f[j-v[i][k]]+s[i][k]>f[j]) then

            f[j]:=f[j-v[i][k]]+s[i][k];

  writeln(f[c]);

  close(input);

  close(output);

end.



(jsp.pas/c/cpp) 

【问题描述】 

我们现在要利用m台机器加工n个工件，每个工件都有m道工序，每道工序都在不同的指定的机器上完成。每个工件的每道工序都有指定的加工时间。 

每个工件的每个工序称为一个操作，我们用记号j-k表示一个操作，其中j为1到n中的某个数字，为工件号；k为1到m中的某个数字，为工序号，例如2-4表示第2个工件第4道工序的这个操作。在本题中，我们还给定对于各操作的一个安排顺序。 

例如，当n=3，m=2时，“1-1，1-2，2-1，3-1，3-2，2-2”就是一个给定的安排顺序，即先安排第1个工件的第1个工序，再安排第1个工件的第2个工序，然后再安排第2个工件的第1个工序，等等。 

一方面，每个操作的安排都要满足以下的两个约束条件。 

(1) 对同一个工件，每道工序必须在它前面的工序完成后才能开始； 

(2) 同一时刻每一台机器至多只能加工一个工件。 

另一方面，在安排后面的操作时，不能改动前面已安排的操作的工作状态。 

由于同一工件都是按工序的顺序安排的，因此，只按原顺序给出工件号，仍可得到同样的安排顺序，于是，在输入数据中，我们将这个安排顺序简写为“1 1 2 3 3 2”。 

还要注意，“安排顺序”只要求按照给定的顺序安排每个操作。不一定是各机器上的实际操作顺序。在具体实施时，有可能排在后面的某个操作比前面的某个操作先完成。 

例如，取n=3,m=2，已知数据如下： 







工件号



机器号/加工时间





工序1



工序2





1



1/3



2/2





2



1/2



2/5





3



2/2



1/4


则对于安排顺序“1 1 2 3 3 2”，下图中的两个实施方案都是正确的。但所需要的总时间分别是10与12。 

当一个操作插入到某台机器的某个空档时（机器上最后的尚未安排操作的部分也可以看作一个空档），可以靠前插入，也可以靠后或居中插入。为了使问题简单一些，我们约定：在保证约束条件（1）（2）的条件下，尽量靠前插入。并且，我们还约定，如果有多个空档可以插入，就在保证约束条件（1）（2）的条件下，插入到最前面的一个空档。于是，在这些约定下，上例中的方案一是正确的，而方案二是不正确的。 

显然，在这些约定下，对于给定的安排顺序，符合该安排顺序的实施方案是唯一的，请你计算出该方案完成全部任务所需的总时间。 

【输入文件】 

输入文件jsp.in 的第1行为两个正整数，用一个空格隔开： 

m n 

（其中m（<20）表示机器数，n（<20）表示工件数） 

第2行：个用空格隔开的数，为给定的安排顺序。 

接下来的2n行，每行都是用空格隔开的m个正整数，每个数不超过20。 

其中前n行依次表示每个工件的每个工序所使用的机器号，第1个数为第1个工序的机器号，第2个数为第2个工序机器号，等等。 

后n行依次表示每个工件的每个工序的加工时间。 

可以保证，以上各数据都是正确的，不必检验。 

【输出文件】 

输出文件jsp.out只有一个正整数，为最少的加工时间。 

【输入样例】 

2 3 

1 1 2 3 3 2 

1 2 

1 2 

2 1 

3 2 

2 5 

2 4 

【输出样例】 

10
{

By Spray_of_learn

Date 2011-11-4

}

program __jsp;

var

  list:array[1..400] of longint;

  machine,times:array[1..20,0..20] of longint;

  n,m,i,j,k,x,y,t,ans:longint;

  map,last:array[1..20,0..20] of longint;

  start:array[1..20] of longint;

  cnt:array[1..20] of longint;

  flag:boolean;

begin

  assign(input,'input.txt');

  reset(input);

  assign(output,'output.txt');

  rewrite(output);

  readln(n,m);

  for i:=1 to n*m do

    read(list[i]);

  readln;

  for i:=1 to m do

    for j:=1 to n do

      read(machine[i][j]);

  for i:=1 to m do

    for j:=1 to n do

      read(times[i][j]);

  for i:=1 to n do

    begin

      map[i][0]:=1;

      map[i][1]:=1;

	  last[i][1]:=0;

    end;

  for k:=1 to m*n do

    begin

      inc(cnt[list[k]]);

      flag:=false;

      t:=machine[ list[k] ][ cnt[ list[k] ] ];

      for i:=2 to map[t][0] do

        begin

          if (map[t][i]-map[t][i-1]-last[t][i-1]>=times[ list[k] ][ cnt[ list[k] ] ]) then

            begin

			  if (map[t][i]-start[ list[k] ]<times[ list[k] ][ cnt[list[k]] ]) then continue;

              for j:=map[t][0] downto i do

                begin

                  map[t][j+1]:=map[t][j];

                  last[t][j+1]:=last[t][j];

                end;

              inc(map[t][0]);

              map[t][i]:=map[t][i-1]+last[t][i-1];

              last[t][i]:=times[ list[k] ][ cnt[ list[k] ] ];

			  if (map[t][i]<start[ list[k] ]) then map[t][i]:=start[ list[k] ];

			  start[ list[k] ]:=map[t][i]+last[t][i];

              flag:=true;

			  break;//______here!I forgot.

            end;

        end;

      if (not flag) then

        begin

          inc(map[t][0]);

          map[t][ map[t][0] ]:=map[t][ map[t][0] - 1 ] + last[t][ map[t][0] - 1 ];

          last[t][ map[t][0] ]:=times[ list[k] ][ cnt[ list[k] ] ];

          if (start[ list[k] ]>map[t][ map[t][0] ]) then

            map[t][ map[t][0] ]:=start[ list[k] ];

          start[ list[k] ]:=map[t][map[t][0]]+last[t][map[t][0]];

          if (map[t][map[t][0]]+last[t][map[t][0]]-1>ans) then

            ans:=map[t][map[t][0]]+last[t][map[t][0]]-1;

        end;

    end;

  writeln(ans);

  close(input);

  close(output);

end.



4．2k进制数 

（digital.pas/c/cpp） 

【问题描述】 

设r是个2k 进制数，并满足以下条件： 

（1）r至少是个2位的2k 进制数。 

（2）作为2k 进制数，除最后一位外，r的每一位严格小于它右边相邻的那一位。 

（3）将r转换为2进制数q后，则q的总位数不超过w。 

在这里，正整数k（1≤k≤9）和w（k<W< span>≤30000）是事先给定的。 

问：满足上述条件的不同的r共有多少个？ 

我们再从另一角度作些解释：设S是长度为w 的01字符串（即字符串S由w个“0”或“1”组成），S对应于上述条件（3）中的q。将S从右起划分为若干个长度为k 的段，每段对应一位2k进制的数，如果S至少可分成2段，则S所对应的二进制数又可以转换为上述的2k 进制数r。 

例：设k=3，w=7。则r是个八进制数（23=8）。由于w=7，长度为7的01字符串按3位一段分，可分为3段（即1，3，3，左边第一段只有一个二进制位），则满足条件的八进制数有： 

2位数：高位为1：6个（即12，13，14，15，16，17），高位为2：5个，…，高位为6：1个（即67）。共6+5+…+1=21个。 

3位数：高位只能是1，第2位为2：5个（即123，124，125，126，127），第2位为3：4个，…，第2位为6：1个（即167）。共5+4+…+1=15个。 

所以，满足要求的r共有36个。 

【输入文件】 

输入文件digital.in只有1行，为两个正整数，用一个空格隔开： 

k W 

【输出文件】 

输出文件digital.out为1行，是一个正整数，为所求的计算结果，即满足条件的不同的r的个数（用十进制数表示），要求最高位不得为0，各数字之间不得插入数字以外的其他字符（例如空格、换行符、逗号等）。 

（提示：作为结果的正整数可能很大，但不会超过200位） 

【输入样例】 

3 7 

【输出样例】 

36
{

By Spray_of_learn

Date 2011-11-4

}

program __digital;

type

  arr=array[0..100] of longint;

var

  c:array[0..512,0..512] of arr;

  n,k,i,j,b,h:longint;

  ans:arr;

procedure plus(var a,b,d:arr);

  var

    c:arr;

    len,i:longint;

  begin

    fillchar(c,sizeof(c),0);

    if (a[0]>b[0]) then len:=a[0]+3 else len:=b[0]+3;

    for i:=1 to len do

      begin

        c[i]:=a[i]+b[i];

        inc(c[i],c[i-1] div 10000);

        c[i-1]:=c[i-1] mod 10000;

      end;

    while (len>1)and(c[len]=0) do dec(len);

    c[0]:=len;

    d:=c;

  end;

procedure print(a:arr);

  var

    i:longint;

  begin

    write(a[a[0]]);

    for i:=a[0]-1 downto 1 do

      begin

        if (a[i]<10) then write('000')

        else if (a[i]<100) then write('00')

        else if (a[i]<1000) then write('0');

        write(a[i]);

      end;

  end;

begin

  assign(input,'input.txt');

  reset(input);

  assign(output,'output.txt');

  rewrite(output);

  readln(k,n);

  b:=1 shl k;

  h:=1 shl (n mod k);

  c[0][0][0]:=1;

  c[0][0][1]:=1;

  for i:=1 to b-1 do

    begin

      c[i][0][0]:=1;

      c[i][0][1]:=1;

      for j:=1 to i do

        plus(c[i-1][j],c[i-1][j-1],c[i][j]);

    end;

  for i:=2 to n div k do

    begin

      if (i>=b) then break;

      plus(ans,c[b-1][i],ans);

    end;

  for i:=1 to h-1 do

    begin

      if (n div k+1>=b) then break;

      plus(ans,c[b-i-1][n div k],ans);

    end;

  print(ans);

  close(input);

  close(output);

end.