批处理实现--以网页形式浏览当前文件夹中的图片

可当作浏览图片常驻用。

::以网页形式（套图形式）浏览当前文件夹中的图片
@echo off&SetLocal EnableDelayedExpansion
For /f "delims=" %%i in ('dir /s /b') do (Set a=%%~pi
Set a=!a:\= !)
For %%i in (%a%) do Set b=%%i
::获取文件夹名
Set n=0
(
  Echo ^<Html^>
  Echo ^<Title^>
  Echo %b%
  Echo ^</Title^>
  Echo ^<Body^>
  For /r %%i in (*.jpg *.bmp *.gif *.png) do (Echo ^<Img Src="%%i"^>^<p^>
  Set n=1)
  ::将当前文件夹中所有的图片地址写入到html文件中。
  Echo ^</Body^>
  Echo ^</Html^>
)>"%b%.html"
If %n%==0 Msg * "当前文件夹中没有图片" & del "%b%.html"
If %n%==1 Start "" "%b%.html"

自己有用，纯粹练手，欢迎试用，有虫告诉我。

 

出处：https://www.bathome.net/thread-13448-1-1.html

=======================================================================================

个人使用

优化：使用临时文件；统计图片总数

::以网页形式（套图形式）浏览当前文件夹中的图片
@echo off&SetLocal EnableDelayedExpansion
::获取当前文件夹名,和html的文件名
For %%i in (%cd%) do Set "b=%%~nxi"&Set b=!b!_Imgs

Set n=0
::把图片写入临时文件
For /r %%i in (*.jpg *.bmp *.gif *.png) do (Echo ^<p^>^<Img Src="%%i"^>^<br ^>%%i^</p^>>>"%temp%\%b%.html"&Set/a n+=1)
(
    Echo ^<Html^>
    Echo ^<Title^>
    Echo %b% Total：!n!
    Echo ^</Title^>
    Echo ^<Body^>    
    Echo ^<h2^>Total：!n!^</h2^>
    ::将当前文件夹中所有的图片地址写入到html文件中。
    if exist "%temp%\%b%.html" type "%temp%\%b%.html"
    Echo ^</Body^>
    Echo ^</Html^>
)>"%b%.html"
if exist "%temp%\%b%.html" del "%temp%\%b%.html"
If %n%==0 Msg * "当前文件夹中没有图片"&echo.&echo 当前文件夹中没有图片&del "%b%.html"
If not %n%==0 Start "" "%b%.html"