Cmake Practice 总结 Static And Dynamic Libraries

本节的任务：

1. 建立一个静态库和动态库，提供 HelloFunc 函数供其他程序编程使用，HelloFunc
   向终端输出 Hello World 字符串。
2. 安装头文件与共享库。

准备工作：

在/home/xiao/cmake_practice 目录建立 t3 目录，用于存放本节涉及到的工程。

建立共享库

cd /home/xiao/cmake_practice/t3

mkdir lib

在 t3 目录下建立 CMakeLists.txt，内容如下：

project(HELLOLIB)
add_subdirectory(lib)

在 lib 目录下建立两个源文件 hello.c 与 hello.h
hello.c 内容如下：

#include “hello.h”
void HelloFunc()
{
  printf(“Hello World\n”);
}

hello.h 内容如下：

#ifndef HELLO_H
#define HELLO_H
#include <stdio.h>
void HelloFunc();
#endif

在 lib 目录下建立 CMakeLists.txt，内容如下：

set(LIBHELLO_SRC hello.c)
add_library(hello SHARED ${LIBHELLO_SRC})

编译共享库:

仍然采用 out-of-source 编译的方式，按照习惯，我们建立一个 build 目录，在 build
目录中

cmake ..
make

这时，你就可以在 lib 目录得到一个 libhello.so，这就是我们期望的共享库。

如果你要指定 libhello.so 生成的位置，可以通过在主工程文件 CMakeLists.txt 中修改 add_subdirectory(lib)指令来指定一个编译输出位置或者
在 lib/CMakeLists.txt 中添加set(LIBRARY_OUTPUT_PATH 路径)来指定一个新的位置。

add_library命令解释

add_library(libname
  [SHARED|STATIC|MODULE]
  [EXCLUDE_FROM_ALL]
  source1 source2 ... sourceN)

你不需要写全 libhello.so，只需要填写 hello 即可，cmake 系统会自动为你生成libhello.X

类型有三种:
SHARED，动态库
STATIC，静态库
MODULE，在使用 dyld 的系统有效，如果不支持 dyld，则被当作 SHARED 对待。

EXCLUDE_FROM_ALL 参数的意思是这个库不会被默认构建，除非有其他的组件依赖或者手工构建。

添加静态库：

同样使用上面的指令，我们在支持动态库的基础上再为工程添加一个静态库，按照一般的习惯，静态库名字跟动态库名字应该是一致的，只不过后缀是.a 罢了。
下面我们用这个指令再来添加静态库：

add_library(hello STATIC ${LIBHELLO_SRC})

然后再在 build 目录进行外部编译，我们会发现，静态库根本没有被构建，仍然只生成了一个动态库。因为 hello 作为一个 target 是不能重名的，所以，静态库构建指令无效。

如果我们把上面的 hello 修改为 hello_static:

add_library(hello_static STATIC ${LIBHELLO_SRC})

就可以构建一个 libhello_static.a 的静态库了。

这种结果显示不是我们想要的，我们需要的是名字相同的静态库和动态库，因为 target 名称是唯一的，所以，我们肯定不能通过 ADD_LIBRARY 指令来实现了。这时候我们需要用到另外一个指令：

set_target_properties(target1 target2 ...
  PROPERTIES prop1 value1
  prop2 value2 ...)

这条指令可以用来设置输出的名称，对于动态库，还可以用来指定动态库版本和 API 版本。

在本例中，我们需要作的是向 lib/CMakeLists.txt 中添加一条：

set_target_properties(hello_static PROPERTIES OUTPUT_NAME "hello")

这样，我们就可以同时得到 libhello.so/libhello.a 两个库了。

与他对应的指令是：

get_target_property(VAR target property)

具体用法如下例，我们向 lib/CMakeListst.txt 中添加：

get_target_property(OUTPUT_VALUE hello_static OUTPUT_NAME)
message(STATUS “This is the hello_static OUTPUT_NAME: ” ${OUTPUT_VALUE})

如果没有这个属性定义，则返回 NOTFOUND.

按照规则，动态库是应该包含一个版本号的，我们可以看一下系统的动态库，一般情况是
libhello.so.1.2
libhello.so ->libhello.so.1
libhello.so.1->libhello.so.1.2

为了实现动态库版本号，我们仍然需要使用 set_target_properties 指令。
具体使用方法如下：

set_target_properties(hello PROPERTIES VERSION 1.2 SOVERSION 1)

VERSION 指代动态库版本，SOVERSION 指代 API 版本。
将上述指令加入 lib/CMakeLists.txt 中，重新构建看看结果。
在 build/lib 目录会生成：
libhello.so.1.2
libhello.so.1->libhello.so.1.2
libhello.so ->libhello.so.1

