flex图片导出

使用flex开发界面经常会碰到需要导出图片的情况，在flash player 10.0以前，通常的做法是：

1、先获取需要生成图片的对象的BitMapData

2、将BitMapData编码为字符串

3、将该字符串发送到server端，解码后生成图片

4、从server端下载该图片

这种方法相当于从client-->sever-->client，绕了一个圈子，在flash player 10.0中，我们可以方便使用FileReference.save()直接在client端保存图片，相当方便。

步骤如下：

1、获取需要生成图片的对象的BitMapData

2、将图片数据编码为一定格式图片

3、保存图片

代码如下：

 import flash.display.BitmapData;
 import flash.display.DisplayObject;
 import flash.display.DisplayObjectContainer;
 import flash.geom.Matrix;
 import flash.geom.Point;
 import flash.net.FileReference;
 import flash.utils.ByteArray;
 
 import mx.controls.Alert;
 import mx.graphics.codec.PNGEncoder;
 public class ChartUtils
 {
  
  public function ChartUtils(){}
  //导出图片  
  public function exportChart(d:DisplayObject):void{
   var dt:DisplayObject = d;
   var bd:BitmapData = getBitMapData(dt,dt.parent);   
   var fr:Object = new FileReference();
   if(fr.hasOwnProperty("save")){
    var encoder:PNGEncoder = new PNGEncoder();
    var data:ByteArray = encoder.encode(bd);
    fr.save(data,'chart.png');
   }else{
    Alert.show("当前flash player版本不支持此功能,请安装10.0.0以上版本！","提示");
   }
  } 
  //获得对象的BitMapData
  public function getBitMapData(mc:DisplayObject,container:DisplayObjectContainer):BitmapData{
   var bmpData:BitmapData = new BitmapData(mc.width,mc.height,true,0x00ffffff);
   var bounds:Object = mc.getBounds(mc);
   var bounds2:Object = container.getBounds(container);
   var matrix:Matrix = mc.transform.matrix.clone();
   var point0:Point = container.globalToLocal(mc.localToGlobal(new Point(bounds.x,bounds.y)));
   var point1:Point = container.globalToLocal(mc.localToGlobal(new Point(bounds.x,bounds.y+bounds.height)));
   var point2:Point = container.globalToLocal(mc.localToGlobal(new Point(bounds.x+bounds.width,bounds.y)));
   var point3:Point = container.globalToLocal(mc.localToGlobal(new Point(bounds.x+bounds.width,bounds.y+bounds.height)));
   var point:Point = point0;
   
   (point.x>point1.x)&&(point.x=point1.x);
   (point.x>point2.x)&&(point.x=point2.x);
   (point.x>point3.x)&&(point.x=point3.x);
   (point.y>point1.y)&&(point.y=point1.y);
   (point.y>point2.y)&&(point.y=point2.y);
   (point.y>point3.y)&&(point.y=point3.y);
   matrix.tx = mc.x - point.x;
   matrix.ty = mc.y - point.y;
   bmpData.draw(mc,matrix);
   return bmpData;
  }
 }

 

PS:如果SDK是flex3，那么在编译前一定要在Flex compiler的编译参数中加上-target-player=10.0.0