CDS标准视图：测量点数据 I_MeasuringPointData

• 视图名称：测量点数据 I_MeasuringPointData
• 视图类型：基础视图
• 视图代码：

点击查看代码

@AbapCatalog.sqlViewName: 'IMEASPOINTDATA'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Measuring Point Data'

@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'MeasuringPoint'
@Metadata.ignorePropagatedAnnotations: true

@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction: {
    enabled: true
  }
}

@ObjectModel: {
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #B,
    sizeCategory: #M
  }
}

@Metadata.allowExtensions: true

@ObjectModel.modelingPattern:   #EXTRACTION_DATA_SOURCE
@ObjectModel.supportedCapabilities:     [ #EXTRACTION_DATA_SOURCE ]

define view I_MeasuringPointData
    as select from I_MeasuringPoint
{
  key MeasuringPoint,

      @ObjectModel.foreignKey.association: '_Language'
      Language,

      MeasuringPointDescription,

      MeasuringPointShortText,

      @ObjectModel.foreignKey.association: '_ControllingObject'
      MeasuringPointObjectIdentifier,

      MeasuringPointPositionNumber,

      @ObjectModel.foreignKey.association: '_MeasuringPointCategory'
      MeasuringPointCategory,

      @Semantics.systemDate.createdAt: true
      CreationDate,

      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,

      AuthorizationGroup,

      MeasuringPointIsInactive,

      MeasuringPointIsCounter,

      MultiLevelDeletionLogicStatus,

      @ObjectModel.foreignKey.association: '_Product'
      Assembly,

      @ObjectModel.foreignKey.association: '_ReferenceMeasuringPoint'
      ReferenceMeasuringPoint,

      MsrgPtInternalCharacteristic,

      MeasuringPointExponent,

      MeasuringPointDecimalPlaces,

      MeasuringPointMinimumThreshold,

      MeasuringPointMaximumThreshold,

      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      MeasurementRangeUnit,

      MeasuringPointSIUnitOfMeasure,

      MsrgPtIsCountingBackwards,

      @ObjectModel.foreignKey.association: '_MsmtRdngSourceMeasuringPoint'
      MsmtRdngSourceMeasuringPoint,

      CounterOverflowRdngThreshold,

      MeasuringPointAnnualEstimate,

      @ObjectModel.foreignKey.association: '_MeasuringPointCatalogType'
      MeasuringPointCatalogType,

      @ObjectModel.foreignKey.association: '_MeasuringPointCodeGroup'
      MeasuringPointCodeGroup,

      ValuationCodeIsSufficient,

      MeasuringPointHasLongText,

      // Propagate association(s)
      _Language,
      _ControllingObject,
      _MeasuringPointCategory,
      _Product,
      _ReferenceMeasuringPoint,
      _UnitOfMeasure,
      _MsmtRdngSourceMeasuringPoint,
      _MeasuringPointCatalogType,
      _MeasuringPointCodeGroup
}
where MeasuringPointObjectType = 'IE'
      or MeasuringPointObjectType = 'IF'

• 事务代码：IK03
  技术对象、测量点

• 视图结构：

字段名称	技术名称
测量点	MEASURINGPOINT
语言	LANGUAGE
描述	MEASURINGPOINTDESCRIPTION
文本	MEASURINGPOINTSHORTTEXT
计量点对象编号	MEASURINGPOINTOBJECTIDENTIFIER
计量位置	MEASURINGPOINTPOSITIONNUMBER
计量点种类	MEASURINGPOINTCATEGORY
创建日期	CREATIONDATE
更改日期	LASTCHANGEDATE
授权组	AUTHORIZATIONGROUP
计量点没激活	MEASURINGPOINTISINACTIVE
计数器	MEASURINGPOINTISCOUNTER
删除标识	MULTILEVELDELETIONLOGICSTATUS
装配	ASSEMBLY
参考计量点	REFERENCEMEASURINGPOINT
内部特性	MSRGPTINTERNALCHARACTERISTIC
浮点指数	MEASURINGPOINTEXPONENT
十进制位	MEASURINGPOINTDECIMALPLACES
计量范围下限	MEASURINGPOINTMINIMUMTHRESHOLD
UpMRLimit	MEASURINGPOINTMAXIMUMTHRESHOLD
计量范围单位	MEASUREMENTRANGEUNIT
SI 单位	MEASURINGPOINTSIUNITOFMEASURE
反向	MSRGPTISCOUNTINGBACKWARDS
读数传输从	MSMTRDNGSOURCEMEASURINGPOINT
计数器溢出读数	COUNTEROVERFLOWRDNGTHRESHOLD
年估算	MEASURINGPOINTANNUALESTIMATE
目录类型	MEASURINGPOINTCATALOGTYPE
代码组	MEASURINGPOINTCODEGROUP
评估代码充足	VALUATIONCODEISSUFFICIENT
长文本	MEASURINGPOINTHASLONGTEXT