程序包的创建与应用
一 程序包简介
程序包(PACKAGE，简称包)是一组相关过程、函数、变量、常量和游标等PL/SQL程序设计元素的组合，作为一个完整的单元存储在数据库中，用名称来标识包。它具有面向对象程序设计语言的特点，是对这些PL/SQL 程序设计元素的封装。包类似于c#和JAVA语言中的类，其中变量相当于类中的成员变量，过程和函数相当于类方法。把相关的模块归类成为包，可使开发人员利用面向对象的方法进行存储过程的开发，从而提高系统性能。
与高级语言中的类相同，包中的程序元素也分为公用元素和私用元素两种，这两种元素的区别是他们允许访问的程序范围不同，即它们的作用域不同。公用元素不仅可以被包中的函数、过程所调用，也可以被包外的PL/SQL程序访问，而私有元素只能被包内的函数和过程序所访问。
当然，对于不包含在程序包中的过程、函数是独立存在的。一般是先编写独立的过程与函数，待其较为完善或经过充分验证无误后，再按逻辑相关性组织为程序包。
对程序包的优点可总结如下：在PL/SQL程序设计中，使用包不仅可以使程序设计模块化，对外隐藏包内所使用的信息（通过使用私用变量），而写可以提高程序的执行效率。因为，当程序首次调用包内函数或过程时，ORACLE将整个包调入内存，当再次访问包内元素时，ORACLE直接从内存中读取，而不需要进行磁盘I/O操作，从而使程序执行效率得到提高。
二 程序包的定义
程序包的定义分为程序包说明定义和程序包主体定义两部分组成：
包说明（PACKAGE）：用于声明包的公用组件，如变量、常量、自定义数据类型、异常、过程、函数、游标等。包说明中定义的公有组件不仅可以在包内使用，还可以由包外其他过程、函数。但需要说明与注意的是，我们为了实现信息的隐藏，建议不要将所有组件都放在包说明处声明，只应把公共组件放在包声明部分。包的名称是唯一的，但对于两个包中的公有组件的名称可以相同，这种用“包名.公有组件名“加以区分。
包主体（PACKAGE BODY）：是包的具体实现细节，其实现在包说明中声明的所有公有过程、函数、游标等。当然也可以在包体中声明仅属于自己的私有过程、函数、游标等。创建包体时，有以下几点需要注意：
—— 包体只能在包说明被创建或编译后才能进行创建或编译。
—— 在包体中实现的过程、函数、游标的名称必须与包说明中的过程、函数、游标一致，包括名称、参数的名称以及参数的模式（IN、OUT、IN OUT）。并建设按包说明中的次序定义包
体中具体的实现。
—— 在包体中声明的数据类型、变量、常量都是私有的，只能在包体中使用而不能被印刷体外的应用程序访问与使用。
—— 在包体执行部分，可对包说明，包体中声明的公有或私有变量进行初始化或其它设置。
创建程序包说明语法格式:
1 CREATE [OR REPLACE] PACKAGE package_name
2 [AUTHID {CURRENT_USER | DEFINER}]
3 {IS | AS}
4 [公有数据类型定义[公有数据类型定义]…]
5 [公有游标声明[公有游标声明]…]
6 [公有变量、常量声明[公有变量、常量声明]…]
7 [公有函数声明[公有函数声明]…]
8 [公有过程声明[公有过程声明]…]
9 END [package_name];
其中：AUTHID CURRENT_USER 和 AUTHID DEFINER 选项说明应用程序在调用函数时所使用的权限模式，它们与 CREATE FUNCTION 语句中 invoker_right_clause 子句的作用相同。
创建程序包主体语法格式:
1 CREATE [OR REPLACE] PACKAGE BODY package_name
2 {IS | AS}
3 [私有数据类型定义[私有数据类型定义]…]
4 [私有变量、常量声明[私有变量、常量声明]…]
5 [私有异常错误声明[私有异常错误声明]…]
6 [私有函数声明和定义[私有函数声明和定义]…]
7 [私有函过程声明和定义[私有函过程声明和定义]…]
8 [公有游标定义[公有游标定义]…]
9 [公有函数定义[公有函数定义]…]
10 [公有过程定义[公有过程定义]…]
11 BEGIN
12 执行部分(初始化部分)
13 END package_name;
其中：在包主体定义公有程序时，它们必须与包定义中所声明子程序的格式完全一致。
三 包的开发步骤
与开发存储过程类似，包的开发需要几个步骤：
1． 将每个存储过程调式正确；
2． 用文本编辑软件将各个存储过程和函数集成在一起；
3． 按照包的定义要求将集成的文本的前面加上包定义；
4． 按照包的定义要求将集成的文本的前面加上包主体；
5． 使用SQLPLUS或开发工具进行调式。
四 包定义的说明
实例：创建的包为DEMO_PKG,该包中包含一个记录变量DEPTREC、两个函数和一个过程。实现对dept表的增加、删除与查询。
1 CREATE OR REPLACE PACKAGE DEMO_PKG
2 IS
3 DEPTREC DEPT%ROWTYPE;
4
5 --Add dept...
6 FUNCTION add_dept(
7 dept_no NUMBER,
8 dept_name VARCHAR2,
9 location VARCHAR2)
10 RETURN NUMBER;
11
12 --delete dept...
13 FUNCTION delete_dept(dept_no NUMBER)
14 RETURN NUMBER;
15
16 --query dept...
17 PROCEDURE query_dept(dept_no IN NUMBER);
18 END DEMO_PKG;
包主体的创建方法，它实现上面所声明的包定义，并在包主体中声明一个私有变量flag和一个私有函数check_dept，由于在add_dept和remove_dept等函数中需要调用check_dpet函数，所以，在定义check_dept 函数之前首先对该函数进行声明，这种声明方法称作前向声明。
1 CREATE OR REPLACE PACKAGE BODY DEMO_PKG
2 IS
3 FUNCTION add_dept
4 (
5 dept_no NUMBER,
6 dept_name VARCHAR2,
7 location VARCHAR2
8 )
9 RETURN NUMBER
10 IS
11 empno_remaining EXCEPTION; --自定义异常
12 PRAGMA EXCEPTION_INIT(empno_remaining, -1);
13 /* -1 是违反唯一约束条件的错误代码 */
14 BEGIN
15 INSERT INTO dept VALUES(dept_no, dept_name, location);
16 IF SQL%FOUND THEN
17 RETURN 1;
18 END IF;
19 EXCEPTION
20 WHEN empno_remaining THEN
21 RETURN 0;
22 WHEN OTHERS THEN
23 RETURN -1;
24 END add_dept;
25
26 FUNCTION delete_dept(dept_no NUMBER)
27 RETURN NUMBER
28 IS
29 BEGIN
30 DELETE FROM dept WHERE deptno = dept_no;
31 IF SQL%FOUND THEN
32 RETURN 1;
33 ELSE
34 RETURN 0;
35 END IF;
36 EXCEPTION
37 WHEN OTHERS THEN
38 RETURN -1;
39 END delete_dept;
40
41 PROCEDURE query_dept
42 (dept_no IN NUMBER)
43 IS
44 BEGIN
45 SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no;
46 EXCEPTION
47 WHEN NO_DATA_FOUND THEN
48 DBMS_OUTPUT.PUT_LINE('温馨提示:数据库中没有编码为'||dept_no||'的部门');
49 WHEN TOO_MANY_ROWS THEN
50 DBMS_OUTPUT.PUT_LINE('程序运行错误,请使用游标进行操作!');
51 WHEN OTHERS THEN
52 DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
53 END query_dept;
54
55 BEGIN
56 Null;
57 END DEMO_PKG;
对包内共有元素的调用格式为：包名.元素名称
调用DEMO_PKG包内函数对dept表进行插入、查询和删除操作，并通过DEMO_PKG包中的记录变量DEPTREC显示所查询到的数据库信息：
1 DECLARE
2 Var NUMBER;
3 BEGIN
4 Var := DEMO_PKG.add_dept(90,'HKLORB', 'HAIKOU');
5 IF var =-1 THEN
6 DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
7 ELSIF var =0 THEN
8 DBMS_OUTPUT.PUT_LINE('温馨提示:该部门记录已经存在！');
9 ELSE
10 DBMS_OUTPUT.PUT_LINE('温馨提示:添加记录成功！');
11 DEMO_PKG.query_dept(90);
12 DBMS_OUTPUT.PUT_LINE(DEMO_PKG.DeptRec.deptno||'---'||
13 DEMO_PKG.DeptRec.dname||'---'||DEMO_PKG.DeptRec.loc);
14 var := DEMO_PKG.delete_dept(90);
15 IF var =-1 THEN
16 DBMS_OUTPUT.PUT_LINE(SQLCODE||'----'||SQLERRM);
17 ELSIF var=0 THEN
18 DBMS_OUTPUT.PUT_LINE('温馨提示:该部门记录不存在！');
19 ELSE
20 DBMS_OUTPUT.PUT_LINE('温馨提示:删除记录成功！');
21 END IF;
22 END IF;
23 END;
创建包EMP_PKG，读取emp表中的数据
1 --创建包说明
2 CREATE OR REPLACE PACKAGE EMP_PKG
3 IS
4 TYPE emp_table_type IS TABLE OF emp%ROWTYPE
5 INDEX BY BINARY_INTEGER;
6
7 PROCEDURE read_emp_table (p_emp_table OUT emp_table_type);
8 END EMP_PKG;
9
10 --创建包体
11 CREATE OR REPLACE PACKAGE BODY EMP_PKG
12 IS
13 PROCEDURE read_emp_table (p_emp_table OUT emp_table_type)
14 IS
15 I BINARY_INTEGER := 0;
16 BEGIN
17 FOR emp_record IN ( SELECT * FROM emp ) LOOP
18 P_emp_table(i) := emp_record;
19 I := I + 1;
20 END LOOP;
21 END read_emp_table;
22 END EMP_PKG;
23
24 --执行
25 DECLARE
26 E_table EMP_PKG.emp_table_type;
27 BEGIN
28 EMP_PKG.read_emp_table(e_table);
29 FOR I IN e_table.FIRST ..e_table.LAST LOOP
30 DBMS_OUTPUT.PUT_LINE(e_table(i).empno||' '||e_table(i).ename);
31 END LOOP;
32 END;
创建包MANAGE_EMP_PKG，对员工进行管理（新增员工、新增部门、删除指定员工、删除指定部门、增加指定员工的工资与奖金）：
1 --创建序列从100开始,依次增加1
2 CREATE SEQUENCE empseq
3 START WITH 100
4 INCREMENT BY 1
5 ORDER NOCYCLE;
6
7 --创建序列从100开始,依次增加10
8 CREATE SEQUENCE deptseq
9 START WITH 100
10 INCREMENT BY 10
11 ORDER NOCYCLE;
12
13 -- *******************************************
14 -- 创建包说明
15 -- 包 名：MANAGE_EMP_PKG
16 -- 功能描述：对员工进行管理(新增员工,新增部门
17 -- ,删除员工,删除部门,增加工资与奖金等)
18 -- 创建人员：胡勇
19 -- 创建日期：2010-05-19
20 -- Q Q: 80368704
21 -- E-mail : 80368704@yahoo.com.cn
22 -- WebSite: http://www.cnblogs.com/huyong
23 -- ******************************************
24 CREATE OR REPLACE PACKAGE MANAGE_EMP_PKG
25 AS
26 --增加一名员工
27 FUNCTION hire_emp
28 (ename VARCHAR2, job VARCHAR2
29 , mgr NUMBER, sal NUMBER
30 , comm NUMBER, deptno NUMBER)
31 RETURN NUMBER;
32
33 --新增一个部门
34 FUNCTION add_dept(dname VARCHAR2, loc VARCHAR2)
35 RETURN NUMBER;
36
37 --删除指定员工
38 PROCEDURE remove_emp(empno NUMBER);
39 --删除指定部门
40 PROCEDURE remove_dept(deptno NUMBER);
41 --增加指定员工的工资
42 PROCEDURE increase_sal(empno NUMBER, sal_incr NUMBER);
43 --增加指定员工的奖金
44 PROCEDURE increase_comm(empno NUMBER, comm_incr NUMBER);
45 END MANAGE_EMP_PKG;--创建包说明结束
46
47 -- *******************************************
48 -- 创建包体
49 -- 包 名：MANAGE_EMP_PKG
50 -- 功能描述：对员工进行管理(新增员工,新增部门
51 -- ,删除员工,删除部门,增加工资与奖金等)
52 -- 创建人员：胡勇
53 -- 创建日期：2010-05-19
54 -- Q Q: 80368704
55 -- E-mail : 80368704@yahoo.com.cn
56 -- WebSite: http://www.cnblogs.com/huyong
57 -- ******************************************
58 CREATE OR REPLACE PACKAGE BODY MANAGE_EMP_PKG
59 AS
60 total_emps NUMBER; --员工数
61 total_depts NUMBER; --部门数
62 no_sal EXCEPTION;
63 no_comm EXCEPTION;
64 --增加一名员工
65 FUNCTION hire_emp(ename VARCHAR2, job VARCHAR2, mgr NUMBER,
66 sal NUMBER, comm NUMBER, deptno NUMBER)
67 RETURN NUMBER --返回新增加的员工编号
68 IS
69 new_empno NUMBER(4);
70 BEGIN
71 SELECT empseq.NEXTVAL INTO new_empno FROM dual;
72 SELECT COUNT(*) INTO total_emps FROM emp;--当前记录总数
73
74 INSERT INTO emp
75 VALUES (new_empno, ename, job, mgr, sysdate, sal, comm, deptno);
76 total_emps:=total_emps+1;
77 RETURN(new_empno);
78 EXCEPTION
79 WHEN OTHERS THEN
80 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
81 END hire_emp;
82
83 --新增一个部门
84 FUNCTION add_dept(dname VARCHAR2, loc VARCHAR2)
85 RETURN NUMBER
86 IS
87 new_deptno NUMBER(4); --部门编号
88 BEGIN
89 --得到一个新的自增的员工编号
90 SELECT deptseq.NEXTVAL INTO new_deptno FROM dual;
91 SELECT COUNT(*) INTO total_depts FROM dept;--当前部门总数
92 INSERT INTO dept VALUES (new_deptno, dname, loc);
93 total_depts:=total_depts;
94 RETURN(new_deptno);
95 EXCEPTION
96 WHEN OTHERS THEN
97 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
98 END add_dept;
99
100 --删除指定员工
101 PROCEDURE remove_emp(empno NUMBER)
102 IS
103 no_result EXCEPTION; --自定义异常
104 BEGIN
105 DELETE FROM emp WHERE emp.empno=remove_emp.empno;
106 IF SQL%NOTFOUND THEN
107 RAISE no_result;
108 END IF;
109 total_emps:=total_emps - 1; --总的员工数减1
110 EXCEPTION
111 WHEN no_result THEN
112 DBMS_OUTPUT.PUT_LINE('温馨提示:你需要的数据不存在!');
113 WHEN OTHERS THEN
114 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
115 END remove_emp;
116
117 --删除指定部门
118 PROCEDURE remove_dept(deptno NUMBER)
119 IS
120 no_result EXCEPTION; --自定义异常
121 exception_deptno_remaining EXCEPTION; --自定义异常
122 /*-2292 是违反一致性约束的错误代码*/
123 PRAGMA EXCEPTION_INIT(exception_deptno_remaining, -2292);
124 BEGIN
125 DELETE FROM dept WHERE dept.deptno=remove_dept.deptno;
126
127 IF SQL%NOTFOUND THEN
128 RAISE no_result;
129 END IF;
130 total_depts:=total_depts-1; --总的部门数减1
131 EXCEPTION
132 WHEN no_result THEN
133 DBMS_OUTPUT.PUT_LINE('温馨提示:你需要的数据不存在!');
134 WHEN exception_deptno_remaining THEN
135 DBMS_OUTPUT.PUT_LINE('温馨提示:违反数据完整性约束!');
136 WHEN OTHERS THEN
137 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
138 END remove_dept;
139
140 --给指定员工增加指定数量的工资
141 PROCEDURE increase_sal(empno NUMBER, sal_incr NUMBER)
142 IS
143 curr_sal NUMBER(7, 2); --当前工资
144 BEGIN
145 --得到当前工资
146 SELECT sal INTO curr_sal FROM emp WHERE emp.empno=increase_sal.empno;
147
148 IF curr_sal IS NULL THEN
149 RAISE no_sal;
150 ELSE
151 UPDATE emp SET sal = sal + increase_sal.sal_incr --当前工资加新增的工资
152 WHERE emp.empno = increase_sal.empno;
153 END IF;
154 EXCEPTION
155 WHEN NO_DATA_FOUND THEN
156 DBMS_OUTPUT.PUT_LINE('温馨提示:你需要的数据不存在!');
157 WHEN no_sal THEN
158 DBMS_OUTPUT.PUT_LINE('温馨提示:此员工的工资不存在!');
159 WHEN OTHERS THEN
160 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
161 END increase_sal;
162
163 --给指定员工增加指定数量的奖金
164 PROCEDURE increase_comm(empno NUMBER, comm_incr NUMBER)
165 IS
166 curr_comm NUMBER(7,2);
167 BEGIN
168 --得到指定员工的当前资金
169 SELECT comm INTO curr_comm
170 FROM emp WHERE emp.empno = increase_comm.empno;
171
172 IF curr_comm IS NULL THEN
173 RAISE no_comm;
174 ELSE
175 UPDATE emp SET comm = comm + increase_comm.comm_incr
176 WHERE emp.empno=increase_comm.empno;
177 END IF;
178 EXCEPTION
179 WHEN NO_DATA_FOUND THEN
180 DBMS_OUTPUT.PUT_LINE('温馨提示:你需要的数据不存在!');
181 WHEN no_comm THEN
182 DBMS_OUTPUT.PUT_LINE('温馨提示:此员工的奖金不存在!');
183 WHEN OTHERS THEN
184 DBMS_OUTPUT.PUT_LINE('温馨提示:发生系统错误!');
185 END increase_comm;
186 END MANAGE_EMP_PKG;--创建包体结束
187
188 --调用
189 SQL> variable empno number
190 SQL>execute :empno:= manage_emp_pkg.hire_emp('HUYONG',PM,1455,5500,14,10)
191
192 PL/SQL procedure successfully completed
193 empno
194 ---------
195 105
利用游标变量创建包 CURROR_VARIBAL_PKG。由于游标变量指是一个指针，其状态是不确定的，因此它不能随同包存储在数据库中，既不能在PL/SQL包中声明游标变量。但在包中可以创建游标变量参照类型，并可向包中的子程序传递游标变量参数。
1 -- *******************************************
2 -- 创建包体
3 -- 包 名：CURROR_VARIBAL_PKG
4 -- 功能描述：在包中引用游标变量
5 -- 创建人员：胡勇
6 -- 创建日期：2010-05-19
7 -- Q Q: 80368704
8 -- E-mail : 80368704@yahoo.com.cn
9 -- WebSite: http://www.cnblogs.com/huyong
10 -- ******************************************
11 CREATE OR REPLACE PACKAGE CURROR_VARIBAL_PKG AS
12 TYPE DeptCurType IS REF CURSOR
13 RETURN dept%ROWTYPE; --强类型定义
14
15 TYPE CurType IS REF CURSOR;-- 弱类型定义
16
17 PROCEDURE OpenDeptVar(
18 Cv IN OUT DeptCurType,
19 Choice INTEGER DEFAULT 0,
20 Dept_no NUMBER DEFAULT 50,
21 Dept_name VARCHAR DEFAULT '%');
22 END;
23
24 -- *******************************************
25 -- 创建包体
26 -- 包 名：CURROR_VARIBAL_PKG
27 -- 功能描述：在包中引用游标变量
28 -- 创建人员：胡勇
29 -- 创建日期：2010-05-19
30 -- Q Q: 80368704
31 -- E-mail : 80368704@yahoo.com.cn
32 -- WebSite: http://www.cnblogs.com/huyong
33 -- ******************************************
34 CREATE OR REPLACE PACKAGE BODY CURROR_VARIBAL_PKG
35 AS
36 PROCEDURE OpenDeptvar(
37 Cv IN OUT DeptCurType,
38 Choice INTEGER DEFAULT 0,
39 Dept_no NUMBER DEFAULT 50,
40 Dept_name VARCHAR DEFAULT ‘%’)
41 IS
42 BEGIN
43 IF choice =1 THEN
44 OPEN cv FOR SELECT * FROM dept WHERE deptno <= dept_no;
45 ELSIF choice = 2 THEN
46 OPEN cv FOR SELECT * FROM dept WHERE dname LIKE dept_name;
47 ELSE
48 OPEN cv FOR SELECT * FROM dept;
49 END IF;
50 END OpenDeptvar;
51 END CURROR_VARIBAL_PKG;
52
53 --定义一个过程
54 CREATE OR REPLACE PROCEDURE UP_OpenCurType(
55 Cv IN OUT CURROR_VARIBAL_PKG.CurType,
56 FirstCapInTableName CHAR)
57 AS
58 BEGIN
59 --CURROR_VARIBAL_PKG.CurType采用弱类型定义
60 --所以可以使用它定义的游标变量打开不同类型的查询语句
61 IF FirstCapInTableName = 'D' THEN
62 OPEN cv FOR SELECT * FROM dept;
63 ELSE
64 OPEN cv FOR SELECT * FROM emp;
65 END IF;
66 END UP_OpenCurType;
67
68
69 --定义一个应用
70 DECLARE
71 DeptRec Dept%ROWTYPE;
72 EmpRec Emp%ROWTYPE;
73 Cv1 CURROR_VARIBAL_PKG.deptcurtype;
74 Cv2 CURROR_VARIBAL_PKG.curtype;
75 BEGIN
76 DBMS_OUTPUT.PUT_LINE('游标变量强类型定义应用');
77 CURROR_VARIBAL_PKG.OpenDeptVar(cv1, 1, 30);
78 FETCH cv1 INTO DeptRec;
79 WHILE cv1%FOUND LOOP
80 DBMS_OUTPUT.PUT_LINE(DeptRec.deptno||':'||DeptRec.dname);
81 FETCH cv1 INTO DeptRec;
82 END LOOP;
83 CLOSE cv1;
84
85 DBMS_OUTPUT.PUT_LINE('游标变量弱类型定义应用');
86 CURROR_VARIBAL_PKG.OpenDeptvar(cv2, 2, dept_name => 'A%');
87 FETCH cv2 INTO DeptRec;
88 WHILE cv2%FOUND LOOP
89 DBMS_OUTPUT.PUT_LINE(DeptRec.deptno||':'||DeptRec.dname);
90 FETCH cv2 INTO DeptRec;
91 END LOOP;
92
93 DBMS_OUTPUT.PUT_LINE('游标变量弱类型定义应用—dept表');
94 UP_OpenCurType(cv2, 'D');
95 FETCH cv2 INTO DeptRec;
96 WHILE cv2%FOUND LOOP
97 DBMS_OUTPUT.PUT_LINE(deptrec.deptno||':'||deptrec.dname);
98 FETCH cv2 INTO deptrec;
99 END LOOP;
100
101 DBMS_OUTPUT.PUT_LINE('游标变量弱类型定义应用—emp表');
102 UP_OpenCurType(cv2, 'E');
103 FETCH cv2 INTO EmpRec;
104 WHILE cv2%FOUND LOOP
105 DBMS_OUTPUT.PUT_LINE(emprec.empno||':'||emprec.ename);
106 FETCH cv2 INTO emprec;
107 END LOOP;
108 CLOSE cv2;
109 END;
110 ----------运行结果-------------------
111 游标变量强类型定义应用
112 10:ACCOUNTING
113 20:RESEARCH
114 30:SALES
115 游标变量弱类型定义应用
116 10:ACCOUNTING
117 游标变量弱类型定义应用—dept表
118 10:ACCOUNTING
119 20:RESEARCH
120 30:SALES
121 40:OPERATIONS
122 50:50abc
123 60:Developer
124 游标变量弱类型定义应用—emp表
125 7369:SMITH
126 7499:ALLEN
127 7521:WARD
128 7566:JONES
129 7654:MARTIN
130 7698:BLAKE
131 7782:CLARK
132 7788:SCOTT
133 7839:KING
134 7844:TURNER
135 7876:ADAMS
136 7900:JAMES
137 7902:FORD
138 7934:MILLER
139
140 PL/SQL procedure successfully completed
五 子程序重载
PL/SQL允许对包内子程序和本地子程序进行重载。所谓重载是指两个或多个子程序有相同的名称，但拥有不同的参数变量、参数顺序或参数数据类型。
实例：
1 -- *******************************************
2 -- 创建包说明
3 -- 包 名：DEMO_PKG1
4 -- 功能描述：创建包对子程序重载进行测试
5 -- 创建人员：胡勇
6 -- 创建日期：2010-05-22
7 -- Q Q: 80368704
8 -- E-mail : 80368704@yahoo.com.cn
9 -- WebSite: http://www.cnblogs.com/huyong
10 -- ******************************************
11 CREATE OR REPLACE PACKAGE DEMO_PKG1
12 IS
13 DeptRec dept%ROWTYPE;
14 V_sqlcode NUMBER;
15 V_sqlerr VARCHAR2(2048);
16
17 --两个子程序名字相同,但参数类型不同
18 FUNCTION query_dept(dept_no IN NUMBER)
19 RETURN INTEGER;
20
21 FUNCTION query_dept(dept_no IN VARCHAR2)
22 RETURN INTEGER;
23 END DEMO_PKG1;
24
25 -- *******************************************
26 -- 创建包体
27 -- 包 名：DEMO_PKG1
28 -- 功能描述：创建包对子程序重载进行测试
29 -- 创建人员：胡勇
30 -- 创建日期：2010-05-22
31 -- Q Q: 80368704
32 -- E-mail : 80368704@yahoo.com.cn
33 -- WebSite: http://www.cnblogs.com/huyong
34 -- ******************************************
35 CREATE OR REPLACE PACKAGE BODY DEMO_PKG1
36 IS
37 FUNCTION check_dept(dept_no NUMBER)
38 RETURN INTEGER
39 IS
40 deptCnt INTEGER; --指定部门号的部门数量
41 BEGIN
42 SELECT COUNT(*) INTO deptCnt FROM dept WHERE deptno = dept_no;
43 IF deptCnt > 0 THEN
44 RETURN 1;
45 ELSE
46 RETURN 0;
47 END IF;
48 END check_dept;
49
50 FUNCTION check_dept(dept_no VARCHAR2)
51 RETURN INTEGER
52 IS
53 deptCnt INTEGER;
54 BEGIN
55 SELECT COUNT(*) INTO deptCnt FROM dept WHERE deptno=dept_no;
56 IF deptCnt > 0 THEN
57 RETURN 1;
58 ELSE
59 RETURN 0;
60 END IF;
61 END check_dept;
62
63 FUNCTION query_dept(dept_no IN NUMBER)
64 RETURN INTEGER
65 IS
66 BEGIN
67 IF check_dept(dept_no) =1 THEN
68 SELECT * INTO DeptRec FROM dept WHERE deptno=dept_no;
69 RETURN 1;
70 ELSE
71 RETURN 0;
72 END IF;
73 END query_dept;
74
75 FUNCTION query_dept(dept_no IN VARCHAR2)
76 RETURN INTEGER
77 IS
78 BEGIN
79 IF check_dept(dept_no) =1 THEN
80 SELECT * INTO DeptRec FROM dept WHERE deptno = dept_no;
81 RETURN 1;
82 ELSE
83 RETURN 0;
84 END IF;
85 END query_dept;
86
87 END DEMO_PKG1;
六 加密实用程序
ORACLE 提供了一个实用工具来加密或者包装用户的PL/SQL，它会将用户的PL/SQL改变为只有ORACLE能够解释的代码版本．
WRAP 实用工具位于$ORACLE_HOME/BIN.
格式为：
WRAP INAME=<input_file_name> [ONAME=<output_file_name>]
wrap iname=e:\sample.txt
注意：在加密前，请将PL/SQL程序先保存一份，以备后用。
七 删除包
可以使用 DROP PACKAGE 命令对不需要的包进行删除，语法如下：
1 DROP PACKAGE [BODY] [user.]package_name;
2
3 DROP PROCEDURE OpenCurType; --删除存储过程
4 --删除我们实例中创建的各个包
5 DROP PACKAGE demo_pack;
6 DROP PACKAGE demo_pack1;
7 DROP PACKAGE emp_mgmt;
8 DROP PACKAGE emp_package;
八 包的管理
包与过程、函数一样，也是存储在数据库中的，可以随时查看其源码。若有需要，在创建包时可以随时查看更详细的编译错误。不需要的包也可以删除。
同样，为了避免调用的失败，在更新表的结构后，一定要记得重新编译依赖于它的程序包。在更新了包说明或包体后，也应该重新编译包说明与包体。语法如下：
ALTER PACKAGE package_name COMPILE [PACKAGE|BODY|SPECIFICATION];
也可以通过以下数据字典视图查看包的相关。
DBA_SOURCE, USER_SOURCE, USER_ERRORS,DBA-OBJECTS
如，我们可以用：select text from user_source wherename='DEMO_PKG1';来查看我们创建的包的源码。
