【vijos1144】小胖守皇宫（树形DP）

描述

huyichen世子事件后，xuzhenyi成了皇上特聘的御前一品侍卫。

皇宫以午门为起点，直到后宫嫔妃们的寝宫，呈一棵树的形状；某些宫殿间可以互相望见。大内保卫森严，三步一岗，五步一哨，每个宫殿都要有人全天候看守，在不同的宫殿安排看守所需的费用不同。

可是xuzhenyi手上的经费不足，无论如何也没法在每个宫殿都安置留守侍卫。

帮助xuzhenyi布置侍卫，在看守全部宫殿的前提下，使得花费的经费最少。

格式

输入格式

输入文件中数据表示一棵树，描述如下：

第1行 n，表示树中结点的数目。

第2行至第n+1n+1行，每行描述每个宫殿结点信息，依次为：该宫殿结点标号i（0<i≤n0<i≤n），在该宫殿安置侍卫所需的经费k，该点的儿子数m，接下来m个数，分别是这个节点的m个儿子的标号r1,r2,⋯,rmr1,r2,⋯,rm。

对于一个n（0<n≤15000<n≤1500）个结点的树，结点标号在1到n之间，且标号不重复。保证经费总和不超过2^31-1

输出格式

输出文件仅包含一个数，为所求的最少的经费。

 

思路：dp[i,0..2]分别表示在i的某个儿子，i本身，i的父亲安置侍卫覆盖i的整个子树的最小花费

        dp[u,0]=dp[v,1]+sigma(min(dp[v',0],dp[v',1]))   v<>v'

        dp[u,1]=a[u]+sigma(min(dp[v,0],dp[v,1],dp[v,2]))

        dp[u,2]=sigma(min(dp[v,0],dp[v,1]))

var dp:array[1..10000,0..2]of longint;
    head,vet,next,a:array[1..10000]of longint;
    n,m,i,j,x,y,tot:longint;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure dfs(u,pre:longint);
var e,v,i,s,d:longint;
begin
 e:=head[u]; dp[u,0]:=maxlongint; dp[u,1]:=a[u]; dp[u,2]:=0;
 d:=0; s:=0;
 while e<>0 do
 begin
  v:=vet[e];
  if v<>pre then
  begin
   inc(d);
   dfs(v,u);
   s:=s+min(dp[v,0],dp[v,1]);
   dp[u,1]:=dp[u,1]+min(min(dp[v,0],dp[v,1]),dp[v,2]);
   dp[u,2]:=dp[u,2]+min(dp[v,0],dp[v,1]);
  end;
  e:=next[e];
 end;
 if d=0 then begin dp[u,0]:=maxlongint; dp[u,1]:=a[u]; dp[u,2]:=0; exit; end;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>pre then dp[u,0]:=min(dp[u,0],s-min(dp[v,0],dp[v,1])+dp[v,1]);
  e:=next[e];
 end;
end;

begin
 //assign(input,'vijos1144.in'); reset(input);
// assign(output,'vijos1144.out'); rewrite(output);
 readln(n);
 for i:=1 to n do
 begin
  read(x); read(a[x]);
  read(m);
  for j:=1 to m do
  begin
   read(y); add(x,y); add(y,x);
  end;
 end;
 fillchar(dp,sizeof(dp),$1f);
 dfs(1,-1);
 writeln(min(dp[1,0],dp[1,1]));

 //close(input);
 //close(output);
end.