d778: NOIP2009 2.Hankson的趣味题

内容 ：

 Hanks 博士是 BT (Bio-Tech，生物技术)  领域的知名专家，他的儿子名叫 Hankson。现在，刚刚放学回家的 Hankson 正在思考一个有趣的问题。 
     今天在课堂上，老师讲解了如何求两个正整数 c1和 c2 的最大公约数和最小公倍数。现在 Hankson 认为自己已经熟练地掌握了这些知识，他开始思考一个“求公约数”和“求公倍数”之类问题的“逆问题” ，这个问题是这样的：已知正整数 a0,a1,b0,b1，设某未知正整数 x 满足： 
1． x 和 a0 的最大公约数是 a1； 
2． x 和b0 的最小公倍数是 b1。 
     Hankson 的“逆问题”就是求出满足条件的正整数 x。但稍加思索之后，他发现这样的x 并不唯一，甚至可能不存在。因此他转而开始考虑如何求解满足条件的 x 的个数。请你帮助他编程求解这个问题。 

输入说明 ：

第一行为一个正整数 n，表示有 n 组输入数据。接下来的 n 行每行一组输入数据，为四个正整数 a0，a1，b0，b1，每两个整数之间用一个空格隔开。输入数据保证 a0能被 a1 整除，b1 能被 b0整除。

输出说明 ：

共n 行。每组输入数据的输出结果占一行，为一个整数。 
对于每组数据：若不存在这样的 x，请输出 0； 若存在这样的 x，请输出满足条件的 x 的个数。

范例输入 ：

若題目沒有特別說明，則應該以多測資的方式讀取，若不知如何讀取請參考 a001 的範例程式。

241 1 96 28895 1 37 1776

 

范例输出 ：

62

提示 ：

第一组输入数据，x 可以是 9、18、36、72、144、288，共有6个。 
第二组输入数据，x 可以是 48、1776，共有 2 个。 

对于 50%的数据，保证有 1≤a0，a1，b0，b1≤10000且 n≤100。 
对于 100%的数据，保证有 1≤a0，a1，b0，b1≤2,000,000,000且 n≤2000。

 

出处 ：

NOIP2009提高组第二题 (管理員：liouzhou_101)

此题有几点要注意:

1.分解因数要注意效率,将条件设为:

while i<=sqrt(n)+1 do

而不是 while n<>1 do

然后在后面加上：

if n<>1 then
     begin
          inc(count);
          a[count].data:=n;
          a[count].exp:=1;
     end; 

效率大大增加。

2.数字相乘时要留心越界

求最小公倍数时，一定要写成

if (b0 div gcd(n,b0)*n)=b1 then f:=true;

而不是

if (b0*n div gcd(n,b0))=b1 then f:=true;

乍看好像没有差别，但要注意到后者的b0*n已超出longint的范围了！

程序：

program d778;
var a0,a1,b0,b1,i,count,x,m,k,res:longint;
    a:array[1..1000]of record
                         data,exp:longint;
                         end;
    b:array[0..1000000]of longint;
procedure deal(n:longint);
var i:longint;
begin
     count:=0;
     i:=2;
     while i<=sqrt(n)+1 do
     begin
          if n mod i=0 then
          begin
               inc(count);
               a[count].data:=i;
               a[count].exp:=0;
               while n mod i=0 do
               begin
                    inc(a[count].exp);
                    n:=n div i;
               end;
          end;
          inc(i);
     end;
     if n<>1 then
     begin
          inc(count);
          a[count].data:=n;
          a[count].exp:=1;
     end;
end;
procedure dfs(n:longint);
var t,i:longint;
begin
     if n>count then
     begin
          inc(b[0]);
          b[b[0]]:=x;
     end
     else
     begin
          if n=1 then x:=1;
          for i:=0 to a[n].exp do
          begin
               t:=x;
               dfs(n+1);
               x:=t*a[n].data;
          end;
     end;
end;
function gcd(a,b:longint):longint;
begin
     if a mod b=0 then gcd:=b
     else gcd:=gcd(b,a mod b);
end;
function f(n:longint):boolean;
var t:longint;
begin
     f:=false;
     t:=gcd(n,a0);
     if t=a1 then
        if (b0 div gcd(n,b0)*n)=b1 then f:=true;
end;
begin
     readln(m);
     for k:=1 to m do
     begin
          fillchar(a,sizeof(a),0);
          readln(a0,a1,b0,b1);
          if b1=1 then begin count:=1;a[1].data:=1;a[1].exp:=0;end else deal(b1);
          b[0]:=0;
          dfs(1);
          res:=0;
          for i:=1 to b[0] do if f(b[i]) then inc(res);
          writeln(res);
     end;
end.