常用表达式解析

假设属性abc的值为xyz。

${abc} => xyz
$${abc} => ${abc}
$$${abc} => $xyz
$$$${abc} => $${abc}
$$$$${abc} => $$xyz

也就是从左往右两个$并一个$且以字符串输出,如果$和{}匹配才解析。

假设  属性"filename" 值为 "a brand new filename.txt"

${filename:replaceAll('\..*', '')} => a brand new filename
${filename:replaceAll('a brand (new)', '$1')} => new filename.txt
${filename:replaceAll('XYZ', 'ZZZ')} => a brand new filename.txt
${filename:replaceAll('brand (new)', 'somewhat $1')} => a somewhat new filename.txt

${filename:replace('.', '_')} => a brand new filename_txt
${filename:replace(' ', '.')} => a.brand.new.filename.txt
${filename:replace('XYZ', 'ZZZ')} => a brand new filename.txt
${filename:replace('filename', 'book')} => a brand new book.txt

假设 属性"str" 值为 "abc" 随机组

${str:repeat(1)} => abc
${str:repeat(2)} => abcabc
${str:repeat(1,2)} => abc 或者 abcabc
${str:repeat( ${str:length()} )} => abc 或者 abcabc 或者 abcabcabc

类型转换

${fileSize:toNumber()}
${fileSize:toNumber():toString()} 
${fileSize:toDecimal()}  小数

假设 属性"myJson" 值如下：

{
  "firstName": "John",
  "lastName": "Smith",
  "isAlive": true,
  "age": 25,
  "address": {
    "streetAddress": "21 2nd Street",
    "city": "New York",
    "state": "NY",
    "postalCode": "10021-3100"
  },
  "phoneNumbers": [
    {
      "type": "home",
      "number": "212 555-1234"
    },
    {
      "type": "office",
      "number": "646 555-4567"
    }
  ],
  "children": [],
  "spouse": null
}

取值

${myJson:jsonPath('$.firstName')} => John
${myJson:jsonPath('$.address.postalCode')} => 10021-3100
${myJson:jsonPath('$.phoneNumbers[?(@.type=="home")].number')} => 212 555-1234
${myJson:jsonPath('$.phoneNumbers')} => [{"type":"home","number":"212 555-1234"},{"type":"office","number":"646 555-4567"}]
${myJson:jsonPath('$.missing-path')} => empty
${myJson:jsonPath('$.bad-json-path..')} => exception bulletin

删除值

${myJson:jsonPathDelete('$.firstName')} => {"lastName":"Smith","age":25,"address":{"streetAddress":"21 2nd Street","city":"New York","state":"NY","postalCode":"10021-3100"},"phoneNumbers":[{"type":"home","number":"212 555-1234"},{"type":"office","number":"646 555-4567"}]}
${myJson:jsonPathDelete('$.missing-path')} => Returns original JSON document

添加[]值

${myJson:jsonPathAdd('$.nicknames', 'Jimmy')} =>{"firstName":"James", lastName":"Smith", "age":25, "voter":true, "height":6.1, "address":{"streetAddress":"21 2nd Street", "city":"New York", "state":"NY", "postalCode":"10021-3100"}, "phoneNumbers":[{"type":"home", "number":"212 555-1234"}, {"type":"office", "number":"646 555-4567"}],"nicknames":["Jimmy"]}
${myJson:jsonPathAdd('$.missingpath', 'Jimmy')} => Returns original JSON document with no modifications
${myJson:jsonPathAdd('$.firstName', 'Jimmy')} => empty

添加对象值

${myJson:jsonPathPut('$','middlename','Turon')} => {"firstName":"James", lastName":"Smith", "middlename": "Turon", "age":25, "voter":true, "height":6.1, "address":{"streetAddress":"21 2nd Street", "city":"New York", "state":"NY", "postalCode":"10021-3100"}, "phoneNumbers":[{"type":"home", "number":"212 555-1234"}, {"type":"office", "number":"646 555-4567"}]}

改变

${myJson:jsonPathSet('$.firstName', 'James')} =>{"firstName":"James", lastName":"Smith", "age":25, "voter":true, "height":6.1, "address":{"streetAddress":"21 2nd Street", "city":"New York", "state":"NY", "postalCode":"10021-3100"}, "phoneNumbers":[{"type":"home", "number":"212 555-1234"}, {"type":"office", "number":"646 555-4567"}]}
${myJson:jsonPathSet('$.missingpath', 'James')} => Returns original JSON document

判断ifElse

假设 属性"filename" 值"a brand new filename.txt";属性"nullFilename" 值null;属性"bool" 值"true"

${bool:ifElse('a','b')} => a
${literal(true):ifElse('a','b')} => a
${nullFilename:isNull():ifElse('file does not exist', 'located file')} => file does not exist
${nullFilename:ifElse('found', 'not_found')} => not_found
${filename:ifElse('found', 'not_found')} => not_found
${filename:isNull():not():ifElse('found', 'not_found')} => found

截取属性字符串

设 属性"filename" 值"a brand new filename.txt";

#substring
${filename:substring(0,1)} => a
${filename:substring(2)} => brand new filename.txt
${filename:substring(12)} => filename.txt
${filename:substring( ${filename:length():minus(2)} )} => xt
#substringBefore 第一个匹配开始
${filename:substringBefore('.')} => a brand new filename
{filename:substringBefore(' ')} => a
${filename:substringBefore(' n')} => a brand
${filename:substringBefore('missing')} => a brand new filename.txt
#substringBeforeLast 最后一个匹配开始
${filename:substringBeforeLast('.')} => a brand new filename
${filename:substringBeforeLast(' ')} => a brand new
${filename:substringBeforeLast(' n')} => a brand
${filename:substringBeforeLast('missing')} => a brand new filename.txt
#substringAfter 截取后面
${filename:substringAfter('.')} => txt
${filename:substringAfter(' ')} => brand new filename.txt
{filename:substringAfter(' n')} => ew filename.txt
${filename:substringAfter('missing')} => a brand new filename.txt
#substringAfterLast
${filename:substringAfterLast('.')} => txt
${filename:substringAfterLast(' ')} => filename.txt
${filename:substringAfterLast(' n')} => ew filename.txt
${filename:substringAfterLast('missing')} => a brand new filename.txt

${filename:append('.gz')} => "a brand new filename.txt.gz"
${filename:prepend('1')}  => "1a brand new filename.txt"

 

获取值

 ${UUID()}

${ip()}

${hostname()}

isNull

${filename:isNull()} 返回 false 或 true。这种格式也可以写成${'filename':isNull()}

${filename:notNull()} 同上用法，判断相反。

更多详见文档