【Tyvj2133&BZOJ1146】网络管理Network（树套树，DFS序，树状数组，主席树，树上差分）

题意：有一棵N个点的树，每个点有一个点权a[i]，要求在线实现以下操作：

1：将X号点的点权修改为Y

2：查询X到Y的路径上第K大的点权

n,q<=80000 a[i]<=10^8

思路：此题明显地体现了我对主席树理解不深

树上路径K大可以直接用树剖+二分答案+树做

但DFS序+主席树也可以

对于点U，它能影响DFS序上的区间(st[u],ed[u])

所以维护方法就是类似序列K大一样 s[st[u]]++ s[ed[u]+1]--

对于路径(x,y)，信息为s[x]+s[y]-s[lca(x,y)]-s[fa[lca(x,y)]]

但因为是在树上的操作，所以每个点是从它在树上的父亲继承下来的，并不是DFS序上的前一个继承的

所以在DFS时就可以建立一棵没有修改过的原树

对于询问，再建立一棵树只做更改，询问时加上原树的信息即可

不开两棵树可以，不过需要主席树合并

var t:array[0..8000000]of record
                           l,r,s:longint;
                          end;
    f:array[0..210000,0..18]of longint;
    head,vet,next,st,ed,dep,flag,hash,root1,root2,b:array[0..210000]of longint;
    d:array[0..210000,1..3]of longint;
    a:array[0..210000]of longint;
    q1,q2:array[0..80000]of longint;
    n,m,i,j,tot,time,up,la,lb,cnt,q,x,y,tmp,p,sum,z,f1,f2,f3,f4:longint;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function find(x:longint):longint;
var l,r,mid:longint;
begin
 l:=1; r:=up;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if hash[mid]=x then exit(mid);
  if hash[mid]<x then l:=mid+1
   else r:=mid-1;
 end;
end;

procedure update(l,r:longint;var p:longint;v,x:longint);
var mid:longint;
begin
 inc(cnt); t[cnt]:=t[p];
 p:=cnt; t[p].s:=t[p].s+x;
 if l=r then exit;
 mid:=(l+r)>>1;
 if v<=mid then update(l,mid,t[p].l,v,x)
  else update(mid+1,r,t[p].r,v,x);
end;

procedure dfs(u:longint);
var e,v,i,tmp:longint;
begin
 for i:=1 to 18 do
 begin
  if dep[u]<(1<<i) then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;
 tmp:=find(a[u]);
 root1[u]:=root1[f[u,0]];
 update(1,up,root1[u],tmp,1);
 inc(time); st[u]:=time; ed[u]:=time;
 flag[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   f[v,0]:=u;
   dep[v]:=dep[u]+1;
   dfs(v);
   ed[u]:=max(ed[u],ed[v]);
  end;
  e:=next[e];
 end;
end;

function lca(x,y:longint):longint;
var d,i:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 18 do
  if d and (1<<i)>0 then x:=f[x,i];
 for i:=18 downto 0 do
  if f[x,i]<>f[y,i] then
  begin
   x:=f[x,i]; y:=f[y,i];
  end;
 if x=y then exit(x);
 exit(f[x,0]);
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=b[(l+r)>>1];
 repeat
  while mid>b[i] do inc(i);
  while mid<b[j] do dec(j);
  if i<=j then
  begin
   swap(b[i],b[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function lowbit(x:longint):longint;
begin
 exit(x and (-x));
end;

function query(l,r,k:longint):longint;
var s1,s2,i,mid:longint;
begin
 if l=r then exit(l);
 mid:=(l+r)>>1;
 s1:=0; s2:=0;
 for i:=1 to la do s1:=s1+t[t[q1[i]].l].s;
 for i:=1 to lb do s2:=s2+t[t[q2[i]].l].s;
 s2:=s2+t[t[f1].l].s+t[t[f2].l].s;
 s1:=s1+t[t[f3].l].s+t[t[f4].l].s;
 if s2-s1>=k then
 begin
  f1:=t[f1].l; f2:=t[f2].l;
  f3:=t[f3].l; f4:=t[f4].l;
  for i:=1 to la do q1[i]:=t[q1[i]].l;
  for i:=1 to lb do q2[i]:=t[q2[i]].l;
  exit(query(l,mid,k));
 end
  else
  begin
   f1:=t[f1].r; f2:=t[f2].r;
   f3:=t[f3].r; f4:=t[f4].r;
   for i:=1 to la do q1[i]:=t[q1[i]].r;
   for i:=1 to lb do q2[i]:=t[q2[i]].r;
   exit(query(mid+1,r,k-(s2-s1)));
  end;
end;

begin
 assign(input,'data.in'); reset(input);
 assign(output,'tyvj2133.out'); rewrite(output);
 read(n,m);
 for i:=1 to n do
 begin
  read(a[i]); b[i]:=a[i];
 end;
 q:=n;
 for i:=1 to n-1 do
 begin
  read(x,y);
  add(x,y);
  add(y,x);
 end;

 for i:=1 to m do
  for j:=1 to 3 do read(d[i,j]);
 for i:=1 to m do
  if d[i,1]=0 then
  begin
   inc(q); b[q]:=d[i,3];
  end;
 qsort(1,q);
 hash[1]:=b[1]; up:=1;
 for i:=2 to q do
  if b[i]<>b[i-1] then begin inc(up); hash[up]:=b[i]; end;
 dfs(1);


 for i:=1 to m do
  if d[i,1]=0 then
  begin
   tmp:=find(a[d[i,2]]);
   j:=st[d[i,2]];
   while j<=n do
   begin
    update(1,up,root2[j],tmp,-1);
    j:=j+lowbit(j);
   end;
   j:=ed[d[i,2]]+1;
   while j<=n do
   begin
    update(1,up,root2[j],tmp,1);
    j:=j+lowbit(j);
   end;
   tmp:=find(d[i,3]);
   j:=st[d[i,2]];
   while j<=n do
   begin
    update(1,up,root2[j],tmp,1);
    j:=j+lowbit(j);
   end;
   j:=ed[d[i,2]]+1;
   while j<=n do
   begin
    update(1,up,root2[j],tmp,-1);
    j:=j+lowbit(j);
   end;

   a[d[i,2]]:=d[i,3];
  end
   else
   begin
    la:=0; lb:=0; p:=lca(d[i,2],d[i,3]);
    j:=st[d[i,2]];
    while j>0 do
    begin
     inc(lb); q2[lb]:=root2[j];
     j:=j-lowbit(j);
    end;

    j:=st[d[i,3]];
    while j>0 do
    begin
     inc(lb); q2[lb]:=root2[j];
     j:=j-lowbit(j);
    end;

    j:=st[p];
    while j>0 do
    begin
     inc(la); q1[la]:=root2[j];
     j:=j-lowbit(j);
    end;

    j:=st[f[p,0]];
    while j>0 do
    begin
     inc(la); q1[la]:=root2[j];
     j:=j-lowbit(j);
    end;

    f1:=root1[d[i,2]]; f2:=root1[d[i,3]];
    f3:=root1[p]; f4:=root1[f[p,0]];
    sum:=dep[d[i,2]]+dep[d[i,3]]-dep[p]*2+1;
    z:=sum-d[i,1]+1;
    if sum<d[i,1] then writeln('invalid request!')
     else writeln(hash[query(1,up,z)]);
   end;


 close(input);
 close(output);
end.