QTP自传之描述性编程

描述性编程，即采用描述性的语言定位对象，不需要事先将对象添加到对象库中。下面，就说说如何使用描述性编程，我们将继续使用对象库编程中的网页。

使用描述性编程的两种方法

• 直接描述

对象("属性名:=属性值","属性名:=属性值"...)

这种方式很形象很好记，比方说要去找个人，就叫张三吧，用上面的公式就是这样。

人("名字:=张三")

如果有多个叫张三的人，可以更具体的描述出特征。

人("名字:=张三","性别:=男","身高:=175CM"...)

通过说出张三的这些特种，最终我们会找到他，下面是我们在对象库编程使用的代码。

Browser("web对象演示").Page("web对象演示").WebEdit("用户名").Set "test"
Browser("web对象演示").Page("web对象演示").WebEdit("邮箱").Set "11111@qq.com"
Browser("web对象演示").Page("web对象演示").WebEdit("个人介绍").Set "haha"

 

用描述性编程可以达到同样的效果，试试看，用户名是不是输入了test呢？

'描述性编程
Browser("micClass:=Browser").Page("micClass:=Page").WebEdit("name:=username").Set "test"
Browser("micClass:=Browser").Page("micClass:=Page").WebEdit("name:=mail").Set "11111@qq.com"
Browser("micClass:=Browser").Page("micClass:=Page").WebEdit("class:=edit","html tag:=TEXTAREA").Set "haha"

 

注意，对个人介绍富文本使用了两个属性描述，通过网页源码(不想或看不到源码可以通过Spy工具查看对象属性)我们可以看到它没有name属性，而用户名和邮箱的class属性都为edit，要想定位，必须再添加唯一性的属性，这里选择html tag。

//截取的网页源码
<div class="content">
   <span>用户名</span><input type="text" name="username" class="edit">
</div>
<div class="content">
    <span>邮箱</span><input type="mail" name="mail"  class="edit">
</div>
<div class="content">
    <span>个人介绍</span><textarea rows="5" cols="20" class="edit"></textarea>
</div>

 

大家有没有注意，描述性编程有的时候不能直接从代码上看出所描述对象的具体用途，比如上面代码WebEdit("class:=edit","html tag:=TEXTAREA")，通过class和html tag属性描述，但是我们不知道它描述的什么对象，而对象库编程的代码WebEdit("个人介绍")，清楚的指出这是设置个人介绍输入框的值，这也算是描述性编程不足的地方吧。

• Description对象方法

直接上代码

'描述性编程description方式
'生成description对象
Set obj_browser=description.Create()
Set obj_page=description.Create()
Set obj_webedit_username=description.Create()
Set obj_webedit_mail=description.Create()
Set obj_webedit_textarea=description.Create()
'设置属性值
obj_browser("micClass").value="Browser"
obj_page("micClass").value="Page"
obj_webedit_username("name").value="username"
obj_webedit_mail("name").value="mail"
obj_webedit_textarea("html tag").value="TEXTAREA"

Browser(obj_browser).Page(obj_page).WebEdit(obj_webedit_username).Set "test"
Browser(obj_browser).Page(obj_page).WebEdit(obj_webedit_mail).Set "11111@qq.com"
Browser(obj_browser).Page(obj_page).WebEdit(obj_webedit_textarea).Set  "haha"

'释放对象
Set obj_browser=nothing
Set obj_page=nothing
Set obj_webedit_username=nothing
Set obj_webedit_mail=nothing
Set obj_webedit_textarea=nothing

 

 

这样写看上去挺好，但当有很多相同对象的时候就会很麻烦，有100个WebEdit难道要设置100个description对象？我们可以改进代码如下

'描述性编程description方式
'生成description对象
Set obj_browser=description.Create()
Set obj_page=description.Create()
Set obj_webedit=description.Create()

'设置属性值
obj_browser("micClass").value="Browser"
obj_page("micClass").value="Page"
obj_webedit("micClass").value="WebEdit"

Set obj_webedits=Browser(obj_browser).Page(obj_page).ChildObjects(obj_webedit)

obj_webedits.item(0).set "test"
obj_webedits.item(1).set "11111@qq.com"
obj_webedits.item(2).set "haha"

'释放对象
Set obj_browser=nothing
Set obj_page=nothing
Set obj_webedit=nothing
Set obj_webedits=nothing

 

 

