SqlCollections - 数据表管理

--==============================数据表管理===============================
--特殊字符的输入
--Tab: char(9)
--换行: char(10)
--回车: char(13)

--varchar(n):1个字符占1个字节；nvarchar(n):1个字符占2个字节
--'我是Sky'存在varchar字段中，占7个字节；存在nvarchar中，占10个字节

--创建新表，并指定主键、自增长、非空、Unique约束、排序类型、默认值、CHECK字段约束、CHECK数据表约束
--约束的格式：CONSTRAINT 自定义的约束名 约束类型 其它参数
CREATE TABLE TEST1
(
    编号 int IDENTITY(1,1) PRIMARY KEY,    --自增长、主键约束
    姓名 nvarchar(50) COLLATE Chinese_PRC_CI_AS NOT NULL,    --排序、非空
    别名 nvarchar(50) UNIQUE,    --唯一键约束
    性别 bit DEFAULT 1,    --默认值
    年龄 tinyint CONSTRAINT CK_TEST1_年龄 CHECK (年龄 > 0 AND 年龄 < 101),    --CHECK字段约束
    部门编号 int CONSTRAINT FK_TEST1_部门编号 
        FOREIGN KEY 
        REFERENCES 部门表(部门编号),    --外键约束
    地址 nvarchar(200),
    电话 varchar(50),
    CHECK (电话 is not null or 地址 is not null)    --CHECK数据表约束
)


--创建计算列
CREATE TABLE TEST2
(
    编号 int,
    编号2 int,
    单价 money NOT NULL,
    数量 int NOT NULL
        CONSTRAINT CK_TEST2_数量 CHECK (数量 > 0),
    合计 AS 单价*数量    --计算列是只读的
)

--添加字段
ALTER TABLE TEST1
ADD 备注 nvarchar(500)

--删除字段
ALTER TABLE TEST1
DROP COLUMN 备注

--修改字段
ALTER TABLE TEST2
ALTER COLUMN 编号 int NOT NULL

--重命名表名和字段名
EXEC sp_rename 'TEST1','测试1'    --修改表名
EXEC sp_rename 'TEST1.别名','Alias','COLUMN'    --修改列名

--添加主键
ALTER TABLE TEST2
ADD CONSTRAINT PK_TEST2 PRIMARY KEY (编号)

--添加外键
ALTER TABLE TEST2
ADD CONSTRAINT FK_TEST2_TEST1 FOREIGN KEY (编号2) REFERENCES 测试1(编号)

--添加CHECK约束
ALTER TABLE TEST2
WITH NOCHECK    --可选：添加约束时不检查现有数据
ADD CONSTRAINT CK_TEST2_单价 CHECK (单价 > 0)

--添加默认值约束
ALTER TABLE TEST2
ADD DEFAULT (1) FOR 数量

--删除约束
ALTER TABLE TEST2
DROP CONSTRAINT CK_TEST2_单价

--禁用约束
ALTER TABLE TEST2
NOCHECK CONSTRAINT CK_TEST2_单价
--禁用所有约束
ALTER TABLE TEST2
NOCHECK CONSTRAINT ALL

--启用约束
ALTER TABLE TEST2
CHECK CONSTRAINT CK_TEST2_单价
--启用所有约束
ALTER TABLE TEST2
CHECK CONSTRAINT ALL

--删除表
--必须先删除表与表间的关联才能删除表
DROP TABLE TEST2

--判断表是否存在
IF NOT EXISTS (SELECT * FROM sys.objects WHERE object_id = OBJECT_ID(N'[dbo].[TEST2]') AND type in (N'U'))
BEGIN
    PRINT '可以创建该表'
END