ARM汇编中的LDR及ADR的区别及其在U-BOOT中的应用

我在看U-BOOT的lowlevel_init.S文件时看到以下代码：

 1 lowlevel_init:
 2 ldr r0, =SMRDATA
 3 ldr r1, _TEXT_BASE
 4 sub r0, r0, r1
 5 ldr r1, =BWSCON
 6 add r2, r0, #13*4
 7 0:
 8 ldr r3, [r0], #4
 9 str r3, [r1], #4
10 cmp r2, r0
11 bne 0b
12 mov pc, lr

这段代码实现了U-BOOT的内存控制器部分的寄存器初始化，一共13个寄存器，对U-BOOT来最重要的就是SDRAM的初始化，显然没有这部分代码，当U-BOOT从NAND FLASH中启动的时候，START.S文件是无法完成代码的relocate的。因为SDRAM没初始化,用不了。

要理解这段代码主要是搞清楚LDR的两种用法。

ldr r0, =SMRDATA的作用是让r0等于U-BOOT编译时已经确定下来的SMRDATA这块内存缓冲池的起始地址。
ldr r1, _TEXT_BASE的作用则是让r1等于_TEXT_BASE这个标号所在的内存里面的内容，也就是 TEXT_BASE。对于MINI2440开发板来说这个值等TEXT_BASE = 0x33F80000（\board\samsung\mini2440\config.mk）这个地址是由于TEXT_BASE实际的地址现在应该是FLASH的0地址(或者内部4KSRAM的0地址)，所以第三条指令 sub r0, r0, r1 ，实现了计算SMRDATA当前在arm地址空间里的实际访问地址。


接下去就是通过
ldr r3, [r0], #4 ；从r0这个地址里取一个32bit的数据，放到r3,并将r0+4，指向下一个内存池里的数据。
str r3, [r1], #4 ；这条指令实现了把r3里的数据赋值给r1所标示的地址。r1的地址通过下面这几句实现。以此配置完从0x48000000开始的CPU内部寄存器的值。这样SDRAM就开始工作了。以后就是正常访问0x30000000开始的地址空间了。

#define BWSCON 0x48000000
ldr r1, =BWSCON /* Bus Width Status Controller */

上面的这个配置代码是无法在将U-BOOT直接用OPENJTAG下载到OPENJTAG中时工作的。因为当下载到内存中的时候，SDRAM的地址是随机的，至少不是从0开始的，这样得到的SMRDATA所在的地址按上面的方式是得不到的，所以需要一条在运行时地址与位置无关的指令。这就是 adr指令。下面代码就是改进后的：

 1 lowlevel_init:
 2 /* memory control configuration */
 3 /* make r0 relative the current location so that it */
 4 /* reads SMRDATA out of FLASH rather than memory ! */
 5 ldr r0, =SMRDATA
 6 ldr r1, =lowlevel_init /*编译时确定的地址*/
 7 sub r0, r0, r1 /* r0 = r0 -r1 , r0 = SMRDATA相对于lowlevel_init的偏移值 */
 8 adr r3, lowlevel_init /*位置无关*/
 9 add r0,r0,r3 /*r0 = r0 +r3 ，r0存放的是当前SMRDATA的实际地址*/
10 ldr r1, =BWSCON /* Bus Width Status Controller */
11 add r2, r0, #13*4
12 0:
13 ldr r3, [r0], #4
14 str r3, [r1], #4
15 cmp r2, r0
16 bne 0b

posted on 2012-10-07 15:55  robin.he  阅读(2247)  评论(0)    收藏  举报

导航