window命令行

del删除:

删除一个或多个文件。

DEL [/P] [/F] [/S] [/Q] [/A[[:]attributes]] names
ERASE [/P] [/F] [/S] [/Q] [/A[[:]attributes]] names

  names         指定一个或多个文件或者目录列表。
                通配符可用来删除多个文件。
                如果指定了一个目录,该目录中的所
                有文件都会被删除。

  /P            删除每一个文件之前提示确认。
  /F            强制删除只读文件。
  /S            删除所有子目录中的指定的文件。
  /Q            安静模式。删除全局通配符时,不要求确认
  /A            根据属性选择要删除的文件
  属性          R  只读文件            S  系统文件
                H  隐藏文件            A  准备存档的文件
                I  无内容索引文件      L  重新分析点
                O  脱机文件            -  表示“否”的前缀

1、无需确认删除D盘test文件夹下面的所有.txt类型文件

del /q /s D:\test\*.txt

2、需确认的删除D盘test文件夹下面的所有广告.png文件

del /p /s D:\test\广告.png

3、只删除test目录下data文件夹中.txt类型的文件

del D:\test\data\*.txt

dir获取文件列表:

显示目录中的文件和子目录列表。

DIR [drive:][path][filename] [/A[[:]attributes]] [/B] [/C] [/D] [/L] [/N]
  [/O[[:]sortorder]] [/P] [/Q] [/R] [/S] [/T[[:]timefield]] [/W] [/X] [/4]

  [drive:][path][filename]
              指定要列出的驱动器、目录和/或文件。

  /A          显示具有指定属性的文件。
  属性         D  目录                R  只读文件
               H  隐藏文件            A  准备存档的文件
               S  系统文件            I  无内容索引文件
               L  重新分析点          O  脱机文件
               -  表示“否”的前缀
  /B          使用空格式(没有标题信息或摘要)。
  /C          在文件大小中显示千位数分隔符。这是默认值。用 /-C 来
              禁用分隔符显示。
  /D          跟宽式相同,但文件是按栏分类列出的。
  /L          用小写。
  /N          新的长列表格式,其中文件名在最右边。
  /O          用分类顺序列出文件。
  排列顺序     N  按名称(字母顺序)     S  按大小(从小到大)
               E  按扩展名(字母顺序)   D  按日期/时间(从先到后)
               G  组目录优先           -  反转顺序的前缀
  /P          在每个信息屏幕后暂停。
  /Q          显示文件所有者。
  /R          显示文件的备用数据流。
  /S          显示指定目录和所有子目录中的文件。

1、获取H盘下的test文件夹目录,并生成到H盘下面的原文件列表.txt文件

dir H:\test /b > H:\原文件列表.txt

ren文件重命名:

重命名文件。

RENAME [drive:][path]filename1 filename2.
REN [drive:][path]filename1 filename2.

1、把H盘下面的test.txt文件重命名为data.txt

ren H:\test.txt data.txt

 echo显示消息:

显示消息,或者启用或关闭命令回显。

  ECHO [ON | OFF]
  ECHO [message]

1、在cmd里打印文本

echo 这是console.log

bat文件:

1、点击打开项目

在项目根目录新建一个index.bat文件,并把项目开启的命令输入

node index.js

打开文件目录点击bat文件就可以打开项目了,还可以在桌面新建快捷键,路径导向这个文件,直接在桌面打开

2、批量给当前文件夹下.txt类型文件添加前缀后缀

获取文件名称

举例:test.txt文件
获取文件名:%%a (即:test.txt)
获取文件名(不含后缀):%%~na (即:test)
获取文件名后缀:%%~xa (即:.txt)

添加前缀:新建一个txt文件,输入以下代码,点击另存为bat文件,保存类型为所有文件,并修改编码UTF-8为ANSI,不改中文会乱码

@echo off
for /f "delims=" %%a in ('dir /a /b *.txt') do (
ren %%a "前缀%%~na%%~xa"
echo "已将原文件名:%%a 重命名为:前缀%%~na%%~xa"
)
echo 重命名完成!
pause

添加后缀:新建一个txt文件,输入以下代码,点击另存为bat文件,保存类型为所有文件,并修改编码UTF-8为ANSI,不改中文会乱码

@echo off
for /f "delims=" %%a in ('dir /a /b *.txt') do (
ren %%a "%%~na后缀%%~xa"
echo "已将原文件名:%%a 重命名为:%%~na后缀%%~xa"
)
echo 重命名完成!
pause

3、批量把当前目录下.txt文件去掉前缀后缀(也可以替换掉部分字符)

去掉前缀:新建一个txt文件,输入以下代码,点击另存为bat文件,保存类型为所有文件,并修改编码UTF-8为ANSI,不改中文会乱码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a /b *.txt') do (
set str=%%a
set "str=!str:前缀=!"
ren %%a !str!
echo "已将原文件名:%%a 重命名为:!str!"
)
echo 重命名完成!
pause

去掉后缀:新建一个txt文件,输入以下代码,点击另存为bat文件,保存类型为所有文件,并修改编码UTF-8为ANSI,不改中文会乱码

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a /b *.txt') do (
set str=%%a
set "str=!str:后缀=!"
ren %%a !str!
echo "已将原文件名:%%a 重命名为:!str!"
)
echo 重命名完成!
pause

4、把当前目录下文件夹重命名为文件1、文件2...以此类推

@echo off
setlocal enabledelayedexpansion
set num=1
for /f "delims=" %%b in ('dir /a:d /b') do (
ren "%%b"  "文件!num!"
set /a num+=1
)
echo bat调用结束
pause

5、批量重命名当前目录文件及子级目录文件

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a:d /b /s') do (
set type=%%~xa
if not "!type!"==".bat" (
echo "第一级目录%%a"
set str=%%a
set "str=!str: =!"
set "str=!str:'=!"
set "str=!str:%%=!"
ren "%%a" "!str!"
echo "已将原文件名:%%a 重命名为:!str!"
for /f "delims=" %%b in ('dir %%a /a /b') do (
echo "第二级目录%%b"
set str=%%b
set "str=!str: =!"
set "str=!str:'=!"
set "str=!str:%%=!"
echo "%%a\%%b"
echo "!str!"
ren "%%a\%%b" "!str!"
echo "已将原文件名:%%a\%%b 重命名为:!str!"
)
)
)
echo 重命名完成!
pause

 6、批量重命名当前文件夹下图片,按1.png、2,jpg.....命名

@echo off
setlocal enabledelayedexpansion
set num=1
for /f "delims=" %%a in ('dir /a /b') do (
set type=%%~xa
if not "!type!"==".bat" (
ren "%%a"  "!num!%%~xa"
echo "已将原文件名:%%a 重命名为:!num!%%~xa"
set /a num+=1
)
)
echo bat调用结束
pause

 

posted @ 2023-02-15 10:56  Pavetr  阅读(33)  评论(0编辑  收藏  举报