Ankh菜单删除

今天下载了AnkhSVN 试用来一番。它是一个Visual Studio IDE的一个插件，感觉仍然不如VSS或者Visual SVN方便，Unintall后，居然发现VS2005菜单上，仍然有AnkhSVN的菜单项目。要删除它，Google这样一个文章：

http://www.therightstuff.de/2006/09/21/Removing+AnkhSVN+Commands+From+Visual+Studio.aspx

Imports System
Imports EnvDTE
Imports System.Diagnostics
' Comment the following line if you're running the macro in Visual Studio .NET 2003.
Imports Microsoft.VisualStudio.CommandBars
Imports Microsoft.Office.Core

Public Module RemoveAnkhMenus
    Public Sub RemoveAnkhMenus()
        DeleteAnkhCommandControls()
        DeleteAnkhCommands()
    End Sub

    Private Sub DeleteAnkhCommandControls()
        For Each bar As CommandBar In CType(DTE.CommandBars, CommandBars)
            ' Debug.WriteLine(String.Format("Processing : {0}", GetPath(bar)))

            RecurseCommandControls(bar.Controls)
        Next
    End Sub

    Private Sub RecurseCommandControls(ByVal controls As CommandBarControls)
        For Each control As CommandBarControl In controls
            ' Debug.WriteLine(String.Format("Processing : {0}", GetPath(control)))

            ' Recurse childs.
            If control.accChildCount > 0 Then
                If control.Type = MsoControlType.msoControlPopup Then
                    RecurseCommandControls(CType(control, CommandBarPopup).Controls)
                End If
            End If

            ' Delete the control if it is related to AnkhSVN.
            DeleteAnkhCommandControl(control)
        Next
    End Sub

    Private Sub DeleteAnkhCommandControl(ByVal control As CommandBarControl)
        ' Delete control if it is related to AnkhSVN.
        If control.Caption.StartsWith("Ankh") Then
            Debug.WriteLine(String.Format("Deleting control: {0}", GetPath(control)))
            control.Delete()
        End If
    End Sub

    Private Sub DeleteAnkhCommands()
        ' Delete all commands related to AnkhSVN.
        For Each command As Command In DTE.Commands
            If command.Name <> Nothing Then
                If command.Name.StartsWith("Ankh") Then
                    Debug.WriteLine(String.Format("Deleting command: {0}", command.Name))
                    command.Delete()
                End If
            End If
        Next
    End Sub

    Private Function GetPath(ByVal control As Object) As String
        If TypeOf (control) Is CommandBarControl Then
            Dim cbc As CommandBarControl
            cbc = CType(control, CommandBarControl)

            Return GetPath(cbc.Parent) + "->" + cbc.Caption
        End If

        If TypeOf (control) Is CommandBar Then
            Dim cb As CommandBar
            cb = CType(control, CommandBar)

            Return GetPath(cb.Parent) + "->" + cb.Name
        End If

        Return "DTE"
    End Function
End Module

这个宏文件必须在VS 的宏IDE中打开，直接保存为VBS项目运行必会报错的（谁试运行了不报错的可要留言）。

你可以把它添加到任意一个宏项目或新建一个宏项目，然后运行之即可。需要注意的是，这个宏会运行很久，在我的T42上估计用了大约10多分钟。

还一个解决办法就是导出VS IDE的设置，然后重置IDE。但这会丢失所有的自定义设置。如果自定义不多，完全可以使用这个方法。 只好再次回到Visual SVN了，唉...

源码控制，仍然推荐使用SVN。