实验3 转移指令跳转原理及其简单应用编程

1、实验任务1

（1）给出程序task1.asm源码，及，运行截图 

assume cs:code, ds:data

data segment
    x db 1, 9, 3
    len1 equ $ - x

    y dw 1, 9, 3
    len2 equ $ - y
data ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov si, offset x
    mov cx, len1
    mov ah, 2
 s1:mov dl, [si]
    or dl, 30h
    int 21h

    mov dl, ' '
    int 21h

    inc si
    loop s1

    mov ah, 2
    mov dl, 0ah
    int 21h

    mov si, offset y
    mov cx, len2/2
    mov ah, 2
 s2:mov dx, [si]
    or dl, 30h
    int 21h

    mov dl, ' '
    int 21h

    add si, 2
    loop s2

    mov ah, 4ch
    int 21h
code ends
end start

 （2）

回答问题①  

① line27, 汇编指令 loop s1 跳转时，是根据位移量跳转的。通过debug反汇编，查看其机器码，分析其跳转的位移量是多少？（位移量数值以十进制数值回答）从CPU的角度，说明 是如何计算得到跳转后标号s1其后指令的偏移地址的。

位移量是12  loop 标号的功能是在cx不小于0时做jmp short的循环，是根据本条指令的后一个字节F2，F2是-14的补码，这就是转移的位移量

回答问题②
② line44，汇编指令 loop s2 跳转时，是根据位移量跳转的。通过debug反汇编，查看其机器码，分析其跳转的位移量是多少？（位移量数值以十进制数值回答）从CPU的角度，说明 是如何计算得到跳转后标号s2其后指令的偏移地址的。

位移量是14  loop 标号的功能是在cx不小于0时做jmp short的循环，是根据本条指令的后一个字节F0，F0是-16的补码，这就是转移的位移量

问题③

③ 附上上述分析时，在debug中进行调试观察的反汇编截图

 

 

 2. 实验任务2

（1）给出程序task2.asm源码 

assume cs:code, ds:data

data segment
    dw 200h, 0h, 230h, 0h
data ends

stack segment
    db 16 dup(0)
stack ends

code segment
start:  
    mov ax, data
    mov ds, ax

    mov word ptr ds:[0], offset s1
    mov word ptr ds:[2], offset s2
    mov ds:[4], cs

    mov ax, stack
    mov ss, ax
    mov sp, 16

    call word ptr ds:[0]
s1: pop ax

    call dword ptr ds:[2]
s2: pop bx
    pop cx

    mov ah, 4ch
    int 21h
code ends
end start

（2）

给出分析、调试、验证后，寄存器(ax) = ? （bx) = ? （cx) = ? 附上调试结果界面截图。
① 根据call指令的跳转原理，先从理论上分析，程序执行到退出（line31)之前，寄存器(ax) = 0021h 寄存器(bx) = 0026h 寄存器(cx) = 076ch

 

② 对源程序进行汇编、链接，得到可执行程序task2.exe。使用debug调试，观察、验证调试 结果与理论分析结果是否一致。

理论分析: ds:[0]将s1的偏移地址进栈,然后出栈存入ax，ds:[2]中先将s2的偏移地址进栈,再将s2的段地址压入栈,然后段地址先出存入bx,偏移地址存入cx,验证正确。

3. 实验任务3

（1）给出程序源码task3.asm 

assume cs:code,ds:data
data segment
   x db 99, 72, 85, 63, 89, 97, 55 
   len equ $- x 
data ends

code segment
start:
   mov ax,data
   mov ds,ax
   mov cx,len
   mov si,offset x

s: mov ah,0
   mov al,[si]
   mov bl,10
   div bl
   call printNumber
   call printSpace
   inc si
   loop s

   mov ah,4ch
   int 21h

printNumber:
   mov bx,ax
   mov ah,2
   mov dl,bl
   add dl,30h
   int 21h
   mov dl,bh
   add dl,30h
   int 21h
   ret

printSpace:
   mov ah,2
   mov dl,' '
   int 21h
   ret

code ends
end start

（2）运行测试截图

4. 实验任务4

（1）给出程序源码task4.asm

assume cs:code ds:data

data segment    
  str db 'try'    
  len equ $ - str 
data ends

code segment
start:
  mov ax,data
  mov ds,ax

  mov si,offset str
  mov bh,0
  mov bl,2
  call printStr

  mov si,offset str
  mov bh,24
  mov bl,4
  call printStr

  mov ah,4ch
  int 21h

printStr:
  mov cx,len
  mov ax,0b800h
  mov es,ax
  mov al,0a0h
  mul bh
  mov di,ax

s:mov al,ds:[si]
  mov ah,bl
  mov es:[di],ax
  inc si
  add di,2
  loop s
  ret

code ends
end start

（2）运行测试截图

5. 实验任务5

（1）给出程序源码task5.asm 

 

assume cs:code ds:data

data segment
stu_no db '201983290119' 
len = $ - stu_no 
data ends

code segment
start:
    mov ax,data
    mov ds,ax
    mov bx,0

    mov ax,0b800h
    mov es,ax
    mov cx,80
    mov si,0f00h
    mov dl,'-'
s1: mov es:[si],dl;将最后一行全部填充-
    add si,2
    loop s1

    mov cx,len
    mov si,0f44h
s2: mov dl,ds:[bx];从最后一行68字节开始填充学号
    mov es:[si],dl
    add si,2
    inc bx
    loop s2

    mov cx,2000
    mov si,1
    mov dl,17h
s3: mov es:[si],dl;全部填充蓝色
    add si,2
    loop s3

    mov ax,4c00h
    int 21h

code ends
end start

（2）运行测试截图