【SPOJ694&705】Distinct Substrings（后缀数组）

题意：求一个字符串的不相同的子串个数

n<=1000

思路：这是一道论文题

var a,x,y,sa,rank,height,wc,wd:array[0..3000]of longint;
    n,i,m,ans,v,cas:longint;
    ch:ansistring;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function cmp(a,b,l:longint):boolean;
begin
 exit((y[a]=y[b])and(y[a+l]=y[b+l]));
end;

procedure getsa(n:longint);
var i,j,p:longint;
begin
 for i:=0 to n-1 do
 begin
  x[i]:=a[i];
  inc(wc[a[i]]);
 end;
 for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
 for i:=n-1 downto 0 do
 begin
  dec(wc[x[i]]);
  sa[wc[x[i]]]:=i;
 end;
 j:=1; p:=1;
 while p<n do
 begin
  p:=0;
  for i:=n-j to n-1 do
  begin
   y[p]:=i; inc(p);
  end;
  for i:=0 to n-1 do
   if sa[i]>=j then begin y[p]:=sa[i]-j; inc(p); end;
  for i:=0 to n-1 do wd[i]:=x[y[i]];
  for i:=0 to m-1 do wc[i]:=0;
  for i:=0 to n-1 do inc(wc[wd[i]]);
  for i:=1 to m-1 do wc[i]:=wc[i-1]+wc[i];
  for i:=n-1 downto 0 do
  begin
   dec(wc[wd[i]]);
   sa[wc[wd[i]]]:=y[i];
  end;
  for i:=0 to n do swap(x[i],y[i]);
  p:=1; x[sa[0]]:=0;
  for i:=1 to n-1 do
   if cmp(sa[i-1],sa[i],j) then x[sa[i]]:=p-1
    else begin x[sa[i]]:=p; inc(p); end;
  j:=j*2;
  m:=p;
 end;
end;

procedure getheight(n:longint);
var i,j,k:longint;
begin
 k:=0;
 for i:=1 to n do rank[sa[i]]:=i;
 for i:=0 to n-1 do
 begin
  if k>0 then dec(k);
  j:=sa[rank[i]-1];
  while a[i+k]=a[j+k] do inc(k);
  height[rank[i]]:=k;
 end;
end;

begin
 assign(input,'spoj694.in'); reset(input);
 assign(output,'spoj694.out'); rewrite(output);
 readln(cas);
 for v:=1 to cas do
 begin
  fillchar(a,sizeof(a),0);
  fillchar(x,sizeof(x),0);
  fillchar(y,sizeof(y),0);
  fillchar(sa,sizeof(sa),0);
  fillchar(rank,sizeof(rank),0);
  fillchar(wc,sizeof(wc),0);
  fillchar(wd,sizeof(wd),0);
  fillchar(height,sizeof(height),0);
  readln(ch); n:=length(ch);
  for i:=0 to n-1 do a[i]:=ord(ch[i+1]);
  a[n]:=0; m:=300;
  getsa(n+1);
  getheight(n);
  ans:=0;
  for i:=1 to n do ans:=ans+n-sa[i]-height[i];
  writeln(ans);
 end;

 close(input);
 close(output);
end.