CDS标准视图：会计员 I_AccountingClerk

视图名称：会计员 I_AccountingClerk

视图类型：基础

视图代码：

点击查看代码

@AbapCatalog: { sqlViewName: 'IFIACCCLERK',
//                compiler.compareFilter: true,
                preserveKey: true }
@AccessControl.authorizationCheck: #CHECK
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Accounting Clerk'
@ObjectModel: { representativeKey: 'AccountingClerk',
                usageType: { serviceQuality: #A,
                             sizeCategory: #M,
                             dataClass: #CUSTOMIZING },
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #SEARCHABLE_ENTITY],
                modelingPattern: #ANALYTICAL_DIMENSION }
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@VDM.viewType: #BASIC

define view I_AccountingClerk
  as select from t001s

  association [0..1] to I_CompanyCode as _Company on _Company.CompanyCode = $projection.CompanyCode

{

      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG
      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED
      @ObjectModel.foreignKey.association: '_Company'
  key cast (bukrs as fis_bukrs)       as CompanyCode,
      @ObjectModel.text.element: 'AccountingClerkName'
  key cast (busab as farp_busab)      as AccountingClerk,

      @Semantics.text
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      cast (sname as farp_sname_001s) as AccountingClerkName,

      cast( usnam as vdm_userid )     as UserID,

      // associations
      _Company
}

事务代码：SPRO

视图结构：

字段名称	技术名称
公司代码	COMPANYCODE
会计员	ACCOUNTINGCLERK
会计员姓名	ACCOUNTINGCLERKNAME
用户标识	USERID