【ZJOI2017 Round1练习】D4T2 trie（贪心，状压DP）

题意：现在 Matej 手上有 N 个英文小写字母组成的单词，

他想知道，如果将这 N 个单词中的字母分别进行重新排列，形成的字母树的节点数最少是多少。

n<=16,len[i]<=1000000

思路：

显然，如果我们希望 Trie 树的节点数尽量少，我们应该先将所有单词公共的字母拿出来，作为 Trie 树最上几层的初始链。

比如说我们有 aaab， baab 和 cab 三个单词，我们会将ab 挑出来，然后剩下的单词就变成了 aa， ab， c。

对于剩下的单词， 我们将其分成两个子集，（ aa， ab）和（ c），并分别再计算最长的公

共字母链。显然，当集合中有 n 个单词时，有 2^n种方式将这些单词分成两个子集。
由此，我们可以用状态压缩 dp 解决这个问题。一个状态由单词的子集来描述，也就是
说我们有 2^n个状态，并计算每一种子集形成 Trie 树需要的最少节点数，转移时枚举如何将
子集分裂成两个更小的子集，即可解决整个问题。整个算法总的时间复杂度为 O(3^n)。

var a:array[1..16,1..26]of longint;
    dp,f:array[0..200000]of longint;
    num:array[1..26]of longint;
    n,i,j,k:longint;
    ch:ansistring;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure dfs(k,sta:longint);
var i,j:longint;
begin
 if k=n+1 then
 begin
  f[sta]:=0;
  for i:=1 to 26 do num[i]:=1<<25;
  for i:=1 to n do
   if sta and (1<<(i-1))>0 then
    for j:=1 to 26 do num[j]:=min(num[j],a[i,j]);
  for i:=1 to 26 do f[sta]:=f[sta]+num[i];
  exit;
 end;
 dfs(k+1,(sta<<1)+1);
 dfs(k+1,sta<<1);
end;

begin
 assign(input,'trie.in'); reset(input);
 assign(output,'trie.out'); rewrite(output);
 readln(n);
 fillchar(dp,sizeof(dp),$7f);
 for i:=1 to n do
 begin
  readln(ch);
  k:=length(ch); dp[1<<(i-1)]:=k;
  for j:=1 to k do inc(a[i,ord(ch[j])-ord('a')+1]);
 end;
 dfs(1,0);
 for i:=1 to (1<<n)-1 do
 begin
  j:=i-1;
  while j>0 do
  begin
   dp[i]:=min(dp[i],dp[j]+dp[i xor j]-f[i]);
   j:=i and (j-1);
  end;
 end;
 writeln(dp[(1<<n)-1]+1);
 close(input);
 close(output);
end.