实验四 8086标志寄存器及中断

一、

assume cs:code, ds:data

data segment
   x dw 1020h, 2240h, 9522h, 5060h, 3359h, 6652h, 2530h, 7031h
   y dw 3210h, 5510h, 6066h, 5121h, 8801h, 6210h, 7119h, 3912h
data ends
code segment 
start:
    mov ax, data
    mov ds, ax
    mov si, offset x
    mov di, offset y
    call add128

    mov ah, 4ch
    int 21h

add128:
    push ax
    push cx
    push si
    push di

    sub ax, ax

    mov cx, 8
s:  mov ax, [si]
    adc ax, [di]
    mov [si], ax

    inc si
    inc si
    inc di
    inc di
    loop s

    pop di
    pop si
    pop cx
    pop ax
    ret
code ends
end start

　　（1）不能替换，因为add指令会改变CF的值，使进位出错

（2）

二、

assume cs:code, ds:data
data segment
str db 80 dup(?)
data ends
code segment
start:
mov ax, data
mov ds, ax
mov si, 0
s1:
mov ah, 1
int 21h
mov [si], al
cmp al, '#'
je next
inc si
jmp s1
next:
mov ah, 2
mov dl, 0ah
int 21h
mov cx, si
mov si, 0
s2: mov ah, 2
mov dl, [si]
int 21h
inc si
loop s2
mov ah, 4ch
int 21h
code ends
end start

　　

（1）作用：输入字符到al,存入[si]，和'#'比较，相等进入next，不相等顺序执行

（2）输出换行符

（3）输出字符si次，由于最后一次si没有增加，所以'#'不输出

三、

assume ds:data, cs:code, ss:stack

data segment
    x dw 91, 792, 8536, 65535, 2021, 0
    len equ $ - x
data ends

stack segment
    db 16 dup(0)
stack ends

code segment
start:
    mov ax, data
    mov ds, ax

    mov ax, stack
    mov ss, ax
    mov sp, 16

    mov di, offset x
    mov cx, len/2 ; len/2
    foreach:
        mov ax, word ptr ds:[di]
        
        push cx
        call printNumber
        pop cx
        
        mov ah, 2
        mov dl, 20h
        int 21h
        
        add di, 2
        loop foreach
    mov ah, 4ch
    int 21h

;ax：
printNumber:
    mov bx, 0
    num:
        mov dx, 0
        mov bp, 10
        div bp;dxax/bp
        push dx;
        inc bx;
        
        cmp ax, 0
        je next
        jmp num
        
    next:
    
    mov cx, bx;
    print:
        pop dx
        add dl, 30h;
        mov ah, 2
        int 21h
        loop print 

    ret

code ends
end start

　　

四、

data segment 
    str1 db "assembly language, it's not difficult but tedious" 
    len equ $ - str1
data ends

stack segment
    db 16 dup(0)
stack ends

code segment
    assume cs:code,ds:data,ss:stack
start:
    mov ax,data
    mov ds,ax
    mov si,offset str1
    mov cx,len
    call strupr
    
    mov ah,4ch
    int 21h
strupr:
s:
    mov al,ds:[si]
    
    cmp al,'a'
    jb next
    cmp al,'z'
    ja next
    
    and al,0dfh;1101 1111
    mov ds:[si],al
    
next:
    inc si
    loop s
    ret

code ends
end start

　　

五、

 assume cs:code, ds:data
data segment
str1 db "yes", '$'
str2 db "no", '$'
data ends
code segment
start:
mov ax, data
mov ds, ax
mov ah, 1
int 21h ; 从键盘输入字符
mov ah, 2
mov bh, 0
mov dh, 24 ; 设置光标位置在第24行
mov dl, 70 ; 设置光标位置在第70列
int 10h ; 设置光标位置
cmp al, '7'
je s1
mov ah, 9
mov dx, offset str2
int 21h ; 显示标号str2处的字符串
jmp over
s1: mov ah, 9
mov dx, offset str1
int 21h ; 显示标号str2处的字符串
over:
mov ah, 4ch
int 21h
code ends
end start

　　

程序功能：

将从键盘输入的字符与7进行比较，如果相同，则输出数据段的str1标号处数据yes；

如果不相同，则输出数据段的str2标号处数据no。

六、

（1）

assume cs:code

code segment
start:
    ; 42 interrupt routine install code
    mov ax, cs
    mov ds, ax
    mov si, offset int42  ; set ds:si

    mov ax, 0
    mov es, ax
    mov di, 200h        ; set es:di

    mov cx, offset int42_end - offset int42
    cld
    rep movsb

    ; set IVT(Interrupt Vector Table)
    mov ax, 0
    mov es, ax
    mov word ptr es:[42*4], 200h
    mov word ptr es:[42*4+2], 0

    mov ah, 4ch
    int 21h

int42: 
    jmp short int42_start
    str db "welcome to 2049!"
    len equ $ - str

    ; display string "welcome to 2049!"
int42_start:
    mov ax, cs
    mov ds, ax
    mov si, 202h

    mov ax, 0b800h
    mov es, ax
    mov di, 24*160 + 32*2

    mov cx, len
s:  mov al, [si]
    mov es:[di], al
    mov byte ptr es:[di+1], 2
    inc si
    add di, 2
    loop s

    iret
int42_end:
   nop
code ends
end start

　　（2）

assume cs:code

code segment
start:
    int 42

    mov ah, 4ch
    int 21h
code ends
end start

　　

运行程序过后，通过实现中断，在屏幕底部的中间成功显示绿色的“welcome to 2049!”。在程序exe6_1.asm中，先将si赋值为标号int42的地址，将di赋值为200h，然后利用rep movsb指令，将int42到int42_end的指令复制到0:200h开始的连续内存空间，接着设置中断向量表，使得exe6_2.asm中通过int42可以跳转到中断处理程序。标号int42到int42_end的指令则实现了在屏幕第0页的最后一行中间打印绿色的“welcome to 2049!”