Delphi 类的内部方法：overload、override、virtual、dynamic、abstract - 重载、多态、覆盖、静态、动态、抽象、类方法

Delphi 类的内部方法：overload、override、virtual、dynamic、abstract - 重载、多态、覆盖、静态、动态、抽象、类方法

1、overload - （重载、超载、多个）（多态）

在Pascal语法规则中，同一个UNIT里是不能存在两个同名的函数的，例如：

function func(): Boolean;
function func(const x: Char): Boolean;

这样是会出语法错误的，原因是因为标识符规则限制。但是问题出来了，如果我们需要几个功能相似但是参数不同的函数，那么根据标识符规则，我们就必须定义几个不同名，但是功能相同或相似的函数。
    如，假设我需要一个函数，要实现返回参数一减去参数二后的值，那么我们就将这样定义函数：

function SubInt(const Value1, Value2: Integer): Integer;
functino SubReal(const Value1, Value2: Real): Real;
function SubDouble(const Value1, Value2: Double): Double;
 
implementation
 
function SubInt(const Value1, Value2: Integer): Integer;
begin
  Result:= Value1 - Value2;
end;
 
functino SubReal(const Value1, Value2: Real): Real;
begin
  Result:= Value1 - Value2;
end;
 
function SubDouble(const Value1, Value2: Double): Double;
begin
  Result:= Value1 - Value2;
end;

我们可以看到，这三个函数除了参数名不同外，实现部分是一样的，这为程序的一致性带来了一定的麻烦。如果能定义一个同名函数来处理这几种不同情况的话，便有利于代码的重用，也有利于我们的记忆。这时我们就可以用 overload 来完成我们的需求了。

function Sub(const Value1, Value2: Integer): Integer; overload;
function Sub(const Value1, Value2: Real): Real; overload;
function Sub(const Value1, Value2: Double): Double; overload;
 
implementation
 
function Sub(const Value1, Value2: Integer): Integer;
begin
  Result:= Value1 - Value2;
end;
 
function Sub(const Value1, Value2: Real): Real;
begin
  Result:= Value1 - Value2;
end;
 
function Sub(const Value1, Value2: Double): Double;
begin
  Result:= Value1 - Value2;
end;

由此可见，名字相同而参数的数据类型或数量不同的函数，称之为overload函数。这是因为编译器在编译时不仅使用了函数名的信息，还使用了参数类型和数量的信息，通过组合这些信息可以确定分配地址时需要的唯一标识，通常我们叫他signature。例如：

Sub(1, 2);     // 调用的是 function Sub(const Value1, Value2: Integer): Integer;
Sub(1.0, 2.0); // 调用的是 function Sub(const Value1, Value2: Real): Real;

这里要说明一下，如果是同名函数，并且参数也相同，只是返回值不同的话，是不能实现overload的。

 

2、override -（覆盖） 父类中存在此方法，不继承父类的方法采用覆盖的方式覆盖父类中的方法 。用 inherited 来重载 / 继承:
    前面我说过，在派生一个新类的时候，首先会继承父类中的所有可继承部分，那么就意味着，默认情况下，父类所有的非私有部分的类成员或方法都已经包含在新类中。

    但是，如果我们要为类的一个方法添加新的代码而又不希望重写父类方法中原有功能的话，我们可以用override来实现方法的覆盖，并用 inherited 来继承（或者可以说调用）父类方法中的方法功能

type
  TBaseClass = class(TObject)
    // 定义一个新的父类
  protected
    FMessage: string;
  public
    constructor Create();    // 构造方法
    procedure MessageBox(); virtual; // 显示字符串
  end;
 
  TChildClass = class(TBaseClass)
    // 定义一个TBaseClass的派生类
  public
    procedure MessageBox(); override; // 重载父类中的方法
  end;
 
implementation
 
constructor TBaseClass.Create;
begin
  inherited Create();   // 继承父类中的构造方法Create
  FMessage:= ClassName; // 初始化信息字符串为类名
end;
 
procedure TBaseClass.MessageBox;
begin
  ShowMessage(FMessage); // 显示字符串
end;
 
procedure TChildClass.MessageBox;
begin
  FMessage:= FMessage + FMessage;
  inherited MessageBox(); // 继承父类中原有MessageBox方法的原有功能
end;

好，我们可以编写一个简单的例子来调用一下：

var
  Child: TChildClass;
begin
  Child:= TChildClass.Create;
  Child.MessageBox();
  Child.Free;
end;

代码执行后，应该可以看到一个弹出“TChildClassTChildClass”字符串的对话框。
    以上代码只是简单的演示了类方法的继承，也许你会奇怪，为什么TBaseClass的构造方法Create没有用override关键字指定，却同样可以inherited来继承父类的该方法，其实不用override也是可以实现继承的（在这里如果你加上override反而会出语法错误，因为TObject类的Create是一个静态方法，而静态方法是不允许被override的），那么他们有什么不一样的呢？我们来看下面的例子：

var
  Child: TBaseClass;
begin
  Child:= TChildClass.Create;
  Child.MessageBox();
  Child.Free;