两种方式都已经介绍完了，第一种方式适用于一般的测试环境，第二种方式适用于基于框架的测试因其代码的复用性较高，具体的区别大家可以自己体会。下面用两种描述性编程方式重写对象库编程的代码。

'描述性编程description方式
'生成description对象
Set obj_browser=description.Create()
Set obj_page=description.Create()
Set obj_webedit=description.Create()
Set obj_weblist=description.Create()
Set obj_webcheckbox=description.Create()
Set obj_webradiogroup=description.Create()
Set obj_webbutton=description.Create()
Set obj_webtabe=description.Create()

'设置属性值
obj_browser("micClass").value="Browser"
obj_page("micClass").value="Page"
obj_webedit("micClass").value="WebEdit"
obj_weblist("micClass").value="WebList"
obj_webcheckbox("micClass").value="WebCheckBox"
obj_webradiogroup("micClass").value="WebRadioGroup"
obj_webbutton("micClass").value="WebButton"
obj_webtabe("micClass").value="WebTable"

'获取所有WebEdit对象
Set obj_webedits=Browser(obj_browser).Page(obj_page).ChildObjects(obj_webedit)
obj_webedits.item(0).set "test"
obj_webedits.item(1).set "11111@qq.com"
obj_webedits.item(2).set "haha"

Browser(obj_browser).Page(obj_page).WebList(obj_weblist).Select "java"

'获取所有WebCheckBox对象
Set obj_webcheckboxs=Browser(obj_browser).Page(obj_page).ChildObjects(obj_webcheckbox)
For i=0 to 1
    obj_webcheckboxs.item(i).set "ON"
Next

Browser(obj_browser).Page(obj_page).WebRadioGroup(obj_webradiogroup).Select "男"
Browser(obj_browser).Page(obj_page).WebButton(obj_webbutton).Click

'获取WebTable单元格内的值
username=Browser(obj_browser).Page(obj_page).WebTable(obj_webtabe).GetCellData(2,1)
mail=Browser(obj_browser).Page(obj_page).WebTable(obj_webtabe).GetCellData(2,2)
sex=Browser(obj_browser).Page(obj_page).WebTable(obj_webtabe).GetCellData(2,3)

If username="test" and mail="11111@qq.com" and sex="男" Then
    msgbox "OK"
End If
'释放对象
Set obj_browser=nothing
Set obj_page=nothing
Set obj_webedit=nothing
Set obj_webedits=nothing
Set obj_weblist=nothing
Set obj_webcheckbox=nothing
Set obj_webradiogroup=nothing
Set obj_webbutton=nothing
Set obj_webcheckboxs=nothing
Set obj_webtabe=nothing
'描述性编程直接描述方式

With Browser("micClass:=Browser").Page("micClass:=Page")
    .WebEdit("name:=username").Set "test"
    .WebEdit("name:=mail").Set "11111@qq.com"
    .WebEdit("class:=edit","html tag:=TEXTAREA").Set "haha"
    .WebList("micClass:=WebList").Select "java"
    .WebCheckBox("html id:=film").Set "ON"
    .WebCheckBox("html id:=game").Set "ON"
    .WebRadioGroup("micClass:=WebRadioGroup").Select "男"
    .WebButton("name:=提交").Click

    username=.WebTable("micClass:=WebTable").GetCellData(2,1)
    mail=.WebTable("micClass:=WebTable").GetCellData(2,2)
    sex=.WebTable("micClass:=WebTable").GetCellData(2,3)
End With

If username="test" and mail="11111@qq.com" and sex="男" Then
    msgbox "OK"
End If

 

如何取舍

• 对象库编程

1.当对象的属性有更改时(例如对象name更改)，而脚本中大量引用此对象(10次，100次)，只需要更改对象库中对象的属性即可，描述性编程则需要手动更改所有涉及的代码，效率很低。

2.可以通过对象拖拽，F7等方式快速编写代码，自动生成，不容易打错。

• 描述性编程

1.不需要维护庞大的对象库。

2.在完成对象库编程不能完成的功能(对象不能识别的时候)

描述性编程和对象库编程各有优缺点，不能说谁好谁劣，只有在适当的时候采用适当的方法才是正理。

最好的方法就是，对象可以识别的时候就用对象库编程，不能识别的时候就用描述性编程。