龙哥量化：通达信涨停的各种写法对比整理

龙哥微信：Long622889  
代写技术指标_选股公式： 通达信，同花顺，东方财富，大智慧，文华，博易，KT交易师
代写期货量化策略：TB交易开拓者，文华8，金字塔量化

 

马上涨停， 马上发财，新年快乐，恭祝股友们，新年开门红！

今天整理一下各种涨停的写法

如果你只做主板，10%涨停，下面这句符合要求， 但是遇到特殊情况， 比如涨幅是9.9%，就涨停的，没有被标记出来
ZT:C>=REF(C,1)*1.1 AND C=H;

由于复权处理或不复权时的分红转增，所以多加一层验证，收盘价要等于最高价 C=H ；

比如这只股票的这天涨幅是9.93% ，在分时图也能看到早盘快速涨停。但是没有被标记出来

 

聪明的你， 肯定想到，如果用计算的方式，会有误差， 有没有函数直接能给出这天是涨停的，确实有，通达信专业版， 的专业财务函数GPJYVALUE，可以

下面这句是函数GPJYVALUE的用法解释

{15--涨跌停 涨跌停状态 封单金额(万元) [注：涨停取2,曾涨停取1,跌停取-2,曾跌停取-1;跌停和曾跌停时,封单金额取负值 该指标展示20160926日之后的数据]}
涨停2:GPJYVALUE(15,1,0)=2;

直接复制这句代码， 核对一下，12月12日，这天被精准的识别为涨停。但是这个函数也有缺点，缺点太多， 舍弃不用 

1，不能通用别的软件，比如同花顺，大智慧

2，只展示20160926日之后的数据

3，免费版不能用

4，要下载专业财务数据

真服了， 为什么不给个单独的函数呢，

这里想吐槽一下通达信的ZTPRICE函数， 鸡肋， 又很秒，

说他鸡肋，只是写法稍有区别，

说他秒， 是因为99.99%的人，不知道上交所的原文规定，不知道要四舍五入，有兴趣的自己对比

A1:ZTPRICE(REF(CLOSE,1),0.1);
A2:ROUND2(REF(CLOSE,1) * (1+0.1),2);

 

OK，那只能再分析一遍 交易所对涨停的定义

上交所官方文件 原话：
{股票、基金涨跌幅价格的计算公式为：涨跌幅价格=前收盘价×(1±涨跌幅比例)。
-计算结果按照四舍五入原则取至价格最小变动单位。}

尤其注意， 乘了10% 之后， 还要四舍五入

简版涨停公式：  

涨停1: C>=REF(C,1)*1.1 AND C=H;

四舍五入的涨停公式：

涨停2: C>=ROUND2(REF(C,1)*1.1, 2) AND C=H;

核对一下，发现：涨停2确实能解决bug，而且计算出的涨停价是准确的。

 

再来看2元，3元的股票涨停，经常会看到涨幅是9.6%  ，  10.5%这种的，核对一下

看着也没问题，这里重点解释一个疑惑， 为啥涨幅不是10.00% 的整数

比如昨日收盘价是2.56元   主板 10%涨停， 那计算涨停价   2.56 * （ 1 + 10%）= 2.816 元  ，四舍五入后， 涨停价是2.82元， 然后再用涨停价2.82除以昨收收盘价2.56，计算出今日涨停的具体幅度，2.82 / 2.56 = 1.10156

所以涨停的幅度是10.16%

 

主板10%，双创20%，ST板5%，所以识别一下板块 ，写法好几种， 电脑都可以用， 但是手机有的不能用， 所以选，双创2，ST3的吧，

双创1:INBLOCK('创业板') OR INBLOCK('科创板');  {通达信手机不能识别INBLOCK函数}
双创2:CODELIKE('30') OR CODELIKE('68');
双创3:FINANCE(3)=3 OR FINANCE(3)=4;  {沪深京品种类型,3:创业板,4:科创板    通达信手机不能识别科创板};

ST1:INBLOCK('ST板块'); {通达信手机不能识别INBLOCK函数}
ST2:NAMELIKE('*ST') OR NAMELIKE('ST');
ST3:NAMEINCLUDE('ST');
ST4:ISSTCODE;  {通达信手机不能识别}

呐，这里多嘴一句

去除科创板， 去除st板，去除北交所，的公式

去除:IF(CODELIKE('30') OR CODELIKE('68') OR NAMEINCLUDE('ST') OR CODELIKE('9'),0,1); 

 

最后一步， 分板块计算涨幅:  主板10%，双创20%，ST板5%,   在副图给出信号效果图， 在主图也给出信号效果图