end;

执行这段测试代码和我们上面的代码是一样的效果的。然后我们再把TBaseClass类的方法MessageBox后的virtual关键字和子类中的override关键字去掉，再执行一次看看，应该是看到一个弹出“TChildClass”字符串的对话框。
    这是为什么呢？原因是因为virtual关键字，下面简单的说明一下virtual关键字：

 

3、virtual 和 dynamic方法（虚拟和动态  - 执行1，2次用dynamic，多次用virtual）
    virtual关键字是指定方法为虚方法，Object Pascal中，默认情况下，所有方法都是静态的（当然和类方法不同），静态方法的特点是，在对象被创建的时候，编译器会分配所有调用静态方法时所指定的内存地址，也就是说，编译期即指定了调用的具体方法。
    而virtual和dynamic方法（虚方法和动态方法）则是在调用时动态分配的。他们的语义是相同的，唯一不同的是，他们的实现方法和调用方法，这涉及到DELPHI的编译机制。

    Delphi的编译器会自动维护用于添加虚方法的虚方法表(VMT)和用于添加动态方法的动态方法表(DMT)。
    虚方法表存放的是类及其基类声明的所有虚方法指针。每一个类都有并且只有一个虚方法表，当然每一个虚方法表都有一个入口。无论一个类是否有他自己定义的虚方法，只要他继承了祖先类的虚方法，他也就会有自己的虚方法表，并列举出他继承的所有虚方法。因为每一个类都有一个自己的虚方法表，Delphi就可以使用虚方法表来识别一个类，实际上，一个类引用就是指向类的虚方法表的指针。
    由于基类和派生类的虚方法表之间有过强的关联性，因此派生类继承了祖先类的虚方法，也就是说派生类的虚方法表的前面一部分必须与基类相同。而当基类和派生类不在同一个DLL或EXE中的时候，这个要求是很难满足的。基类一旦改变，派生类如果不重新编译，将导致错误。另外，如果类的继承很深，那么虚方法表将会因不断继承的虚方法而膨胀，导致效率低下。
    而动态方法则可以解决这个问题，每一个类的动态方法表中只维护部分的动态方法，也就是说动态方法表只列出了该类所声明的动态方法，他并不包括从祖先类那里继承来的动态方法。动态方法表使用了一种独特的编号和检索系统，当调用动态方法时，会在动态方法表中的Indexes数组中查找该方法的代号，一旦找到匹配该方法的代号，则方法指针会到相应的地址中调用方法。如果没有找到，则会搜索祖先类中的动态方法表。这样虽然解决了虚方法表膨胀的问题，但是产生了执行效率的问题。

    总的来说，虚方法侧重于提高速度，动态方法侧重于节省内存，如果某方法其后代类基本都需要override的，那么推荐使用virtual，如果某方法不经常或者几乎不在后代类中被override的，则推荐使用dynamic。

TSaa = class
  procedure ProcTest; virtual; {或 dynamic}
end;

TChild = class(TSaa)
  procedure ProcTest; override;
end;

 

4、abstract 方法 - 抽象方法
    abstract方法就是我们常说的抽象方法，该方法只能有声明而不能有实现部分，一般只是提供给派生类override使用的，所以一般abstract关键字和virtual是一起出现的。而一般含有抽象方法的类一般我们叫他虚类。

{定义两个抽象方法}
TMyClass = class(TObject)
  procedure Proc1; virtual; abstract;      {抽象方法首先应该是一个虚方法或动态方法}
  function Fun: string; dynamic; abstract; {抽象方法也叫纯虚方法}
end;

 抽象方法在本类中只有定义、没有实现;方法应该在子类中实现。如果一个类包含了抽象方法, 那么这个类也就成了抽象类;抽象类只能通过其子类来实例化, 自己不能生成对象。最常用的一个抽象类： TStrings 

var
  List: TStrings;
  i: Integer;
begin
  List := TStringList.Create;
  for i := 0 to 99 do List.Add(IntToStr(i));
  Memo1.Lines := List;
  List.Free;
end;

 

5、类(Class) 方法
    类方法和C中的static方法有点相似，Object Pascal中的类方法是不需要实例化对象就可以调用的方法。由于他不需要为对象分配内存空间就可以调用他，那么也就意味着在类方法中不能引用类中的其他数据成员。
    类方法的声名如下：

type
  TNewClass = class(TObject)
  public
    class procedure RoyTest(s:String):String;
  end;

 示例：

{类的对象的正常调用}
procedure TForm1.Button1Click(Sender: TObject);
var
  NewClass: TNewClass;
begin
  NewClass:= TNewClass.Create;  //创建
  TNewClass.RoyTest('滔Roy'); {滔Roy}
  NewClass.Free;  //释放
end;

{类方法可以直接通过类名使用}
procedure TForm1.Button2Click(Sender: TObject);
begin
  TNewClass.RoyTest('滔Roy'); {滔Roy}
end;

　　

　　

 

 

创建时间：2019.08.22　　更新时间：2020.11.05　　2021.02.23