SqlCollections - 触发器

--==============================触发器===============================
--分类及注意
--触发器分为DML触发器和DDL触发器，DML触发器又分After触发器和Instead Of触发器
--After触发器只可以建在表上，Instead Of触发器可以建在表或视图上
--每个触发器都定义了插入表Inserted和删除表Deleted，存在于服务器内存中，不是物理表
--Truncate Table语句不会激发Delete类型触发器

--After触发器
--例：插入一条记录时，显示友好提示
CREATE TRIGGER 产品_Insert1
ON 产品    --ON+表名或视图名（是有Instead Of触发器可以建在视图上）
AFTER INSERT
AS
BEGIN
    PRINT '又添加了一种产品（1）！'
END
GO
--再创建一个
CREATE TRIGGER 产品_Insert2
ON 产品
AFTER INSERT
AS
BEGIN
    PRINT '又添加了一种产品（2）！'
END
GO
/*显示：又添加了一种产品（1）！
        又添加了一种产品（2）！*/
INSERT INTO 产品(产品名称) VALUES ('小苹果')    

--After触发器的激活顺序
--参数1：触发器名，注意引号；
--参数2：激活次序，包括First,Last,None，None代表不指定；
--参数3：激活动作，可以为Insert,Update或Delete
EXEC sp_settriggerorder '产品_Insert1','Last','Insert'
GO
EXEC sp_settriggerorder '产品_Insert2','First','Insert'
GO
/*显示：又添加了一种产品（2）！
        又添加了一种产品（1）！
顺序已经反了*/
INSERT INTO 产品(产品名称) VALUES ('小苹果')    

--在After触发器中回滚
--例：插入记录时，若折扣大于0.6，则执行回滚不插入
CREATE TRIGGER 订单明细_Insert
ON 订单明细
AFTER INSERT
AS
BEGIN
    IF(SELECT 折扣 FROM INSERTED) > 0.6    --INSERTED:存放新纪录的表，DELETED:存放旧记录的表
    BEGIN
        PRINT '折扣不允许大于0.6！'
        ROLLBACK TRAN    --回滚操作
    END
END
GO
INSERT INTO 订单明细(订单ID,产品ID,单价,数量,折扣)
VALUES(11077,1,18,1,0.8)
GO
--数据被回滚，未成功插入
SELECT * FROM 订单明细 WHERE 订单ID = 11077 AND 折扣=0.8

--Instead Of触发器
--上一例用Instead Of触发器更好，在插入前先判断，减少服务器负担
CREATE TRIGGER 订单明细_Insert2
ON 订单明细
INSTEAD OF INSERT
AS
BEGIN
    DECLARE @订单ID int,
    @产品ID int,
    @单价 money,
    @数量 smallint,
    @折扣 real;
    SELECT @订单ID = 订单ID FROM inserted
    SELECT @产品ID = 产品ID FROM inserted
    SELECT @单价 = 单价 FROM inserted
    SELECT @数量 = 数量 FROM inserted
    SELECT @折扣 = 折扣 FROM inserted
    IF(@折扣 > 0.6)
        BEGIN
            PRINT '折扣不允许大于0.6！'
        END
    ELSE
        BEGIN
            INSERT INTO 订单明细(订单ID,产品ID,单价,数量,折扣)
            VALUES(@订单ID,@产品ID,@单价,@数量,@折扣)
        END
END
GO
INSERT INTO 订单明细(订单ID,产品ID,单价,数量,折扣)
VALUES(11077,1,18,1,0.9)
GO
--数据被回滚，未成功插入
SELECT * FROM 订单明细 WHERE 订单ID = 11077 AND 折扣=0.9

--查看指定触发器信息
EXEC sp_help '订单明细_Insert'    --简要信息
EXEC sp_helptext '订单明细_Insert'    --具体脚本

--重命名触发器
EXEC sp_rename '订单明细_Insert','订单明细_Insert1'

--删除触发器
--删除表时会自动删除该表的触发器
DROP TRIGGER 订单明细_Insert1    --注意不能带引号

--启用与禁用触发器
ALTER TABLE 订单明细
DISABLE TRIGGER 订单明细_Insert2    --禁用
--ENABLE TRIGGER 订单明细_Insert2    --启用
--ENABLE TRIGGER ALL    --启用所有

--DDL触发器
--DDL触发器只能定义FOR或AFTER（意义一样），不能定义Instead Of
CREATE TRIGGER 禁止修改或删除该数据库的表
ON DATABASE    --ON后面可跟DATABASE，作用到当前数据库，或跟ALL SERVER，作用到当前服务器的所有数据库
FOR ALTER_TABLE,DROP_TABLE    --当作用在ALL SERVER时，可以FOR DROP_DATABASE等
AS
BEGIN
    PRINT '不允许操作数据表！'
    ROLLBACK TRAN
END
GO
DROP TABLE tbl1

--创建自定义数据库日志
--创建日志记录表
CREATE TABLE 日志记录表
(
    编号 int IDENTITY(1,1) PRIMARY KEY NOT NULL,
    事件 varchar(5000) NULL,
    所用语句 varchar(5000) NULL,
    操作者 varchar(50) NULL,
    操作时间 datetime NULL
)
GO
--创建DDL触发器
CREATE TRIGGER 记录日志
ON DATABASE
FOR DDL_DATABASE_LEVEL_EVENTS
AS
BEGIN
    DECLARE @log XML
    DECLARE @event varchar(5000)
    DECLARE @sql varchar(5000)
    DECLARE @operator varchar(50)
    SET @log = EVENTDATA()
    SET @event = @log.value('(EVENT_INSTANCE/EventType)[1]','nvarchar(100)')
    SET @sql = @log.value('(/EVENT_INSTANCE/TSQLCommand)[1]','nvarchar(2000)')
    SET @operator = CONVERT(varchar(50),CURRENT_USER)
    --插入日志表
    INSERT INTO 日志记录表(事件,所用语句,操作者,操作时间)
    VALUES(@event,@sql,@operator,GETDATE())
END    
GO
--验证日志
CREATE TABLE 测试日志表(编号 int PRIMARY KEY,测试内容 varchar(50))
GO
--先把之前的DDL触发器禁用掉
DISABLE TRIGGER 禁止修改或删除该数据库的表 ON DATABASE    --禁用DDL触发器的写法
GO
--删除表
DROP TABLE 测试日志表
GO
--查看日志
SELECT * FROM 日志记录表

--判断字段是否被更改
CREATE TRIGGER 看折扣是否被更改
ON 订单明细
AFTER UPDATE
AS
BEGIN
    IF UPDATE(折扣)    --该字段是否被更新
    BEGIN
        PRINT '折扣字段将被修改'
    END
    ELSE
    BEGIN
        PRINT '折扣字段没有被修改'
    END
END
GO
--输出：折扣字段将被修改
UPDATE 订单明细 SET 折扣 = 0.2 WHERE 订单ID = 1 AND 产品ID = 1
--输出：折扣字段没有被修改
UPDATE 订单明细 SET 数量 = 1 WHERE 订单ID = 1 AND 产品ID = 1
--输出：折扣字段将被修改
UPDATE 订单明细 SET 折扣 = 0.2,数量 = 1 WHERE 订单ID = 1 AND 产品ID = 1