安装共享库和头文件

以上面的例子，我们需要将 libhello.a, libhello.so.x 以及 hello.h 安装到系统目录，才能真正让其他人开发使用，在本例中我们将 hello 的共享库安装到prefix/lib目录，将 hello.h 安装到prefix/include/hello 目录。

利用上一节了解到的 INSTALL 指令，我们向 lib/CMakeLists.txt 中添加如下指令：

install(TARGETS hello hello_static
  LIBRARY DESTINATION lib
  ARCHIVE DESTINATION lib)

install(FILES hello.h DESTINATION include/hello)

注意，静态库要使用 ARCHIVE 关键字
通过:

cmake -DCMAKE_INSTALL_PREFIX=/usr ..
make
make install

我们就可以将共享库和头文件安装到系统目录/usr/lib 和/usr/include/hello 中了。

使用外部共享库和头文件

在/home/xiao/cmake_practice 目录建立 t4 目录

建立 src 目录，编写源文件 main.c，内容如下：

#include <hello.h>
int main()
{
  HelloFunc();
  return 0;
}

编写工程主文件 CMakeLists.txt

project(NEWHELLO)
add_subdirectory(src)

编写 src/CMakeLists.txt

add_executable(main main.c)
target_include_directories(main PUBLIC /usr/include/hello)
target_link_libraries(main PRIVATE hello)

也可以写成
target_link_libraries(main PRIVATE libhello.so)
这里的 hello 指的是我们上一节构建的共享库 libhello.

进入 build 目录重新进行构建。

cmake ..
make

这是我们就得到了一个连接到 libhello 的可执行程序 main，位于 build/src 目录，运
行 main 的结果是输出：

Hello World

让我们来检查一下 main 的链接情况：

ldd src/main

linux-gate.so.1 =>
(0xb7ee7000)
libhello.so.1 => /usr/lib/libhello.so.1 (0xb7ece000)
libc.so.6 => /lib/libc.so.6 (0xb7d77000)
/lib/ld-linux.so.2 (0xb7ee8000)

可以清楚的看到 main 确实链接了共享库 libhello，而且链接的是动态库libhello.so.1

那如何链接到静态库呢？
方法很简单：
将 target_link_libraries 指令修改为:

target_link_libraries(main libhello.a)

重新构建后再来看一下 main 的链接情况

ldd src/main

linux-gate.so.1 => (0xb7fa8000)
libc.so.6 => /lib/libc.so.6 (0xb7e3a000)
/lib/ld-linux.so.2 (0xb7fa9000)说明，main 确实链接到了静态库 libhello.a
在链接阶段，会将汇编生成的目标文件.o与引用到的库一起链接打包到可执行文件中。因此对应的链接方式称为静态链接。程序在运行时与函数库再无瓜葛，移植方便。

静态库与动态库区别：https://www.cnblogs.com/codingmengmeng/p/6046481.html

特殊的环境变量 CMAKE_INCLUDE_PATH 和 CMAKE_LIBRARY_PATH

务必注意，这两个是环境变量而不是 cmake 变量。使用方法是要在 bash 中用 export。

如果头文件没有存放在常规路径(/usr/include, /usr/local/include 等)，则可以通过这些变量就行弥补。

我们以本例中的 hello.h 为例，它存放在/usr/include/hello 目录，所以直接查找肯
定是找不到的。
前面我们直接使用了绝对路径 target_include_directories(main PUBLIC /usr/include/hello) 告诉工程这个头文件目录。
为了将程序更智能一点，我们可以使用 CMAKE_INCLUDE_PATH 来进行，使用 bash 的方法
如下：

export CMAKE_INCLUDE_PATH=/usr/include/hello

然后在头文件中将 target_include_directories(main PUBLIC /usr/include/hello) 替换为：

find_path(myHeader hello.h)
if(myHeader)
target_include_directories(main PUBLIC ${myHeader})
endif(myHeader)

find_path 用来在指定路径中搜索文件名，比如：

find_path(myHeader NAMES hello.h PATHS /usr/include /usr/include/hello)

这里我们没有指定路径，但是，cmake 仍然可以帮我们找到 hello.h 存放的路径，就是因为我们设置了环境变量 CMAKE_INCLUDE_PATH。

如果你不使用 find_path，CMAKE_INCLUDE_PATH 变量的设置是没有作用的，你不能指望它会直接为编译器命令添加参数-I CMAKE_INCLUDE_PATH。

以此为例，CMAKE_LIBRARY_PATH 可以用在 find_library 中。同样，因为这些变量直接为 find_指令所使用，所以所有使用 find_指令的 cmake 模块都会受益。