新手更能接受汉字类的源码， 因为可读性强。其实，我更喜欢字母类的源码， 不用频繁切换中英文，容易和注释识别开，汉字是方块字，眼花

主图源码：

涨停的涨幅:=IF(NAMEINCLUDE('ST'),0.05,IF(CODELIKE('30') OR CODELIKE('68'), 0.2, 0.1));
涨停价:ROUND2(REF(C,1)*(1+涨停的涨幅), 2),NODRAW,COLORRED;
涨停:C>=ROUND2(REF(C,1)*(1+涨停的涨幅), 2) AND C=H,NODRAW,COLORRED;
DRAWTEXT(涨停, H, '涨停'),COLORRED,DRAWABOVE;
DRAWICON(涨停, H*1.02, 90),DRAWABOVE;
STICKLINE(涨停, C, O, 2.8,0),COLORRED;
 
跌停价:ROUND2(REF(C,1)*(1-涨停的涨幅), 2),NODRAW,COLORGREEN;
跌停:C<=ROUND2(REF(C,1)*(1-涨停的涨幅), 2) AND C=L,NODRAW,COLORGREEN;
DRAWTEXT(跌停, H, '跌停'),COLORGREEN,DRAWABOVE;
DRAWICON(跌停, H*1.02,  91),COLORGREEN,DRAWABOVE;
STICKLINE(跌停, C, O, 2.8,0),COLORGREEN;

 

副图源码：

涨停的涨幅:IF(NAMEINCLUDE('ST'),0.05,IF(CODELIKE('30') OR CODELIKE('68'), 0.2, 0.1));
涨停价:ROUND2(REF(C,1)*(1+涨停的涨幅), 2),NODRAW,COLORRED;
涨停:C>=ROUND2(REF(C,1)*(1+涨停的涨幅), 2) AND C=H,COLORRED;
DRAWTEXT(涨停, 0.5, '涨停'),COLORRED,DRAWABOVE;
DRAWICON(涨停, 0.7, 90),DRAWABOVE;
STICKLINE(涨停, 0.2, 0.5, 2.8,0),COLORRED;
 
跌停价:ROUND2(REF(C,1)*(1-涨停的涨幅), 2),NODRAW,COLORGREEN;
跌停:C<=ROUND2(REF(C,1)*(1-涨停的涨幅), 2) AND C=L,COLORGREEN;
DRAWTEXT(跌停, 0.5, '跌停'),COLORGREEN,DRAWABOVE;
DRAWICON(跌停, 0.7,  91),COLORGREEN,DRAWABOVE;
STICKLINE(跌停, 0.2, 0.5, 2.8,0),COLORGREEN;

 

字母板主图源码：

BANKUAI:=IF(NAMEINCLUDE('ST'),0.05,IF(CODELIKE('30') OR CODELIKE('68'), 0.2, 0.1));
涨停价:ROUND2(REF(C,1)*(1+BANKUAI), 2),NODRAW,COLORRED;
ZT:=C>=ROUND2(REF(C,1)*(1+BANKUAI), 2) AND C=H,NODRAW,COLORRED;
DRAWTEXT(ZT, H, '涨停'),COLORRED,DRAWABOVE;
DRAWICON(ZT, H*1.02, 90),DRAWABOVE;
STICKLINE(ZT, C, O, 2.8,0),COLORRED;
 
跌停价:ROUND2(REF(C,1)*(1-BANKUAI), 2),NODRAW,COLORGREEN;
DT:=C<=ROUND2(REF(C,1)*(1-BANKUAI), 2) AND C=L,NODRAW,COLORGREEN;
DRAWTEXT(DT, H, '跌停'),COLORGREEN,DRAWABOVE;
DRAWICON(DT, H*1.02,  91),COLORGREEN,DRAWABOVE;
STICKLINE(DT, C, O, 2.8,0),COLORGREEN;

 

字母版再简化，主图源码：

BANKUAI:=IF(NAMEINCLUDE('ST'),0.05,IF(CODELIKE('30') OR CODELIKE('68'), 0.2, 0.1));
ZT:=C>=ROUND2(REF(C,1)*(1+BANKUAI), 2) AND C=H,NODRAW,COLORRED;
DRAWTEXT(ZT, H, '涨停'),COLORRED,DRAWABOVE;

DT:=C<=ROUND2(REF(C,1)*(1-BANKUAI), 2) AND C=L,NODRAW,COLORGREEN;
DRAWTEXT(DT, H, '跌停'),COLORGREEN,DRAWABOVE;

 

下一篇，列出涨停的各种相关数据，比如，涨停时间， 封板金额，等等

再下下一篇， 在5分钟K线，计算出日线涨停的相关数据

再续写几种涨停类的策略。