[noip2007T2]字符串的展开

字符串的展开

(expand.pas/c/cpp)

【问题描述】

在初赛普及组的“阅读程序写结果”的问题中，我们曾给出一个字符串展开的例子：如果在输入的字符串中，含有类似于“d-h”或“4-8”的子串，我们就把它当作一种简写，输出时，用连续递增的字母或数字串替代其中的减号，即，将上面两个子串分别输出为“defgh”和“45678”。在本题中，我们通过增加一些参数的设置，使字符串的展开更为灵活。具体约定如下：

（1）遇到下面的情况需要做字符串的展开：在输入的字符串中，出现了减号“-”，减号两侧同为小写字母或同为数字，且按照ASCII码的顺序，减号右边的字符严格大于左边的字符。

（2）参数p1：展开方式。p1=1时，对于字母子串，填充小写字母；p1=2时，对于字母子串，填充大写字母。这两种情况下数字子串的填充方式相同。p1=3时，不论是字母子串还是数字子串，都用与要填充的字母个数相同的星号“*”来填充。

（3）参数p2：填充字符的重复个数。p2=k表示同一个字符要连续填充k个。例如，当p2=3时，子串“d-h”应扩展为“deeefffgggh”。减号两侧的字符不变。

（4）参数p3：是否改为逆序：p3=1表示维持原有顺序，p3=2表示采用逆序输出，注意这时仍然不包括减号两端的字符。例如当p1=1、p2=2、p3=2时，子串“d-h”应扩展为“dggffeeh”。

（5）如果减号右边的字符恰好是左边字符的后继，只删除中间的减号，例如：“d-e”应输出为“de”，“3-4”应输出为“34”。如果减号右边的字符按照ASCII码的顺序小于或等于左边字符，输出时，要保留中间的减号，例如：“d-d”应输出为“d-d”，“3-1”应输出为“3-1”。

【输入】

输入文件expand.in包括两行：

第1行为用空格隔开的3个正整数，依次表示参数p1，p2，p3。

第2行为一行字符串，仅由数字、小写字母和减号“-”组成。行首和行末均无空格。

【输出】

输出文件expand.out只有一行，为展开后的字符串。

【输入输出样例1】

expand.in	expand.out
1 2 1 abcs-w1234-9s-4zz	abcsttuuvvw1234556677889s-4zz

【输入输出样例2】

expand.in	expand.out
2 3 2 a-d-d	aCCCBBBd-d

【输入输出样例3】

expand.in	expand.out
3 4 2 di-jkstra2-6	dijkstra2************6

【限制】

     40%的数据满足：字符串长度不超过5

    100%的数据满足：1<=p1<=3, 1<=p2<=8, 1<=p3<=2。字符串长度不超过100

[题目]给定一个字符串，如果某个'-'左边同为数字或同为字母，并且右边的Ascii码严格大于左边的Ascii码，则在原串中删去'-'，并在该位置上插入左右字符之间的字符。其中插入字符有3个参数。
参数p1=1 ==> 字母为小写
      =2 ==> 字母为大写
      =3 ==> 字母、数字都用'*'代替
参数p2    ==> 同一字母填充的个数
参数p3 =1 按ascii递增填充，
       =2 按ascii递减填充。
其中原串的长度不大于100。
[分析]很纯粹的模拟题，要注意的是注意各种特殊情况的处理——因为NOIP的测试数据总是很刁的。例如，考虑开头和结尾的'-'等。由于规模比较大，需要用ansistring而不能用普通的string，但是用不着动用字符数组。
[参考代码]
//By LYLtim

var p1,p2,p3,i:byte;
    p:word;
    s:ansistring;
    l,r,ch:char;
begin
    assign(input,'expand.in');reset(input);
    assign(output,'expand.out');rewrite(output);
    readln(p1,p2,p3);
    readln(s);
    p:=pos('-',s);
    while p=1 do begin delete(s,1,1); write('-'); p:=pos('-',s); end;
    while p<>0 do
        begin
            write(copy(s,1,p-1));
            l:=s[p-1];r:=s[p+1];
            delete(s,1,p);
            if((l in['a'..'z'])and(r in['a'..'z'])or(l in['0'..'9'])and(r in['0'..'9']))and(l<r)then
                case p3 of
                    1: for ch:=succ(l) to pred(r)do
                        for i:=1 to p2 do
                            case p1 of
                                1:write(ch);
                                2:write(upcase(ch));
                                3:write('*');
                            end;
                    2:for ch:=pred(r) downto succ(l) do
                        for i:=1 to p2 do
                            case p1 of
                                1:write(ch);
                                2:write(upcase(ch));
                                3:write('*');
                            end;
                end
            else write('-');
            p:=pos('-',s);
        end;
    writeln(s);
    close(input);close(output);
end.