【POJ2828】Buy Tickets（线段树）

题意：有一个输入序列，每次操作要把b[i]插入到第a[i]个，在第a[i]个后面的要后移，问最后序列。

n<=200000 

思路：顺序来只能用splay维护

考虑倒序，对于插入到第K个位置，在线段树二分第K个0的位置，类似于主席树

将其插入后将这个位置修改为已经有数

单点修改

var t:array[1..1000000]of longint;
    a,b,c:array[1..300000]of longint;
    n,i,k:longint;

procedure pushup(p:longint);
begin
 t[p]:=t[p<<1]+t[p<<1+1];
end;

function query(l,r,k,p:longint):longint;
var mid:longint;
begin
 if l=r then exit(l);
 mid:=(l+r)>>1;
 if t[p<<1]>=k then exit(query(l,mid,k,p<<1))
  else exit(query(mid+1,r,k-t[p<<1],p<<1+1));
 pushup(p);
end;

procedure update(l,r,k,p:longint);
var mid:longint;
begin
 if (l=k)and(r=k) then
 begin
  dec(t[p]); exit;
 end;
 mid:=(l+r)>>1;
 if k<=mid then update(l,mid,k,p<<1)
  else update(mid+1,r,k,p<<1+1);
 pushup(p);
end;

procedure build(l,r,p:longint);
var mid:longint;
begin
 if l=r then
 begin
  t[p]:=1; exit;
 end;
 mid:=(l+r)>>1;
 build(l,mid,p<<1);
 build(mid+1,r,p<<1+1);
 pushup(p);
end;

begin
 assign(input,'poj2828.in'); reset(input);
 assign(output,'poj2828.out'); rewrite(output);
 while not eof do
 begin
  readln(n);
  if n=0 then break;
  for i:=1 to n<<2 do t[i]:=0;
  fillchar(c,sizeof(c),0);
  for i:=1 to n do
  begin
   read(a[i],b[i]);
   inc(a[i]);
  end;
  build(1,n,1);
  for i:=n downto 1 do
  begin
   k:=query(1,n,a[i],1);
   c[k]:=b[i];
   update(1,n,k,1);
  end;
  for i:=1 to n-1 do write(c[i],' ');
  write(c[n]);
  writeln;
 end;

 close(input);
 close(output);
end.