【BZOJ1834】network 网络扩容（最大流，费用流）

题意：给定一张有向图，每条边都有一个容量C和一个扩容费用W。这里扩容费用是指将容量扩大1所需的费用。

求： 1、 在不扩容的情况下，1到N的最大流；

2、 将1到N的最大流增加K所需的最小扩容费用。

30%的数据中，N<=100
100%的数据中，N<=1000，M<=5000，K<=10

思路：RYZ作业

第一问最大流即可

第二问网上很多题解都是在第一问的残余网络上构图，但是根本不需要

考虑边(x,y,z,w)

有容量为z，费用为0的免费流量，有容量为INF，费用为w的扩容付费流量，连这两种边

又因为求的是最大流为ans1+k时的最小费用，所以需要建立一个新的源点，从n连一条容量为ans1+k，费用为0的边来限制流量

费用流经典模型之一（模板？）

 

var head,vet,next,len1,len2,fan,x,y,z,w:array[1..200000]of longint;
    pre:array[1..200000,1..2]of longint;
    dis,gap,q:array[0..200000]of longint;
    inq:array[1..200000]of boolean;
    n,m,ans1,ans2,tot,i,src,source,s,k:longint;

procedure add(a,b,c,d:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len1[tot]:=c;
 len2[tot]:=d;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len1[tot]:=0;
 len2[tot]:=-d;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function dfs(u,aug:longint):longint;
var e,v,val,t,flow:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; flow:=0; val:=s-1;
 while e<>0 do
 begin
  v:=vet[e];
  if len1[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len1[e],aug-flow));
    len1[e]:=len1[e]-t;
    len1[fan[e]]:=len1[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;

function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

function spfa:boolean;
var t,u,e,v,i,w:longint;
begin
 for i:=1 to s do
 begin
  dis[i]:=maxlongint>>1;
  inq[i]:=false;
 end;
 t:=0; w:=1; q[1]:=source; inq[source]:=true; dis[source]:=0;
 while t<w do
 begin
  inc(t); u:=q[t mod 3000];
  inq[u]:=false;
  e:=head[u];
  while e<>0 do
  begin
   v:=vet[e];
   if (len1[e]>0)and(dis[u]+len2[e]<dis[v]) then
   begin
    pre[v,1]:=u;
    pre[v,2]:=e;
    dis[v]:=dis[u]+len2[e];
    if not inq[v] then
    begin
     inc(w); q[w mod 3000]:=v; inq[v]:=true;
    end;
   end;
   e:=next[e];
  end;
 end;
 if dis[src]=maxlongint>>1 then exit(false);
 exit(true);
end;

procedure mcf;
var k,e,t:longint;
begin
 k:=src; t:=maxlongint;
 while k<>source do
 begin
  t:=min(t,len1[pre[k,2]]);
  k:=pre[k,1];
 end;
 k:=src;
 while k<>source do
 begin
  e:=pre[k,2];
  len1[e]:=len1[e]-t;
  len1[fan[e]]:=len1[fan[e]]+t;
  ans2:=ans2+t*len2[e];
  k:=pre[k,1];
 end;
end;

begin
 assign(input,'bzoj1834.in'); reset(input);
 assign(output,'bzoj1834.out'); rewrite(output);
 readln(n,m,k);
 for i:=1 to 200000 do
  if i and 1=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for i:=1 to m do
 begin
  readln(x[i],y[i],z[i],w[i]);
  add(x[i],y[i],z[i],w[i]);
 end;

 source:=1; src:=n; s:=n;
 ans1:=maxflow;
 fillchar(head,sizeof(head),0);
 tot:=0;
 for i:=1 to m do
 begin
  add(x[i],y[i],z[i],0);
  add(x[i],y[i],maxlongint,w[i]);
 end;
 write(ans1,' ');
 inc(src); inc(s);
 add(n,src,ans1+k,0);
 while spfa do mcf;
 write(ans2);
 close(input);
 close(output);
end.