bzoj3275: Number

3275: Number

Time Limit: 10 Sec  Memory Limit: 128 MB
Submit: 892  Solved: 383
[Submit][Status][Discuss]

Description

有N个正整数，需要从中选出一些数，使这些数的和最大。
若两个数a,b同时满足以下条件，则a,b不能同时被选
1:存在正整数C，使a*a+b*b=c*c
2:gcd(a,b)=1

Input

第一行一个正整数n，表示数的个数。

第二行n个正整数a1,a2,?an。

 

 

Output

最大的和。

 

Sample Input

5
3 4 5 6 7

Sample Output

22

HINT

 

n<=3000。

题解

首先观察出可以把数字按奇数和偶数变成二分图，因为第一条性质保证了奇数和奇数之间没有边（奇数的平方和模4余2，而是偶数的平方数是4的倍数），第二条性质保证了偶数和偶数之间没有边。然后把奇数连s，偶数连T，容量是权值；奇数和偶数之间满足条件就连容量无穷打的边。这样最后答案要保证选出来的点组成的子图中S到T不连通，所以割某条边就相当于这个数不在集合里，最大化选的点的圈就是最小化割的权。最后所有点的权和减去最小割就行。

program j01;
const maxn=3006;maxm=1000086;
var flow,next,q:array[0..maxm]of longint;
    head:array[0..maxn]of longint;
    dis,l,a:array[0..maxn]of longint;
    s,t,tt,n,i,j:longint;
    ans:int64;

procedure add(u,v,w:longint);
begin
  inc(tt);q[tt]:=v;next[tt]:=head[u];head[u]:=tt;flow[tt]:=w;
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;

function gcd(a,b:longint):longint;
begin
  if b=0 then exit(a) else exit(gcd(b,a mod b));
end;

function jud(a,b:int64):boolean;
var tmp,m:int64;
begin
  tmp:=a*a+b*b;
  m:=trunc(sqrt(tmp));
  exit(m*m=tmp);
end;

function bfs:boolean;
var h,tail,i,j:longint;
begin
  h:=0;tail:=1;l[1]:=s;
  fillchar(dis,sizeof(dis),$3f);dis[s]:=0;
  while h<>tail do
  begin
    inc(h);i:=l[h];j:=head[i];
    while j>0 do
    begin
      if (dis[i]+1<dis[q[j]])and(flow[j]>0) then
      begin
        dis[q[j]]:=dis[i]+1;
        inc(tail);l[tail]:=q[j];
      end;
      j:=next[j];
    end;
  end;
  if dis[t]=$3f3f3f3f then exit(false) else exit(true);
end;

function dfs(i,ll:longint):longint;
var j,x,tmp:longint;
begin
  if i=t then exit(ll);
  j:=head[i];x:=0;
  while j>0 do
  begin
    if (dis[q[j]]=dis[i]+1)and(flow[j]>0) then
    begin
      tmp:=dfs(q[j],min(ll-x,flow[j]));
      dec(flow[j],tmp);
      inc(flow[j xor 1],tmp);
      inc(x,tmp);
      if x=ll then exit(x);
    end;
    j:=next[j];
  end;
  if x=0 then dis[i]:=-1;
  exit(x);
end;

begin
  readln(n);
  s:=0;t:=n+1;tt:=1;ans:=0;
  for i:=1 to n do
  begin
    read(a[i]);ans:=ans+a[i];
    if a[i] mod 2=1 then
    begin
      add(s,i,a[i]);add(i,s,0);
    end else
    begin
      add(i,t,a[i]);add(t,i,0);
    end;
  end;
  for i:=1 to n do
    if a[i] mod 2=1 then
      for j:=1 to n do
        if a[j] mod 2=0 then
          if (gcd(a[i],a[j])=1)and jud(a[i],a[j]) then
          begin
            add(i,j,maxlongint);
            add(j,i,0);
          end;
  while bfs do
    ans:=ans-dfs(s,maxlongint);
  writeln(ans);
end.