龙哥量化：通达信六脉神剑大揭秘，公式叠加真的有用吗，因子叠加效果分析

龙哥微信：Long622889  
代写技术指标_选股公式： 通达信，同花顺，东方财富，大智慧，文华，博易，KT交易师
代写期货量化策略：TB交易开拓者，文华8，金字塔量化

 

量化越来越普及， AI写量化策略， 写选股指标越来越厉害，可是，你懂公式原理的细节吗？

这篇以六脉神剑为案例分析

以下是通达信副图公式源码， 公式名称：六脉神剑

DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
STICKLINE(DIFF>DEA,0.3,1,3,0),COLORRED;
STICKLINE(DIFF<DEA,0.3,1,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.9, 0, ' MACD'),COLORMAGENTA;

XX:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(XX,3,1);
D:=SMA(K,3,1);
STICKLINE(K>D,1.3,2,3,0),COLORRED;
STICKLINE(K<D,1.3,2,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.73, 0, ' KDJ'),COLORMAGENTA;

GSKZZB:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-GSKZZB,0),5,1))/(SMA(ABS(CLOSE-GSKZZB),5,1))*100;
RSI2:=(SMA(MAX(CLOSE-GSKZZB,0),13,1))/(SMA(ABS(CLOSE-GSKZZB),13,1))*100;
STICKLINE(RSI1>RSI2,2.3,3,3,0),COLORRED;
STICKLINE(RSI1<RSI2,2.3,3,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.56, 0, ' RSI'),COLORMAGENTA;

XXX:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
LWR1:=SMA(XXX,3,1);
LWR2:=SMA(LWR1,3,1);
STICKLINE(LWR1>LWR2,3.3,4,3,0),COLORRED;
STICKLINE(LWR1<LWR2,3.3,4,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.38, 0, ' LWR'),COLORMAGENTA;

BBI:=(MA(CLOSE,3)+MA(CLOSE,5)+MA(CLOSE,8)+MA(CLOSE,13))/4;
STICKLINE(CLOSE>BBI,4.3,5,3,0),COLORRED;
STICKLINE(CLOSE<BBI,4.3,5,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.21, 0, ' BBI'),COLORMAGENTA;

ABC5:=CLOSE>BBI;
GSK:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(GSK,5),3)/EMA(EMA(ABS(GSK),5),3);
GSKZ:=100*EMA(EMA(GSK,13),8)/EMA(EMA(ABS(GSK),13),8);
STICKLINE(MMS>GSKZ,5.3,6,3,0),COLORRED;
STICKLINE(MMS<GSKZ,5.3,6,3,0),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR,0.01, 0.03, 0, ' ZLMM'),COLORMAGENTA;

买入:DIFF>DEA AND K>D AND RSI1>RSI2 AND LWR1>LWR2 AND CLOSE>BBI AND MMS>GSKZ,NODRAW,COLORMAGENTA;
{STICKLINE(买入,0.3,6,3,0),COLORMAGENTA;};

 

话先说到前面哦， 这是我挑出来一段上涨的行情，所以看起来有作用，嗯，看蓝色框框

 

继续看， 再挑个震荡的行情，看看效果还是可以的

 

现在两张图片，看着效果还挺好， 网上也有很多六脉神剑的公式， 显示稍有区别， 比如箭头的，

 

然后说5个红色的上车，6个红的持有， 5个卖出的， 各种思路都有，OK， 那我再简化成一条线， 如果红色个数是1， 那线的数值就是1， 如果红色个数是6，那线的数值是6

直接上副图公式源码， 再看效果图

DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:DIFF>DEA,NODRAW;

XX:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=SMA(XX,3,1);
D:=SMA(K,3,1);
KDJ:K>D,NODRAW;

GSKZZB:=REF(CLOSE,1);
RSI1:=(SMA(MAX(CLOSE-GSKZZB,0),5,1))/(SMA(ABS(CLOSE-GSKZZB),5,1))*100;
RSI2:=(SMA(MAX(CLOSE-GSKZZB,0),13,1))/(SMA(ABS(CLOSE-GSKZZB),13,1))*100;
RSI:RSI1>RSI2,NODRAW;

XXX:=-(HHV(HIGH,13)-CLOSE)/(HHV(HIGH,13)-LLV(LOW,13))*100;
LWR1:=SMA(XXX,3,1);
LWR2:=SMA(LWR1,3,1);
LWR:LWR1>LWR2,NODRAW;

BB1:=(MA(CLOSE,3)+MA(CLOSE,5)+MA(CLOSE,8)+MA(CLOSE,13))/4;
BBI:CLOSE>BB1,NODRAW;

GSK:=CLOSE-REF(CLOSE,1);
MMS:=100*EMA(EMA(GSK,5),3)/EMA(EMA(ABS(GSK),5),3);
GSKZ:=100*EMA(EMA(GSK,13),8)/EMA(EMA(ABS(GSK),13),8);
ZLMM:MMS>GSKZ,NODRAW;

买入:IF(DIFF>DEA,1,0)+IF( K>D,1,0)+IF(RSI1>RSI2,1,0)+IF(LWR1>LWR2,1,0)+IF(CLOSE>BB1,1,0)+IF(MMS>GSKZ,1,0),COLORYELLOW;

 

其实6脉，就是6个技术指标叠加，

震荡指标：LWR, RSI, KDJ

趋势指标：ZLMM, BBI, MACD

LWR 和  KDJ 是对称的，

 

其实macd，和 kdj是同一个东西,

kdj的参数放大一点，933改成20.10.8，走势和macd的12.26.9差不多，也就是说kdj等同于小参数的macd

参数越小越灵敏，参数小，就是超买超卖型，就是震荡型

参数越大越迟钝，参数大，就是趋势型

六脉神剑的表面看起来是指标叠加，起了作用， 

实际是，大周期看方向， 小周期入场， 起了作用，

大周期看方向， 就是macd，zlmm，这种趋势指标， 参数大的

小周期入场， 就是kdj，rsi这种震荡指标， 小参数的，